summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/public/mxedruli/xucp.mf
blob: a15d31a983e0fb1a3c99d3e195bfa2a1ceb794af (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
% Xucuri Punctuation `xucp.mf'
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Designed and (c) by Johannes Heinecke                                     %
%                     Humboldt-Universit"at zu Berlin                       %
%                     Philosophische Faskult"at II                          %
%                     Institut f"ur deutsche Sprache und Linguistik         %
%                     Computerlinguistik                                    %
%                     J"agerstr. 10/11                                      %
%                     D - 10099 Berlin                                      %
%                     <heinecke@compling.hu-berlin.de>                      %
% Please send any improvements, corrections, suggestions, enhancements etc  %
% to the Author!                                                            %
%                                                                           %
% Version 0.1 as of 30th March 1997                                         %
%                                                                           %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%


def xuc_comma (suffix $) =
    pickup xuc_pcomma;
    rt z$a = (pdot, y$);
    z$b = (0, y$-.6mxlow);
    draw z$a{down}..{dir -135}z$b;
    labels($a, $b);
enddef;



%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%% Character Definitions: %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%



%% + %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "+";
beginchar("+", mxzw#+mxone#, mxone#, 0);
    if known cmbase: adjust_fit(0,0); fi
    pickup xuc_dash;
    lft z1 = (0, .5mxone);
    z2 = (x1+mxone, y1);
    draw z1--z2;

    z3 = (.5[x1, x2], 0);
    z4 = (x3, mxone);
    draw z3--z4;

    penlabels(range 1 thru 4);
endchar;

%% = %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Equals sign =";
beginchar("=", mxzw#+1.5mxone#, mxlittle#, 0);
    pickup xuc_dash;
    lft z1 = (0, 1.5mxthird);
    z2 = (x1+1.5mxone, y1);
    z3 = (x1, 2.5mxthird);
    z4 = (x2, y3);
    draw z1--z2;
    draw z3--z4;
    penlabels(range 1 thru 4);
endchar;

%% / %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Slash /";
beginchar("/", mxzw#+1.5mxone#, mxlittle#, 0);
    pickup xuc_dash;
    z1 = (0,0);
    z2 = (1.5mxone, mxheight);
    draw z1--z2;
    penlabels(1,2);
endchar;

%% \ %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Backslash \ ";
beginchar("\", mxzw#+1.5mxone#, mxlittle#, 0);
    pickup xuc_dash;
    z1 = (0,mxheight);
    z2 = (1.5mxone, 0);
    draw z1--z2;
    penlabels(1,2);
endchar;



%% - %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "-";
beginchar("-", mxzw#+mxone#, mxlittle#, 0);
    pickup xuc_dash;
    lft z1 = (0, mxmiddle);
    z2 = (x1+mxone, y1);
    draw z1--z2;
    penlabels(range 1 thru 2);
endchar;

%% -- %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "-- (123)";
beginchar(123, mxzw#+1.5mxone#, mxlittle#, 0);
    pickup xuc_dash;
    lft z1 = (0, mxmiddle);
    z2 = (x1+1.5mxone, y1);
    draw z1--z2;
    penlabels(range 1 thru 2);
endchar;

%% --- %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "--- (124)";
beginchar(124, mxzw#+2mxone#, mxlittle#, 0);
    pickup xuc_dash;
    lft z1 = (0, mxmiddle);
    z2 = (x1+2mxone, y1);
    draw z1--z2;
    penlabels(range 1 thru 2);
endchar;

%% . %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Period .";
beginchar(".", mxzw#+mxhalf#, mxlittle#, 0);
    pickup xuc_dot;
    bot lft z1 = (0, 0);
    drawdot z1;
    penlabels(1);
endchar;

%% : %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Colon :";
beginchar(":", mxzw#+mxhalf#, mxlittle#, 0);
    pickup xuc_dot;
    lft z1 = (0, mxthird);
    lft z2 = (0, 2.5mxthird);
    drawdot z1;
    drawdot z2;
    penlabels(range 1 thru 2);
endchar;

%% ; %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Semicolon ;";
beginchar(";", mxzw#+pdot#, mxlittle#, .6mxlow#);
    pickup xuc_dot;
    bot lft z1 = (0, 0);
    z4 = (x1, y1+.5mxlittle);
    drawdot z1;
    drawdot z4;

    xuc_comma(1); 
    penlabels(range 1 thru 4);
endchar;


%% , %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Comma ,";
beginchar(",", mxzw#+pdot#, mxlittle#, .6mxlow#);
    pickup xuc_dot;
    bot lft z1 = (0, 0);
    drawdot z1;
    xuc_comma(1); 
    penlabels(range 1 thru 3);
endchar;


%% ' %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Apostroph '";
beginchar("'", mxzw#+pdot#, mxheight#, 0#);
    pickup xuc_dot;
    lft z1 = (0, mxheight);
    drawdot z1;

    xuc_comma(1); 
    penlabels(range 1 thru 3);
endchar;

%% ? %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Question mark ?";
beginchar("?", mxzw#+mxone#, mxheight#, 0);
   pickup xuc_dot;
   bot z1 = (mxhalf, 0);
   drawdot z1;

   pickup xuc_punctpen;
   z2 = (0, mxheight-.5mxtop);
   z3 = (x1, mxheight);
   z4 = (mxone, y2);
   z5 = (x1, mxmiddle);
   z6 = (x5, 1.2mxthird);

   draw z2{up}..{right}z3..{down}z4..{down}z5--z6;
   penlabels(1,2,3,4,5);
endchar;

%% ! %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Exclamation mark !";
beginchar("!", mxzw#+.5mxhalf#, mxheight#, 0);
   pickup xuc_dot;
   bot lft z1 = (0, 0);
   drawdot z1;

   z2 = (x1, mxheight-.5pdot); penpos2(pdot, 0);
   drawdot z2;
   z3 = (x1, mxmiddle); penpos3(.18mxu, 0);
   penstroke z2e..z3e;
   penlabels(1,2,3);
endchar;

%% ( %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Left parenthesis (";
beginchar("(", mxzw#+mxhalf#, 1.1mxheight#, .1mxheight#);
  z1 = (.5pdot+mxhalf, 1.1mxheight); penpos1(.18mxu, 0);
  z3 = (x1, -.1mxheight); penpos3(.18mxu, 0);
  z2 = (.5pdot, .5[y1, y3]); penpos2(pdot, 0);
  penstroke z1e..z2e..z3e;
  penlabels(range 1 thru 4);
endchar;


%% ) %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Right parenthesis )";
beginchar(")", mxzw#+mxhalf#, 1.1mxheight#, .1mxheight#);
  z1 = (0, 1.1mxheight); penpos1(.18mxu, 0);
  z3 = (x1, -.1mxheight); penpos3(.18mxu, 0);
  z2 = (mxhalf, .5[y1, y3]); penpos2(pdot, 0);
  penstroke z1e..z2e..z3e;
  penlabels(range 1 thru 4);
endchar;

%% [ %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Left bracket [";
beginchar("[", mxzw#+mxhalf#, 1.1mxheight#, .1mxheight#);
  pickup xuc_square;
  z1 = (mxhalf, -.1mxheight);
  z2 = (0, y1);
  z3 = (0, 1.1mxheight);
  z4 = (x1, y3);
  draw z1--z2--z3--z4;
  penlabels(range 1 thru 4);
endchar;

%% ] %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
xucchar "Right bracket ]";
beginchar("]", mxzw#+mxhalf#, 1.1mxheight#, .1mxheight#);
  pickup xuc_square;
  z1 = (0, -.1mxheight);
  z2 = (mxhalf, y1);
  z3 = (x2, 1.1mxheight);
  z4 = (0, y3);
  draw z1--z2--z3--z4;
  penlabels(range 1 thru 4);
endchar;


%endinput;