summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/public/euxm/euxmch.mf
blob: 129acb48f3157fb80221eb94e7b493918da8d8b6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
% EUXMCH.MF
% AMS deleted two characters that I need in Concrete Math; they
% are resuscitated here -- Don Knuth
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
more_side(0);
"smlessthanorequal";
% by DEK, not HZ!
charbegin( oct"024", 2800h#, (1430+925)*v#, (1430-925)*v#);

n := 0;

numeric a[],b[],alpha[],beta[];
pair vec[];
a6=a8=a10=2493; a7=a9=347; .5[b6,b8]=b7; .5[b6,b10]=925; b6-b8=2000;
b8-b10=b7-b9=860;
vec1=(a6,b6)-(a7,b7); vec2=(a8,b8)-(a7,b7);
vec3=unitvector vec1 rotated 90; vec4=unitvector vec2 rotated 90;
(a2,b2)=(a6,b6)+55vec3; (a3,b3)=(a6,b6)-75vec3;
(a0,b0)=(a8,b8)-75vec4; (a5,b5)=(a8,b8)+75vec4;
(a1,b1)=(a6,b6)+75vec3+alpha1*vec1=(a0,b0)+beta1*vec2;
(a4,b4)=(a3,b3)+alpha2*vec1=(a5,b5)+beta2*vec2;

adj_fill.A() % fixed x points
 () % fixed y points
 () % tied points
 () % verticals
 () % horizontals
 ((a0,b0)-- % 0
 (a1,b1)-- % 1
 (a2,b2)-- % 2
 (a3,b3)-- % 3
 (a4,b4)-- % 4
 (a5,b5)--cycle); % 5

adj_fill.B() % fixed x points
 () % fixed y points
 () % tied points
 () % verticals
 () % horizontals
 (((a10,b10)-75vec4)-- % 0
 ((a9-60,b9)-75vec4)-- % 1
 ((a9,b9)+75vec4)-- % 2
 ((a10,b10)+75vec4)--cycle); % 3

endchar(0);

"smgreaterthanorequal";
% by DEK, not HZ!
charbegin( oct"025", 2800h#, (1430+925)*v#, (1430-925)*v#);

n := 0;

numeric a[],b[],alpha[],beta[];
pair vec[];
a6=a8=a10=307; a7=a9=2453; .5[b6,b8]=b7; .5[b6,b10]=925; b6-b8=2000;
b8-b10=b7-b9=860;
vec1=(a6,b6)-(a7,b7); vec2=(a8,b8)-(a7,b7);
vec3=unitvector vec1 rotated 90; vec4=unitvector vec2 rotated 90;
(a2,b2)=(a6,b6)-55vec3; (a3,b3)=(a6,b6)+75vec3;
(a0,b0)=(a8,b8)+75vec4; (a5,b5)=(a8,b8)-75vec4;
(a1,b1)=(a6,b6)-75vec3+alpha1*vec1=(a0,b0)+beta1*vec2;
(a4,b4)=(a3,b3)+alpha2*vec1=(a5,b5)+beta2*vec2;

adj_fill.A() % fixed x points
 () % fixed y points
 () % tied points
 () % verticals
 () % horizontals
 ((a0,b0)-- % 0
 (a1,b1)-- % 1
 (a2,b2)-- % 2
 (a3,b3)-- % 3
 (a4,b4)-- % 4
 (a5,b5)--cycle); % 5

adj_fill.B() % fixed x points
 () % fixed y points
 () % tied points
 () % verticals
 () % horizontals
 (((a10,b10)+75vec4)-- % 0
 ((a9+60,b9)+75vec4)-- % 1
 ((a9,b9)-75vec4)-- % 2
 ((a10,b10)-75vec4)--cycle); % 3

endchar(0);