1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
dnl Process this file with autoconf to produce a configure script.
dnl
dnl Copyright (C) 2009 - 2011 Peter Breitenlohner <tex-live@tug.org>
dnl
dnl This file is free software; the copyright holder
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl
m4_define([gd_version], [2.0.35])[]dnl using unmodified gd source tree
AC_INIT([gd for TeX Live], gd_version, [tex-k@tug.org])
AC_PREREQ([2.65])
AC_CONFIG_SRCDIR([gd-]gd_version[/gd.c])
AC_CONFIG_AUX_DIR([../../build-aux])
AC_CONFIG_MACRO_DIR([../../m4])
AM_INIT_AUTOMAKE([foreign])
AM_MAINTAINER_MODE
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_LN_S
AC_CONFIG_HEADERS([config.h:config.hin])
LT_PREREQ([2.2.6])
LT_INIT
# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([errno.h limits.h stddef.h stdlib.h string.h unistd.h])
# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T
AC_STRUCT_TM
# Checks for library functions.
AC_SEARCH_LIBS([sin], [m], , [AC_ERROR([cannot find sin])])
KPSE_ZLIB_FLAGS
KPSE_LIBPNG_FLAGS
KPSE_FREETYPE2_FLAGS
AM_CONDITIONAL([build], [test "x$enable_build" != xno])
if test "x$enable_build" != xno || test -f config.force; then
KPSE_ADD_FLAGS([zlib])
AC_CHECK_FUNC([deflate], , [AC_ERROR([zlib not found])])
AC_CHECK_HEADERS([zlib.h], , [AC_ERROR([zlib not found])])
AC_DEFINE([HAVE_LIBZ], 1, [Define if you have zlib.])
KPSE_ADD_FLAGS([libpng])
AC_CHECK_FUNC([png_create_read_struct], , [AC_ERROR([libpng not found])])
AC_CHECK_HEADERS([png.h], , [AC_ERROR([libpng not found])])
AC_DEFINE([HAVE_LIBPNG], 1, [Define if you have the png library.])
KPSE_ADD_FLAGS([freetype2])
AC_CHECK_FUNC([FT_Init_FreeType], , [AC_ERROR([libfreetype2 not found])])
AC_CHECK_HEADERS([ft2build.h], , [AC_ERROR([libfreetype2 not found])])
AC_DEFINE([HAVE_LIBFREETYPE], 1, [ Define if you have the freetype library.])
KPSE_RESTORE_FLAGS
echo timestamp >config.force
fi
GD_TREE=gd-[]gd_version
AC_SUBST([GD_TREE])
AC_CONFIG_FILES([Makefile include/Makefile])
AC_OUTPUT
|
