summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/public/schulschriften/wesu14_sz.mf
diff options
context:
space:
mode:
Diffstat (limited to 'Master/texmf-dist/fonts/source/public/schulschriften/wesu14_sz.mf')
-rw-r--r--Master/texmf-dist/fonts/source/public/schulschriften/wesu14_sz.mf386
1 files changed, 386 insertions, 0 deletions
diff --git a/Master/texmf-dist/fonts/source/public/schulschriften/wesu14_sz.mf b/Master/texmf-dist/fonts/source/public/schulschriften/wesu14_sz.mf
new file mode 100644
index 00000000000..7144136cf50
--- /dev/null
+++ b/Master/texmf-dist/fonts/source/public/schulschriften/wesu14_sz.mf
@@ -0,0 +1,386 @@
+% Suetterlinschrift wesu
+% Program-File Sonderzeichen
+% Walter Entenmann
+% 09.06.2011
+%
+% Spitzes s ohne Verbindungsstrich, z.B. vor Apostroph
+beginchar(oct"032",10ut#,Ht#,dt#);
+ pickup wesu_pen;
+ xpos:=0;
+ spitz(xpos);
+ stamm(Ht,-dt,xpos);
+endchar;
+
+% Aufstrich vor Kleinbuchstaben am Wortanfang
+beginchar(oct"200",7ut#,ht#,0);
+ pickup wesu_pen;
+ xpos:=0;
+ gerade(ht-endx,endx-dy,1,xpos);
+endchar;
+
+% Ziffern
+Hz:=30ut; bt:=20ut; s':=5ut;
+beginchar("0",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((0,Hz){left}..(-bt/2,Hz/2){down}..(0,0){right}..(bt/2,Hz/2){up}..{left}(0,Hz)) shifted (s'+bt/2,0);
+endchar;
+
+beginchar("1",30ut#,30ut#,0);
+ pickup wesu_pen;
+ draw ((-7.5ut,ht){1,1}..{1,4}(0,Hz)--(0,0)) shifted (s'+12.5ut,0);
+endchar;
+
+beginchar("2",30ut#,Ht#,0);
+ pickup wesu_pen;
+draw ((1ut,ht-2ut)..(0,ht+1ut){up}..(bt/2,Hz){right}..(bt,ht+1ut){down}..tension2 and 3..{-1,-1}(0,0)) shifted (s',0);
+draw ((0,0){1,1}..(3bt/4,0){right}..(bt,2ut)) shifted (s',0);
+endchar;
+
+beginchar("3",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((2ut,Hz-2.5ut)..(bt/2,Hz){right}..(bt-2ut,ht+2ut){down}..(bt/2,ht-3ut){left}..(bt/2-2ut,ht-1.5ut){up}..(bt/2,ht){right}..(bt,ht/2){down}..(bt/2,0){left}..{-1,2}(0,3.5ut)) shifted (s',0);
+endchar;
+
+beginchar("4",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((15ut,Hz)--(15ut,0)) shifted (s',0);
+draw ((bt/2,Hz)--(0,7.5ut)) shifted (s',0);
+draw ((0,7.5ut){1,0.3}..(0.75bt,7.5ut){right}..(bt,8.5ut)) shifted (s',0);
+endchar;
+
+
+beginchar("5",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((1ut,ht-2ut)--(5ut,Hz){1,-0.3}..(bt-1ut,Hz)) shifted (s',0);
+draw ((1ut,ht-2ut)..(bt/2,ht){right}..(bt,ht/2){down}..(bt/2,0){left}..{-1,2}(0,3.5ut)) shifted (s',0);
+endchar;
+
+
+beginchar("6",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((bt-3ut,Hz-1.5ut){-1,0.7}..(bt/2,Hz){left}..(0,15ut){down}..(bt/2,0){right}..(bt,ht/2+1ut){up}..(bt/2,ht+2ut){left}..{-1,-5}(1ut,15ut)) shifted (s',0);
+endchar;
+
+
+beginchar("7",30ut#,Ht#,0);
+ pickup wesu_pen;
+draw ((0,Hz-1.5ut)..(5ut,Hz){right}..tension1.5..{1,2}(bt,Hz)--(5ut,0)) shifted (s',0);
+endchar;
+
+beginchar("8",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((0,Hz){left}..(-7ut,ht+4ut){down}..tension1..(0,ht-2ut)..(bt/2,ht/2-1ut){down}..(0,0){left}..(-bt/2,ht/2-1ut){up}..tension1..(0,ht-2ut)..(7ut,ht+4ut){up}..{left}(0,Hz)) shifted (s'+bt/2,0);
+endchar;
+
+
+beginchar("9",30ut#,30ut#,0);
+ pickup wesu_pen;
+draw ((bt-1ut,15ut){-1,-5}..(bt/2,8ut){left}..(0,ht-1ut){up}..(bt/2,Hz){right}..(bt,15ut){down}..(bt/2,0){left}..{-1,0.5}(3ut,2ut)) shifted (s',0);
+endchar;
+
+% ASCII-Zeichen
+beginchar("!",20ut#,40ut#,0);
+ pickup wesu_pen;
+ z1=(10ut,40ut);
+ z2=(10ut,10ut);
+ z3=(10ut,0);
+ p := z1--z2;
+ draw p;
+ pickup wesu_pen_thick;
+ drawdot z3;
+ labels(range 1 thru 3);
+endchar;
+
+% ", Doppelapostroph, hier identisch mit oct"020", dt. Anfz. o.
+beginchar(oct"042",25ut#,Ht#,0);
+ pickup wesu_pen;
+ komma(12.5ut,Ht);
+ komma(17.5ut,Ht);
+endchar;
+
+% #
+beginchar("#",50ut#,Ht#,dt#);
+ pickup wesu_pen;
+draw ((0,1.5*ht)--(0,-1.5*ht)) slanted 1/6 shifted (20ut,ht/2);
+draw ((0,1.5*ht)--(0,-1.5*ht)) slanted 1/6 shifted (20ut+10ut,ht/2);
+draw (((-ht,0)--(ht,0)) shifted (0,5ut) slanted 1/6) shifted (25ut,ht/2);
+draw (((-ht,0)--(ht,0)) shifted (0,-5ut) slanted 1/6) shifted (25ut,ht/2);
+endchar;
+
+% $
+beginchar("$",30ut#,Ht#,0);
+ pickup wesu_pen;
+ draw halfcircle xscaled 20ut yscaled 20ut shifted (15ut,30ut);
+ draw (halfcircle rotated 180 xscaled 20ut yscaled 20ut) shifted (15ut,10ut);
+ draw ((-10ut,10ut){down}..{down}(10ut,-10ut)) shifted (15ut,ht);
+ draw ((0,ht+2.5ut)--(0,-ht-2.5ut)) shifted (15ut,ht);
+endchar;
+
+% %
+beginchar("%",40ut#,Ht#,0);
+ pickup wesu_pen;
+ q := (-23.6ut,0)--(23.6ut,0);
+ breit:=12.5ut;hoch:=17.5ut;
+ p := (breit/2,0){up}..(0,hoch/2){left}..(-breit/2,0){down}..(0,-hoch/2){right}..{up}(breit/2,0);
+ x0:=whatever;y0:=whatever;
+ z0=(directionpoint (-1,2) of (subpath (0,1) of p)) shifted (7.5ut+breit/2,Ht-hoch/2);
+ draw p shifted (7.5ut+breit/2,Ht-hoch/2);
+ draw p shifted (7.5ut+25ut-breit/2,hoch/2);
+ draw q rotated 58 shifted (w/2,h/2);
+ draw z0{1,-2}..{dir 58}(7.5ut+25ut,Ht);
+ endchar;
+
+% &
+ beginchar("&",40ut#,Ht#,0);
+ pickup wesu_pen;
+ p := (22.5ut,12.5ut)..tension 1.2..(7.5ut,0){left}..(0,8ut){up}..
+ %(8.167ut,21ut){3,2}..
+ tension 1.2..(17ut,34.5ut){up}..(11.5ut,Ht){left}..(4ut,30ut){down}..{2,-3}(8.167ut,21ut)--(22.5ut,0);
+ draw p shifted (10ut,0);
+ endchar;
+
+% ยง
+ beginchar(oct"237",30ut#,Ht#,dt#);
+ pickup wesu_pen;
+ p := (7.5ut,20ut){up}..(0,30ut){left}..(-7.5ut,20ut){down}..(-2.5ut,10ut){3,-2}..tension 1.2..(7.5ut,-2.5ut){down}..{left}(2.5ut,-10ut);
+ draw p shifted (w/2,ht/2);
+ draw p rotated 180 shifted (w/2,ht/2);
+ endchar;
+
+% [
+beginchar("[",25ut#,Ht#,0);
+ pickup wesu_pen;
+ p := (5ut,Ht)--(0,Ht)--(0,0)--(5ut,0);
+ draw p shifted (10ut,0);
+ endchar;
+
+% ]
+beginchar("]",25ut#,Ht#,0);
+ pickup wesu_pen;
+ p := (-5ut,Ht)--(0,Ht)--(0,0)--(-5ut,0);
+ draw p shifted (15ut,0);
+ endchar;
+
+beginchar("'",20ut#,Ht#,0);
+ pickup wesu_pen;
+komma(12.5ut,Ht);
+endchar;
+
+beginchar("(",20ut#,Ht#,0);
+ pickup wesu_pen;
+ z1=(15ut,Ht);
+ z2=(10ut,ht);
+ z3=(15ut,0);
+ p := z1..z2{down}..z3;
+ draw p;
+ labels(range 1 thru 3);
+endchar;
+
+beginchar(")",20ut#,Ht#,0);
+ pickup wesu_pen;
+ z1=(5ut,Ht);
+ z2=(10ut,ht);
+ z3=(5ut,0);
+ p := z1..z2{down}..z3;
+ draw p ;
+ labels(range 1 thru 3);
+endchar;
+
+beginchar("*",38ut#,42.5ut#,0);
+ pickup wesu_pen;
+z3=(19ut,30ut);
+ z1=(-12.5ut,0);
+ z2=(12.5ut,0);
+ p := z1--z2;
+ draw p rotated 30 shifted z3 ;
+ draw p rotated -30 shifted z3 ;
+ draw p rotated 90 shifted z3 ;
+ labels(range 0 thru 3);
+endchar;
+
+beginchar("+",40ut#,Ht#,0);
+ pickup wesu_pen;
+z3=(20ut,12.5ut);
+ z1=(-12.5ut,0);
+ z2=(12.5ut,0);
+ p := z1--z2;
+ draw p shifted z3 ;
+ draw p rotated 90 shifted z3 ;
+ labels(range 0 thru 3);
+endchar;
+
+beginchar(",",15ut#,ht#,dt#);
+ pickup wesu_pen;
+komma(7.5ut,3.5ut);
+endchar;
+
+% Bindestrich (-), Trennstrich
+beginchar(oct"055",27.5ut#,ht#,0);
+ pickup wesu_pen;
+ z1=(0,0);
+ z2=(12.5ut,0);
+ p := z1--z2;
+ draw p shifted (7.5ut,ht/2);
+ labels(range 1 thru 2);
+endchar;
+
+% Bindestrich (-), Trennstrich
+beginchar(oct"177",27.5ut#,ht#,0);
+ pickup wesu_pen;
+ z1=(0,0);
+ z2=(12.5ut,0);
+ p := z1--z2;
+ draw p shifted (7.5ut,ht/2);
+ labels(range 1 thru 2);
+endchar;
+
+beginchar(".",15ut#,ht#,0);
+ pickup wesu_pen_thick;
+ z1=(7.5ut,0ut);
+ drawdot z1 ;
+ labels(1);
+endchar;
+
+beginchar("/",25ut#,Ht#,0);
+ pickup wesu_pen;
+ z1=(20ut,Ht);
+ z2=(5ut,0);
+ p := z1--z2;
+ draw p ;
+ labels(range 1 thru 2);
+endchar;
+
+beginchar(":",20ut#,ht#,0);
+ pickup wesu_pen_thick;
+ drawdot (0,0) shifted (10ut,0);
+ drawdot (0,0) shifted (10ut,17.5ut);
+endchar;
+
+beginchar(";",20ut#,ht#,-dt#);
+ pickup wesu_pen;
+komma(10ut,3.5ut);
+ pickup wesu_pen_thick;
+ drawdot (0,0) shifted (10ut,17.5ut);
+endchar;
+
+beginchar(">",37.5ut#,Ht#,0);
+ pickup wesu_pen;
+ z1=(7.5ut+20ut*sqrt(3)/2,12.5ut);
+ p := (0,0)--(20ut,0);
+ draw p rotated 150 shifted z1;
+ draw p rotated -150 shifted z1;
+ labels(1);
+endchar;
+
+beginchar("=",40ut#,Ht#,0);
+ pickup wesu_pen;
+p := (0,0)--(25ut,0);
+draw p shifted (7.5ut,12.5ut+3.5ut);
+draw p shifted (7.5ut,12.5ut-3.5ut);
+endchar;
+
+beginchar("<",37.5ut#,Ht#,0);
+ pickup wesu_pen;
+ z1=(7.5ut,12.5ut);
+ p := (0,0)--(20ut,0);
+ draw p rotated 30 shifted z1;
+ draw p rotated -30 shifted z1;
+ labels(1);
+endchar;
+
+beginchar("?",30ut#,Ht#,0);
+ pickup wesu_pen;
+draw ((-bt/2,ht+dt/2){up}..(0,Ht){right}..(bt/2,ht+dt/2+1ut){down}..tension1.2..(-5ut,15ut){down}..(0,ht/2){right}..(5ut,ht/2+2ut)) shifted (s'+bt/2,0);
+ pickup wesu_pen_thick;
+ drawdot (0,0) shifted (w/2,0);
+endchar;
+
+% @
+beginchar("@",50ut#,Ht#,0);
+ pickup wesu_pen;
+draw (superellipse((ata,0),(0,atb),(-ata,0),(0,-atb),sigma)) shifted (25ut,ht);
+draw ((ata,atb-2.5ut)--(ata,-atb+r){down}..(ata+r,-atb){right}..tension1.5..(ata+9ut,0){up}..(0,ht){left}..(-ata-9ut,0){down}..(0,-ht){right}..(ata+9ut,-ht+9ut)) shifted (ata+9ut+9ut,ht);
+endchar;
+
+%
+% spezielle Sonderzeichen (T1-Kodierung)
+% dt. Anfuehrungszeichen oben (\grqq), wie oct"042"
+beginchar(oct"020",25ut#,Ht#,0);
+ pickup wesu_pen;
+ komma(12.5ut,Ht);
+ komma(17.5ut,Ht);
+endchar;
+
+% dt. Anfuehrungszeichen unten (\glqq)
+beginchar(oct"022",25ut#,ht#,dt#);
+ pickup wesu_pen;
+ komma(7.5ut,3.5ut);
+ komma(12.5ut,3.5ut);
+endchar;
+
+% Bis-Strich, Gedankenstrich ( -- )
+beginchar(oct"025",40ut#,ht#,0);
+ pickup wesu_pen;
+ p :=(0,0)--(25ut,0);
+draw p shifted (7.5ut,12.5ut);
+endchar;
+
+% langer (engl.) Gedankenstrich (---)
+beginchar(oct"026",65ut#,ht#,0);
+ pickup wesu_pen;
+ p := (0,0)--(50ut,0);
+ draw p shifted (7.5ut,12.5ut);
+endchar;
+
+% franz. Anfz. << (\flqq)
+beginchar(oct"023",30ut#,ht#,0);
+ pickup wesu_pen;
+p := (0,0){dir 10}..(11.5ut,0);
+q := (0,0){dir -10}..(11.5ut,0);
+draw p rotated -60 shifted (10ut,10ut);
+draw q rotated 60 shifted (10ut,10ut);
+draw p rotated -60 shifted (15ut,10ut);
+draw q rotated 60 shifted (15ut,10ut);
+endchar;
+
+% franz. Anfz. < (\flq)
+beginchar(oct"016",25ut#,ht#,0);
+ pickup wesu_pen;
+p := (0,0){dir 10}..(11.5ut,0);
+q := (0,0){dir -10}..(11.5ut,0);
+draw p rotated -60 shifted (10ut,10ut);
+draw q rotated 60 shifted (10ut,10ut);
+endchar;
+
+
+% franz. Anfz. >> (\frqq)
+beginchar(oct"024",30ut#,ht#,0);
+ pickup wesu_pen;
+p := (0,0){dir 10}..(11.5ut,0);
+q := (0,0){dir -10}..(11.5ut,0);
+draw p rotated 120 shifted (20ut,10ut);
+draw q rotated -120 shifted (20ut,10ut);
+draw p rotated 120 shifted (15ut,10ut);
+draw q rotated -120 shifted (15ut,10ut);
+endchar;
+
+% franz. Anfz. > (\frq)
+beginchar(oct"017",25ut#,ht#,0);
+ pickup wesu_pen;
+p := (0,0){dir 10}..(11.5ut,0);
+q := (0,0){dir -10}..(11.5ut,0);
+draw p rotated 120 shifted (15ut,10ut);
+draw q rotated -120 shifted (15ut,10ut);
+endchar;
+
+% Euro (\euros)
+beginchar(oct"027",50ut#,Ht#,0);
+ pickup wesu_pen;
+ draw (halfcircle rotated 90) xscaled 30ut yscaled Ht shifted (30ut,ht);
+ draw ((0,0){right}..(10ut,-5ut)) shifted (30ut,Ht);
+ draw ((0,0){right}..(10ut,5ut)) shifted (30ut,0);
+ draw (((-27.5ut,0)--(0,0)) shifted (30ut,ht+2.5ut)) slanted 0.29;
+ draw (((-27.5ut,0)--(0,0)) shifted (30ut,ht-2.5ut)) slanted 0.29;
+ endchar;
+
+%%%%%%%%%%%%%%%% File-Ende %%%%%%%%%%%%%%%%%