1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
|
%D \module
%D [ file=mp-page.mpiv,
%D version=1999.03.10,
%D title=\CONTEXT\ \METAPOST\ graphics,
%D subtitle=page enhancements,
%D author=Hans Hagen,
%D date=\currentdate,
%D copyright={PRAGMA ADE \& \CONTEXT\ Development Team}]
%C
%C This module is part of the \CONTEXT\ macro||package and is
%C therefore copyrighted by \PRAGMA. See mreadme.pdf for
%C details.
%D This module is rather preliminary and subjected to changes.In the process of
%D moving to \METAFUN2\ this might change.
if known context_page : endinput ; fi ;
boolean context_page ; context_page := true ;
def LoadPageState = enddef ; % just in case some old style uses it
% Next we implement the the page area model. First some constants.
LeftEdge := -4 ; Top := -40 ;
LeftEdgeSeparator := -3 ; TopSeparator := -30 ;
LeftMargin := -2 ; Header := -20 ;
LeftMarginSeparator := -1 ; HeaderSeparator := -10 ;
Text := 0 ; Text := 0 ;
RightMarginSeparator := +1 ; FooterSeparator := +10 ;
RightMargin := +2 ; Footer := +20 ;
RightEdgeSeparator := +3 ; BottomSeparator := +30 ;
RightEdge := +4 ; Bottom := +40 ;
numeric HorPos ; HorPos := 0 ;
numeric VerPos ; VerPos := 0 ;
% Because metapost > 1.50 has dynamic memory management and is less efficient than
% before we now delay calculations ... (on a document with 150 pages the time spent
% in mp was close to 5 seconds which was only due to initialising the page related
% areas, something that was hardly noticeable before. At least now we're back to
% half a second for such a case.
def SetPageVsize =
numeric Vsize[] ;
Vsize[Top] = TopHeight ;
Vsize[TopSeparator] = TopDistance ;
Vsize[Header] = HeaderHeight ;
Vsize[HeaderSeparator] = HeaderDistance ;
Vsize[Text] = TextHeight ;
Vsize[FooterSeparator] = FooterDistance ;
Vsize[Footer] = FooterHeight ;
Vsize[BottomSeparator] = BottomDistance ;
Vsize[Bottom] = BottomHeight ;
enddef ;
def SetPageHsize =
numeric Hsize[] ;
Hsize[LeftEdge] = LeftEdgeWidth ;
Hsize[LeftEdgeSeparator] = LeftEdgeDistance ;
Hsize[LeftMargin] = LeftMarginWidth ;
Hsize[LeftMarginSeparator] = LeftMarginDistance ;
Hsize[Text] = MakeupWidth ;
Hsize[RightMarginSeparator] = RightMarginDistance ;
Hsize[RightMargin] = RightMarginWidth ;
Hsize[RightEdgeSeparator] = RightEdgeDistance ;
Hsize[RightEdge] = RightEdgeWidth ;
enddef ;
def SetPageVstep =
numeric Vstep[] ;
Vstep[Top] = Vstep[TopSeparator] +Vsize[TopSeparator] ;
Vstep[TopSeparator] = PaperHeight-TopSpace ;
Vstep[Header] = Vstep[TopSeparator] -Vsize[Header] ;
Vstep[HeaderSeparator] = Vstep[Header] -Vsize[HeaderSeparator] ;
Vstep[Text] = Vstep[HeaderSeparator]-Vsize[Text] ;
Vstep[FooterSeparator] = Vstep[Text] -Vsize[FooterSeparator] ;
Vstep[Footer] = Vstep[FooterSeparator]-Vsize[Footer] ;
Vstep[BottomSeparator] = Vstep[Footer] -Vsize[BottomSeparator] ;
Vstep[Bottom] = Vstep[BottomSeparator]-Vsize[Bottom] ;
enddef ;
def SetPageHstep =
numeric Hstep[] ;
Hstep[LeftEdge] = Hstep[LeftEdgeSeparator] -Hsize[LeftEdge] ;
Hstep[LeftEdgeSeparator] = Hstep[LeftMargin] -Hsize[LeftEdgeSeparator] ;
Hstep[LeftMargin] = Hstep[LeftMarginSeparator] -Hsize[LeftMargin] ;
Hstep[LeftMarginSeparator] = Hstep[Text] -Hsize[LeftMarginSeparator] ;
Hstep[Text] = BackSpace ;
Hstep[RightMarginSeparator] = Hstep[Text] +Hsize[Text] ;
Hstep[RightMargin] = Hstep[RightMarginSeparator]+Hsize[RightMarginSeparator] ;
Hstep[RightEdgeSeparator] = Hstep[RightMargin] +Hsize[RightMargin] ;
Hstep[RightEdge] = Hstep[RightEdgeSeparator] +Hsize[RightEdgeSeparator] ;
enddef ;
def SetPageArea =
path Area[][] ;
for VerPos=Top step 10 until Bottom:
for HorPos=LeftEdge step 1 until RightEdge:
Area[HorPos][VerPos] := unitsquare xscaled Hsize[HorPos] yscaled Vsize[VerPos] ;
Area[VerPos][HorPos] := Area[HorPos][VerPos] ;
endfor ;
endfor ;
enddef ;
def SetPageLocation =
pair Location[][] ;
for VerPos=Top step 10 until Bottom:
for HorPos=LeftEdge step 1 until RightEdge:
Location[HorPos][VerPos] := (Hstep[HorPos],Vstep[VerPos]) ;
Location[VerPos][HorPos] := Location[HorPos][VerPos] ;
endfor ;
endfor ;
enddef ;
def SetPageField =
path Field[][] ;
for VerPos=Top step 10 until Bottom:
for HorPos=LeftEdge step 1 until RightEdge:
Field[HorPos][VerPos] := unitsquare xscaled Hsize[HorPos] yscaled Vsize[VerPos] shifted (Hstep[HorPos],Vstep[VerPos]) ;
Field[VerPos][HorPos] := Field[HorPos][VerPos] ;
endfor ;
endfor ;
enddef ;
def Area = hide(SetPageArea ;) Area enddef ;
def Location = hide(SetPageLocation ;) Location enddef ;
def Field = hide(SetPageField ;) Field enddef ;
def Vsize = hide(SetPageVsize ;) Vsize enddef ;
def Hsize = hide(SetPageHsize ;) Hsize enddef ;
def Vstep = hide(SetPageVstep ;) Vstep enddef ;
def Hstep = hide(SetPageHstep ;) Hstep enddef ;
vardef FrontPageWidth = PaperWidth enddef ;
vardef BackPageWidth = PaperWidth enddef ;
vardef CoverWidth = 2 * PaperWidth + SpineWidth enddef ;
vardef CoverHeight = PaperHeight enddef ;
vardef FrontPageHeight = PaperHeight enddef ;
vardef BackPageHeight = PaperHeight enddef ;
vardef SpineHeight = PaperHeight enddef ;
def SetPagePage = path Page ; Page := unitsquare xscaled PaperWidth yscaled PaperHeight ; enddef ;
def SetPageCoverPage = path CoverPage ; CoverPage := unitsquare xscaled CoverWidth yscaled CoverHeight ; enddef ;
def SetPageSpine = path Spine ; Spine := unitsquare xscaled SpineWidth yscaled CoverHeight shifted (BackPageWidth,0) ; enddef ;
def SetPageBackPage = path BackPage ; BackPage := unitsquare xscaled BackPageWidth yscaled CoverHeight ; enddef ;
def SetPageFrontPage = path FrontPage ; FrontPage := unitsquare xscaled FrontPageWidth yscaled CoverHeight shifted (BackPageWidth+SpineWidth,0) ; enddef ;
def Page = hide(SetPagePage ;) Page enddef ;
def CoverPage = hide(SetPageCoverPage;) CoverPage enddef ;
def Spine = hide(SetPageSpine ;) Spine enddef ;
def BackPage = hide(SetPageBackPage ;) BackPage enddef ;
def FrontPage = hide(SetPageFrontPage;) FrontPage enddef ;
% pages
def StartPage =
begingroup ;
setbounds currentpicture to Page ;
enddef ;
def StopPage =
setbounds currentpicture to Page ;
endgroup ;
enddef ;
% cover pages
def StartCover =
begingroup ;
setbounds currentpicture to CoverPage enlarged PaperBleed ;
enddef ;
def StopCover =
setbounds currentpicture to CoverPage enlarged PaperBleed ;
endgroup ;
enddef ;
% overlays:
def OverlayBox =
(unitsquare xyscaled (OverlayWidth,OverlayHeight))
enddef ;
% handy
def innerenlarged =
if OnRightPage : leftenlarged else : rightenlarged fi
enddef ;
def outerenlarged =
if OnRightPage : rightenlarged else : leftenlarged fi
enddef ;
% obsolete
% def llEnlarged (expr p,d) = (llcorner p shifted (-d,-d)) enddef ;
% def lrEnlarged (expr p,d) = (lrcorner p shifted (+d,-d)) enddef ;
% def urEnlarged (expr p,d) = (urcorner p shifted (+d,+d)) enddef ;
% def ulEnlarged (expr p,d) = (ulcorner p shifted (-d,+d)) enddef ;
% def Enlarged (expr p, d) =
% (
% llEnlarged (p,d) --
% lrEnlarged (p,d) --
% urEnlarged (p,d) --
% ulEnlarged (p,d) --
% cycle
% )
% enddef ;
% for the moment we put these here:
string RuleDirection ; RuleDirection := "" ;
string RuleOption ; RuleOption := "" ;
numeric RuleWidth ; RuleWidth := 0 ;
numeric RuleHeight ; RuleHeight := 0 ;
numeric RuleDepth ; RuleDepth := 0 ;
numeric RuleH ; RuleH := 0 ;
numeric RuleV ; RuleV := 0 ;
numeric RuleThickness ; RuleThickness := 0 ;
numeric RuleFactor ; RuleFactor := 0 ;
numeric RuleOffset ; RuleOffset := 0 ;
def RuleColor = (.5white) enddef ;
def FakeWord(expr RuleWidth, RuleHeight, RuleDepth, RuleThickness) (text RuleColor) =
fill unitsquare
xscaled RuleWidth
yscaled (RuleDepth-RuleThickness/2)
withcolor RuleColor ;
fill unitsquare
xscaled RuleWidth
yscaled (RuleHeight-RuleDepth-RuleThickness/2)
shifted (0,RuleDepth+RuleThickness)
withcolor RuleColor ;
enddef ;
def FakeRule(expr RuleWidth, RuleHeight, RuleDepth, RuleThickness) (text RuleColor) =
fill unitsquare
xscaled RuleWidth
yscaled RuleHeight
withcolor RuleColor ;
enddef ;
|
