rm simpsons, no info on license, seems dubious

git-svn-id: svn://tug.org/texlive/trunk@20771 c570f23f-e606-0410-a88d-b1316a301751

11 files changed, 1 insertions, 1203 deletions

diff --git a/Master/texmf-dist/fonts/source/public/simpsons/bart.mf b/Master/texmf-dist/fonts/source/public/simpsons/bart.mf
deleted file mode 100644
index f37d35cd3fe..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/bart.mf
+++ /dev/null
@@ -1,123 +0,0 @@
-% bart.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% Bart Simpson. 
- 
-pictureof(Bart, 24u#, 24u#, 0); 
-    pickup thinpen; 
- 
-    localpath eye_left, eye_right; 
-    eye_right = superellipse( (16.6u, 11.5u), (14u, 13.7u), (11.5u, 11u), 
-                (13.5u, 9u), .7); 
-    draw eye_right; 
- 
-    localpath nose; 
-    nose = preclip((15u, 10u).. (17.5u, 10.8u){right} ... 
-                   (20u, 9.7u){down} ... (16.7u, 8.2u){left}, eye_right); 
-    draw nose; 
- 
-    localpath dimple; 
-        z1d = (12.8u, 6.3u); 
-        z2d = (12.2u, 5.2u); 
-    dimple = z1d{(z2d-z1d) rotated  dimple_depth}.. 
-                {(z2d-z1d) rotated -dimple_depth}z2d; 
-    draw dimple; 
-    labels(1d, 2d); 
- 
-    localpath mouth; 
-    mouth = prepostclip( 
-           (18u, 9u).. tension infinity and 3.. 
-           (19.6u, 5.3u) .. 
-           (19u, 5u){left} .. 
-           (14.3u, 5u) .. 
-           (12u, 6.2u), nose, dimple); 
-    draw mouth; 
- 
-    eye_left = prepostclip( 
-                (18u, 9.7u){right}.. 
-                (20u, 12.2u){up}.. 
-                (18u, 14.2u){left}.. 
-                {down}(15.5u, 12u), nose, eye_right); 
-    draw eye_left; 
- 
-    % The spikes of the hair are equally spaced along a path. 
-    % (Which means they really aren't equally spaced, since speed 
-    % along a path is nonconstant.  But that's good, because 
-    % that introduces variability.) 
-    % 
-    % n is two less than the number of spikes atop Bart's head.  Although 
-    % you can choose any value you want, the official Bart has 9 spikes, 
-    % so you should set n to 7. 
-    % 
- 
-    localpath hair_top, hair_bot; 
-    local(numeric)(bumpiness, n); 
-    bumpiness = 5; n = 7; 
- 
-    z0h = (18.3u, 13u); z3h = (8.8u, 5.5u); 
-    z1h = (15.5u, 22u); z2h = (4u, 18.6u); 
-    z4h = (8.5u, 3.8u); 
- 
-    hair_top =  z1h{(z2h-z1h) rotated -bumpiness} .. 
-                   {(z2h-z1h) rotated  bumpiness}z2h; 
-    z1h' = z1h - 2u * (z1h-z0h) / length(z1h-z0h); 
-    z2h' = z2h - (2u * (z2h-z3h) / length(z2h-z3h)) rotated 10; 
-    hair_bot =  z1h'{(z2h-z1h) rotated -bumpiness} .. 
-                    {(z2h-z1h) rotated  bumpiness}z2h'; 
- 
-    % What we want is for the valleys to be equally spaced, but 50% 
-    % further from the ends. 
-    numeric t[]; 
- 
-    % The following wild macro makes t0 ... t[n] equally spaced. 
- 
-    for i = 1 upto 2n: t[i] - t[i-1] = endfor 
- 
-    % and we make them 50% further from the far endpoints 0 and 1. 
- 
-    .6(t0 - 0) = .6(1 - t[2n]); 
- 
-    % But we allow the points to vary randomly, so it doesn't look 
-    % too computerized. 
- 
-    localpath hair; 
-    hair = preclip(z0h --- z1h --- 
-            for i = 0 upto n-1: 
-                point t[2i] of hair_bot 
-                    shifted (kemptness*(normaldeviate, normaldeviate)) --- 
-                point t[2i+1] of hair_top 
-                    shifted (kemptness*(normaldeviate, normaldeviate)) --- 
-            endfor 
-                point t[2n] of hair_bot --- 
-            z2h .. tension infinity and 1 .. z3h{down} .. z4h, eye_left); 
-    draw hair; 
- 
-    numeric t; 
- 
-    localpath ear; 
-    ear = (9.5u, 8.9u) .. (8u, 7.5u) ..(9.3u, 6.5u); 
-    erase fill ear .. cycle; 
-    draw ear; 
- 
-    drawtau( (8.5u, 7.8u), (9.5u, 8.2u), (9.1u, 7u), (9.1u, 8.3u) ); 
- 
-    % chin and neck 
-    z.chin = (14.4u, 2u); 
-    draw preclip( 
-        (17u, 5u){down} .. (16u, 4u){left} .. {(-1/2, -2)}z.chin, 
-        mouth); 
- 
-    % Bart's shirt 
-    z1s = (x4h - 1.2u, 0u); 
-    z2s = z4h + (-.5u, -.8u); 
-    z3s = z.chin + (.2u, -.2u); 
-    z4s = (x.chin + .3u, 0u); 
-    draw z1s 
-    .. {z2s-z1s}z2s 
-    .. {dir -45}z4h 
-    .. (12u, 1.8u){right} 
-    ... z.chin & 
-        flex(z.chin, z3s, z4s); 
-    labels(1s, 2s, 4h); 
- 
-    eyepos(Bart, 13.5u#, 11.2u#, 17.5u#, 12u#); 
-endpicture; 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/burns.mf b/Master/texmf-dist/fonts/source/public/simpsons/burns.mf
deleted file mode 100644
index e60d2309bfe..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/burns.mf
+++ /dev/null
@@ -1,171 +0,0 @@
-% burns.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% Monty Burns. 
- 
-pictureof(Burns, 24u#, 24u#, 0); 
-    pickup thinpen; 
- 
-    localpath ear; 
-    ear = (8u, 15u) .. (6u, 15.9u) .. (4.4u, 14.5u) .. (5.5u, 12.4u) .. 
-          (6.7u, 12.8u); 
-    % We don't draw the ear until it's been clipped by Burns' sideburns. 
- 
-    localpath head; 
-    z1h = (9u, 20.6u);          % join point for Burns' hair 
-    z2h = (7u, 13u);            % terminal join point for interpathing 
-    z1e = (12u, 15u);           % beginning of Burns' eye 
-    z2e = (16u, 12u);           % end of Burns' eye 
-    z3e = (20u, 14u);           % where Burns' eyebrow might be 
-    z4e = (20.5u, 17u);         % the forward lobe of his forehead 
-    labels(1h, 2h, 1e, 2e, 3e, 4e); 
-    head = postclip( 
-           z1e                   .. tension 3 and 1 .. 
-           z2e{dir -5}           .. 
-           z3e                   .. 
-           z4e{up}               .. 
-           (16  u, 21.8u)        .. 
-           (12  u, 21.6u)        .. 
-           z1h                   .. tension 1 and 2 .. 
-           ( 5.7u, 19  u)        .. % inflection upwards slightly 
-           ( 3.7u, 16.5u){down}  .. 
-%          ( 5  u, 14  u) 
-           z2h 
-           , ear); 
- 
-% Now split the head at z1h into the forehead and the hair. 
-% Although the intersectiontimes should give us an integer, we round just 
-% in case something got lost in translation. 
- 
-    numeric t; t = round xpart(head intersectiontimes z1h); 
-    if t < 0: errmessage("Unable to find Burns' hairline"); fi 
- 
-    localpath outerhair; 
-    outerhair = subpath(t, infinity) of head; 
-    head := subpath(0, t) of head; 
- 
-    localpath innerhair;        % the inner boundary of Burns' hair, 
-                                % and his sideburns. 
-    innerhair = 
-                z1h{direction 0 of outerhair} .. 
-                (8.8u, 16u){down} .. 
-                (8.3u, 12.5u) .. 
-                (8u, 12.3u) .. tension 2 .. 
-                z2h .. tension 2 .. 
-                (8u, 16u) .. 
-                (8.5u, 18u) .. 
-           {up} z1h; 
- 
-    draw preclip(ear, innerhair);  % now the ear can be drawn 
-    drawtau( (5.2u, 14.5u), (6.7u, 15u), (6.1u, 13.4u), (6.3u, 15.5u) ); 
- 
-% Now split innerhair at z2h. 
- 
-    numeric t; t = round xpart(innerhair intersectiontimes z2h); 
-    if t < 0: errmessage("Unable to find Burns' sideburns"); fi 
- 
-    localpath interhair; 
-    interhair = reverse subpath(t, length innerhair - .5) of innerhair; 
-    innerhair := subpath(0,t) of innerhair; 
- 
-% Now we can clip the innerhair so his sideburns stop at the hairline 
-    draw innerhair; 
-    draw preclip(interhair, innerhair); 
- 
-% Now what's left of Burns' hair can be drawn 
-    for i= 0 step .3 until .8: 
-        draw prepostclip(interpath(i, outerhair, interhair), innerhair, ear); 
-    endfor 
- 
-    localpath beak; 
-    z1b = (17  u, 12.5u);            % first two beak points 
-    z2b = (20.3u,  8.5u); 
-                                    % Beak contains an inflection point 
-    beak = z1b{(z2b-z1b) rotated -5} .. z2b .. 
-           (21.6u,  6  u)       .. tension 1 and 3 .. 
-           (21.7u,  3.8u)       .. tension 3 and 3 .. 
-           (20.3u,  5.3u)       .. 
-           (18  u,  7  u)       .. 
-           (17  u,  8  u){up}   .. 
-    {right}(18.4u,  9  u); 
- 
-    draw (reverse beak) hardjoin head; 
- 
-% Now Burns' right eye. 
-    draw subpath(0,1) of head; 
-    localpath eye_bottom; 
-    eye_bottom = z1e {direction 0 of head} .. 
-                 (14.5u, 10.9u) .. {dir 40} z2e; 
-    draw eye_bottom; 
-% The bag under Burns' eye. 
-    draw (subpath(.4, 1) of eye_bottom) shifted (-.3u, -.5u); 
- 
-% Burns' left eye. 
-    draw prepostclip( 
-        (18u, 10.5u) .. (19.8u, 12u) .. (19u, 13u), 
-        beak, head); 
- 
-    localpath mouth; 
-    mouth = preclip( 
-           (18.5u, 7u) .. tension 1 and 2 .. 
-           (18u, 4.5u) .. tension 2 and 1 .. 
-           (10u, 7.8u) .. 
-           (8.2u, 7.5u), beak); 
-    draw mouth; 
- 
-if false: 
-    % back of neck 
-    localpath neck; 
-    neck = preclip( 
-        (9u, 7u){down} .. %tension .9 and 3 .. 
-        {-(1,1.5)}(7.2u, 0u), ear); 
-    draw neck; 
- 
-fi 
- 
-    % Burns' fangs, err, teeth.  Must be drawn after the chin. 
-    numeric n; n = 5; % number of teeth, minus 1 
-    % n points equally spaced. 
-    numeric t[]; 
- 
-    % The following wild macro makes t0 ... t[n] equally spaced. 
- 
-    for i = 1 upto n: t[i] - t[i-1] = endfor whatever; 
-    t0 = 1.1; t[n] = 2; 
- 
-    localpath teeth; 
-    teeth = 
-    for i = 1 upto n: 
-        hide( makelabel.top(decimal(i-1), point t[i-1] of mouth); ) 
-        bend(60, point t[i-1] of mouth, point t[i] of mouth) & 
-    endfor 
-        bend(60, point 2 of mouth, point 3 of mouth); 
-    draw teeth; 
- 
-    z1c = (13.3u, 5.5u);                % the inner cavity of the chin 
-    z2c = (9.5u, 0u);                   % the bottom tip of the neck 
-    z3c = (5.5u, 4u);                   % the bottom of the back of the neck 
-    labels(1c, 2c, 3c); 
- 
-    localpath neck; 
-    neck = prepostclip( (15u, 7u) .. z1c .. tension 2 .. z2c & 
-                    bend(20, z2c, z3c) & 
-                    z3c{dir 80}.. (6.4u, 13u), teeth, ear); 
-    draw neck; 
- 
-    % Draw Burns' suit jacket 
-    draw z3c .. {curl5} (2.5u, 0u); 
-    draw z3c .. (6u, 0u); 
- 
-    z1j = neck intersectionpoint ((0u, 3u) .. (24u, 3u)); 
-    draw z1j .. (14.3u, 0u); 
-    draw z1j .. (11.4u, 0u); 
- 
-% Burns' age spots. 
-    localpath agespot; 
-    agespot = fullcircle xscaled 1.5 scaled .4u rotated -15; 
-    draw agespot shifted (12u, 19.5u); 
-    draw agespot shifted (10.4u, 17.4u); 
-    draw agespot shifted (12.8u, 15.8u); 
- 
-    eyepos(Burns, 14.2u#, 12.1u#, 18.6u#, 12.0u#); 
-endpicture; 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/homer.mf b/Master/texmf-dist/fonts/source/public/simpsons/homer.mf
deleted file mode 100644
index 31557a6a796..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/homer.mf
+++ /dev/null
@@ -1,130 +0,0 @@
-% homer.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% Homer Simpson. 
- 
-pictureof(Homer, 24u#, 24u#, 0); 
-    pickup thinpen; 
- 
-    localpath eye_left, eye_right; 
-    eye_right = superellipse( (14.2u, 14.5u), (12.2u, 16.3u), 
-                              (10u, 14u), (12u, 12u), .7); 
-    draw eye_right; 
- 
-    localpath nose;              % extends down and around to chin 
-    nose = preclip((12u, 13u).. 
-                   (16u, 13.2u).. 
-                   (17.7u, 12.5u){down} .. 
-                   (16u, 11.5u).. 
-                   (10u, 7u){down}.. 
-                   (12.5u, 4u){right}..tension 1 and 6.. 
-                   (14.7u, 6.5u).. 
-                   (15.7u, 6.8u).. 
-                   {up}(15.7u, 8u), eye_right); 
-    localpath dimple; 
-        z1d = (11.3u, 8.1u); 
-        z2d = (10.9u, 6.8u); 
-    dimple = z1d{(z2d-z1d) rotated  dimple_depth}.. 
-                {(z2d-z1d) rotated -dimple_depth}z2d; 
-    draw dimple; 
- 
-    localpath mouth; 
-    mouth = prepostclip( 
-           (16u, 12u).. tension infinity and 3.. 
-           (17.7u, 8u){down} .. tension 2 and 1 .. 
-           (15.7u, 7.2u){left}.. 
-           (12.2u, 7.7u){left}.. 
-           (0u, 7u), nose, dimple); 
-    draw mouth; 
- 
-    nose := postclip(nose, mouth); 
-    draw nose; 
- 
-    eye_left = prepostclip( 
-                (15u, 12.6u){right}.. 
-                (17.2u, 14.5u){up}.. 
-                (15.5u, 16.4u){left}.. 
-                {down}(13.1u, 14.2u), nose, eye_right); 
-    draw eye_left; 
- 
-    localpath scalp; 
-    scalp = preclip( 
-           (16u, 15.3u) .. tension 1.5 .. 
-           (12u, 20u) .. 
-           (9.5u, 20.8u){left}.. tension 1 .. 
-           (4u, 16.4u){down} .. tension 1 .. 
-           (7.4u, 7u) .. 
-           (5.4u, 0u), eye_left); 
- 
-    % scalp and collar interact 
-    localpath collar; 
-    collar = (11.4u, 2.3u) .. tension infinity and 1 .. 
-             (7u, 4.2u) .. (6.7u, 4.7u) .. 
-             (9u, 6u) .. tension 1 and infinity .. (15.2u, 2.5u); 
-    z0c = point 0 of collar; 
-    draw postclip(scalp, collar); 
-    draw postclip(collar, scalp); 
- 
-    % the rest of the collar is also tricky 
-    numeric t; 
-    t = directiontime dir (90-starch) of collar; 
-    z1c = point t of collar; 
-    x2c = 5u; z1c - z2c = whatever * dir (90-starch); 
-    draw z1c -- z2c & reverse subpath (0,t) of collar shifted (z2c-z1c) -- z0c; 
-    y.bottom = ypart (z0c + (z2c-z1c)); 
-    numeric t; 
- 
-    % while I'm here, I may as well finish the right collar 
-    draw postclip (z0c .. (z0c + 100u * dir -machismo), 
-                   (0u,y.bottom)..(100u,y.bottom)); 
- 
-    localpath ear; 
-    ear = (7.5u, 11.5u) .. % (6.8u, 11.6u) .. 
-          (6u, 11.3u) .. 
-          (5.7u, 10u) .. (6.6u, 8.5u) .. (7.5u, 9u); 
-    erase fill ear .. cycle; 
-    draw ear; 
- 
-    drawtau( (6.2u, 10.5u), (7.4u, 11u), (6.8u, 9.3u), (6.8u, 11.1u) ); 
- 
-    % tufts on top 
-    draw postclip ( 
-      (5.2u, 17.7u){dir 100} ... (6u, 22u) ... {dir -60}(9.3u, 19.5u), scalp); 
-    localpath tuft; 
-    tuft = (6.2u, 18.7u){dir 100} ... (8u, 22.3u) ... {dir -70}(10.8u, 19.5u); 
-    draw subpath (0,1) of tuft & 
-        postclip(subpath (1,2) of tuft, scalp); 
-    numeric tuft; 
- 
-    % the tuft by the ear 
-    draw (4.5u, 11.5u) --- (4.6u, 14u) --- (6.1u, 12.2u) 
-            --- (6.4u, 14.4u) --- (7.7u, 12.5u); 
- 
-    % The interaction between the left collar and the front of the neck 
-    % is also messy. 
- 
-    % shift part of left collar 
-    localpath lcollar; 
-    z2cr = point infinity of collar; 
-    y1cr = y.bottom; z2cr - z1cr = whatever * dir machismo; 
-    lcollar = z2cr .. z1cr; 
-    draw lcollar; 
- 
-    % now the front of the neck 
-    localpath neck; 
-    neck = prepostclip( 
-            (13u, 7u){down} .. (14.7u, 0u), nose, lcollar); 
-    draw neck; 
- 
-    % now the top of the left collar 
-    draw preclip(collar, neck); 
- 
-    % and the other side of the left collar. 
-    z2cr - z3cr = 1.5u * dir machismo; 
-    z4cr - z3cr = whatever * dir (270+starch+30); 
-    z4cr - z2cr = whatever * dir (270+starch); 
-    draw z2cr -- z4cr -- z3cr; 
-    labels(1cr, 2cr, 3cr, 4cr); 
- 
-    eyepos(Homer, 11.5u#, 14u#, 15.2u#, 14.5u#); 
- 
-endpicture; 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/lisa.mf b/Master/texmf-dist/fonts/source/public/simpsons/lisa.mf
deleted file mode 100644
index 5586d4cdb99..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/lisa.mf
+++ /dev/null
@@ -1,108 +0,0 @@
-% lisa.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% Lisa Simpson. 
- 
-% Dependencies: 
-% 
-%       eye_right  dimple     tau 
-%           |        |         | 
-%         nose       |        vertical part of tau 
-%           |  \     | 
-%           |    mouth 
-%  ear   eye_left    | 
-% |   \  /  |       chin 
-% neck hair lashes  / 
-%    \            / 
-%      \        / 
-%        pearls 
-% 
-% The ordering is so that we draw the pearls as early as possible. 
- 
-pictureof(Lisa, 24u#, 24u#, 0); 
-    pickup thinpen; 
- 
-    localpath eye_left, eye_right; 
-    eye_right = superellipse( (16u, 10.1u), (14u, 12u), (11.5u, 10u), 
-                (13.75u, 8u), .7); 
-    draw eye_right; 
- 
-    localpath nose; 
-    nose = preclip((14u, 10u).. (16.5u, 8.7u){right} ... 
-                   (19.3u, 7.5u){down} ... (17u, 6.5u){left}, eye_right); 
-    draw nose; 
- 
-    localpath dimple; dimple = dimplepath( (11.8u, 6u), (10.9u, 5.5u)); 
-    draw dimple; 
- 
-    localpath mouth; 
-    mouth = prepostclip( 
-           (18.3u, 6.8u).. tension infinity and 3.. 
-           (20u, 5.6u){down} .. tension 5 and 1 .. 
-           (16u, 4.7u){left} .. 
-           (11.5u, 5.8u), nose, dimple); 
-    draw mouth; 
- 
-    localpath ear; 
-    ear = (8.5u, 7.9u) .. (7u, 6.5u) ..(8.3u, 5.5u); 
-    draw ear; 
- 
-    localpath chin; 
-            z1c = (15.7u, 5.5u); 
-            z2c = (15.5u, 4.1u); 
-            z3c = (15u, 3.6u); 
-            z4c = (13.5u, 0u); 
-    chin = preclip(z1c{down}..z2c..z3c..{z4c-z3c}z4c, mouth); 
-    draw chin; 
- 
-    localpath neck; 
-    neck = preclip((8u, 5.8u){dir -60}..{-dir 60}(8u,3.2u)..(6.75u,u), ear); 
-    draw neck; 
- 
-    % For efficiency, we draw the pearls as soon as it becomes possible. 
-    if pearl > 0: 
-    pickup lacepen; 
-    overdraw fullcircle scaled .9pearl shifted (7.5u, 2.7u); % far left 
-    overdraw fullcircle scaled .95pearl shifted (13.7u, 1.4u); % far right 
-    overdraw fullcircle scaled .95pearl shifted (8.8u, 2.3u); % left of center 
-    overdraw fullcircle scaled pearl shifted (12u, 1.5u);  % right of center 
-    overdraw fullcircle scaled pearl shifted (10.3u, 1.7u); % center 
-    pickup thinpen; 
-    fi 
- 
-    drawtau( (7.5u, 6.8u), (8.5u, 7.2u), (8.1u, 6u), (8.1u, 7.3u) ); 
- 
-    eye_left = prepostclip( 
-                (17.2u, 8.2u){right}.. 
-                (19.25u, 10.5u){up}.. 
-                (17u, 12.2u){left}.. 
-                {down}(15.3u, 10.5u), nose, eye_right); 
-    draw eye_left; 
- 
-    localpath hair; 
-    hair = prepostclip((18u, 11.3u) :: (21u, 13u) :: 
-           %(18.5u, 16u) :: 
-           (18.7u, 15.5u) :: 
-           %(19.25u, 19.25u) :: 
-           (19.5u, 19u) :: 
-           (16u, 18u) :: (14u, 21u) :: (11.6u, 18.7u) :: 
-           (8u, 20u) ..tension 3..  (7u, 17.5u) ..tension 3..  (3u, 16u) :: 
-           (4.75u, 13.75u) :: (2.5u, 11.5u) :: (4.5u, 9.5u) :: (3.3u, 7u) :: 
-           (6u, 6.7u) :: (6.5u, 4.25u) :: (8u, 5.8u), eye_left, ear); 
-    draw hair; 
- 
-    pickup lashpen; 
-    localpath lash; 
- 
-    rlash((12u, 10.5u), (11u, 11.7u), 3); 
-    rlash((12.75u, 11.25u), (12.2u, 12.8u), 3); 
-    rlash((14u, 12u), (14.2u, 13.5u), -3); 
-    rlash((15u, 11.7u), (15.5u, 12.9u), -3); 
- 
-    llash((17.0u, 12.0u), (17.6u, 13.1u), -3); 
-    llash((18.2u, 11.8u), (18.9u, 13.1u), -2); 
-    llash((18.9u, 11.4u), (19.8u, 12.1u), -2); 
-    llash((19.0u, 10.4u), (20.3u, 11.1u), -2); 
- 
-    eyepos(Lisa, 12.5u#, 9.75u#, 16.8u#, 9.75u#); 
- 
-endpicture; 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/maggie.mf b/Master/texmf-dist/fonts/source/public/simpsons/maggie.mf
deleted file mode 100644
index 700ce386a15..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/maggie.mf
+++ /dev/null
@@ -1,136 +0,0 @@
-% maggie.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% Maggie Simpson. 
- 
-pictureof(Maggie, 20u#, 20u#, 0); 
-    pickup thinpen; 
- 
-    localpath eye_right; 
-    z.eye_right = (8u, 8u);             % base for right eye 
- 
-    eye_right = (superellipse( (3.6u, 0u), (1.5u, 2u), 
-                  (-.8u, 0u), (1.5u, -2u), .7) ) shifted z.eye_right; 
-    draw eye_right; 
- 
-    localpath nose; 
-    z.nose = (12u, 4u);                 % base for nose 
-    z1n = (.8u, .9u);                   % where nose meets pacifier 
-    z1n.dir = -dir10;                   % direction through z1n 
-    z2n = (xpart z1n, -2.7u);           % bottom turn of pacifier 
-    labelsoffset(z.nose, 1n, 2n, 3n);   % Label the points 
-    nose = preclip( ( 
-            (-u, 3u) --- (1u, 3u) ..    % bridge of nose 
-            (2u, 2u) ..                 % tip 
-            z1n{z1n.dir} ..             % through here 
-            (0u, .8u) ..                % return 
-            (-1.7u, -1.4u) ..           % back of pacifier 
-            (0u, -3u) ..                % bottom of pacifier 
-            z2n ..                      % turn 
-            tension 2 .. 
-            {z1n.dir}z1n                % end of front of pacifier 
-           )shifted z.nose, eye_right); 
-    draw nose; 
- 
-    % The handle of the pacifier 
-    numeric t; t = 1.2u;                % handle thickness 
- 
-    penpos1p(t, 0);                     % hump of the bowl 
-    penpos2p(t, 90);                    % upper handle 
-    penpos3p(t,-90);                    % lower handle 
-    z1p = z.nose + (1.3u, -1u); 
-    x2p = 
-    x3p = xpart z.nose + .2u; 
-    y1p = 1/2[y2p, y3p]; 
-    y2p - y1p = .8u; 
- 
-    penlabels(1p, 2p, 3p); 
- 
-    overdraw z1p.l{up}   .. z2p.l{left} .. z2p.r{right} .. 
-             z1p.r{down} .. z3p.r{left} .. z3p.l{right} .. cycle; 
- 
-    localpath eye_left; 
-    z.eye_left = (12u, 8u); 
- 
-    eye_left = prepostclip( ( 
-                (1u, -1.3u){right}.. 
-                (2.7u, .5u){up}.. 
-                (1u, 2u){left}.. 
-                {down}(-.8u, .5u) ) shifted z.eye_left, nose, eye_right); 
-    draw eye_left; 
- 
-    localpath hair; 
-    hair = preclip( 
-           (14u, 7.5u) :: 
-           (16.2u, 8.8u) :: 
-           (15u, 9.1u) :: 
-           (17u, 11u) :: 
-           (14.7u, 11.8u) :: 
-           (15.4u, 14.4u) :: 
-           (13u, 14u) :: 
-           (10.7u, 16.4u) :: 
-           (8.7u, 13.9u) :: 
-           (5.3u, 15.5u) :: 
-           (4u, 12u) :: 
-           (1.4u, 11u) :: 
-           (2.8u, 8u) :: 
-           (1.1u, 6u) :: 
-           (4.2u, 4.5u) :: 
-           (3u, 2.5u) :: 
-           (6u, 2.6u) .. (6u, 1.5u) .. (8u, .7u){right} .. 
-           (10.3u, 1u), eye_left); 
-    z1h = point infinity of hair; 
-    draw hair; 
- 
-    % Maggie's adorable bow 
-    numeric t; t = .7u;                 % size of knot 
-    def ::: = ..tension 2 .. enddef; % for bow drawing 
-    z.bow = (11u, 13u); 
-    z1b = (-t,  t);                     %      7\      /5 
-    z2b = ( t,  t);                     %      | \    / | 
-    z3b = ( t, -t);                     %      |  1--2  | 
-    z4b = (-t, -t);                     %      |  |  |  | 
-    z5b = (3t, 2.5t);                   %      |  4--3  | 
-    z6b = (3t, -2t);                    %      | /    \ | 
-    z7b = (-3.5t, 3t);                  %      8/      \6 
-    z8b = (-3.2t, -2.5t); 
- 
-    overdraw (z2b ::: z5b ::: z6b ::: z3b -- cycle) shifted z.bow;  % right bow 
-    overdraw (z1b ::: z7b ::: z8b ::: z4b -- cycle) shifted z.bow;  % left bow 
-    overdraw (z1b ::: z2b ::: z3b ::: z4b ::: cycle) shifted z.bow; % the knot 
- 
-    labelsoffset(z.bow, 1b, 2b, 3b, 4b, 5b, 6b, 7b, 8b); 
- 
-    % Maggie's ear 
-    z.ear = (5u, 5u); 
-    draw ( (1.5u, 1u) .. (-.2u, -.4u) .. (1.5u, -1.4u) ) shifted z.ear; 
- 
-    drawtau( z.ear + (.3u, -.5u), 
-             z.ear + (1.3u, .5u), 
-             z.ear + (1u, -1.1u), 
-             z.ear + (1u, .5u) ); 
- 
-    % Maggie's chin (and mouth, sucking on the pacifier) 
-    draw postclip( 
-        ( (-.4u, .2u) .. (0,0) .. (2u, 1u) ) shifted z1h, nose); 
- 
-    % The front of the Maggie baggie 
-    draw bend(20, z1h, (.3u + xpart z1h, 0)); 
- 
-    % The back of the Maggie baggie 
-    draw postclip( 
-        (4.2u, 0u){dir 60} .. {dir 45}(5.5u, 2.5u), hair); 
- 
-    pickup lashpen; 
-    localpath lash; 
- 
-    rlash( (0  u,  .8u), (-.6u, 1.8u), 0); 
-    rlash( (1  u, 1.6u), ( .8u, 2.4u), 0); 
-    rlash( (2.5u, 1.5u), (2.7u, 2.2u), 0); 
- 
-    llash( ( .5u, 1.9u), ( .4u, 2.3u), 0); 
-    llash( (1.8u, 1.9u), (1.9u, 2.3u), 0); 
-    llash( (2.5u, 1.5u), (2.7u, 1.8u), 0); 
- 
-    eyepos(Maggie, 9.2u#, 8.1u#, 12.7u#, 8.1u#); 
- 
-endpicture; 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/marge.mf b/Master/texmf-dist/fonts/source/public/simpsons/marge.mf
deleted file mode 100644
index 35f88979972..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/marge.mf
+++ /dev/null
@@ -1,136 +0,0 @@
-% marge.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% Marge Simpson. 
- 
-pictureof(Marge, 22u#, 40u#, 0); 
-    pickup thinpen; 
- 
-    localpath eye_left, eye_right; 
-    eye_right = superellipse( (15.5u, 11.5u), (13.5u, 13.5u), (11.2u, 11.3u), 
-                (13.5u, 9.5u), .7); 
-    draw eye_right; 
-    localpath nose; 
-    nose = preclip((15u, 10.5u).. 
-                   (16.3u,10.1u) .. 
-                   (18  u,10  u){right} .. 
-                   (18.8u, 9.5u){down} ... 
-          {-dir 30}(17  u, 8  u), eye_right); 
-    draw nose; 
- 
-    localpath dimple; 
-        z1d = (12.5u, 7.4u); 
-        z2d = (11.8u, 6.8u); 
-    dimple = z1d{(z2d-z1d) rotated  dimple_depth}.. 
-                {(z2d-z1d) rotated -dimple_depth}z2d; 
-    draw dimple; 
-    labels(1d, 2d); 
- 
-    localpath mouth; 
-    mouth = prepostclip( 
-           (17u, 8.8u).. tension infinity and 3.. 
-           (19.6u, 7.5u) .. 
-           (17u, 6.5u){left} .. 
-           (14u, 7u) .. 
-           (12u, 7.1u), nose, dimple); 
-    draw mouth; 
- 
-    eye_left = prepostclip( 
-                (17u, 9.7u){right}.. 
-                (19u, 12u){up}.. 
-                (17u, 13.6u){left}.. 
-                {down}(14.7u, 11u), nose, eye_right); 
-    draw eye_left; 
- 
-    localpath ear; 
-    ear = (9.5u, 9.6u) .. (8.1u, 8.3u) ..(10u, 6.9u); 
-    draw ear; 
- 
-    drawtau( (8.7u, 8.5u), (9.7u, 8.9u), (9.3u, 7.7u), (9.3u, 9.0u) ); 
- 
-    % chin 
-    draw preclip( 
-        (16.3u, 6.5u){down} .. 
-        (16u, 6u){-dir30} .. 
-        (15u, 4u){down} .. 
-        (16.5u, 0u), 
-        mouth); 
- 
-    % back of neck 
-    localpath neck; 
-    neck = preclip( 
-        (9u, 7u){down} .. %tension .9 and 3 .. 
-        {-(1,1.5)}(7.2u, 0u), ear); 
-    draw neck; 
- 
-    if pearl > 0: 
-    pickup lacepen; 
-    overdraw fullcircle scaled .9pearl shifted (8.7u, 3u); % far left 
-    overdraw fullcircle scaled .95pearl shifted (15u, 2u); % far right 
-    overdraw fullcircle scaled .95pearl shifted (10.1u, 2.2u); % left of center 
-    overdraw fullcircle scaled pearl shifted (13.3u, 1.9u);  % right of center 
-    overdraw fullcircle scaled pearl shifted (11.6u, 1.8u); % center 
-    pickup thinpen; 
-    fi 
- 
-    % Marge's beehive 'do 
-    draw preclip( puffhair( 
-        (18.3u, 12.6u), %  1 
-        (18.6u, 16.5u), %  2 
-        (18.6u, 19  u), %  3 
-        (17.8u, 22.8u), %  4 
-        (17  u, 26  u), %  5 
-        (16  u, 29  u), %  6 
-        (14.8u, 32.7u), %  7 
-        (13  u, 35  u)),%  8 
-    eye_left); 
- 
-    curlers := curlers + 10;  % more curliness on top 
- 
-    draw puffhair( 
-        (13  u, 35  u), %  1 
-        (10  u, 37  u), %  2 
-        ( 6  u, 37  u), %  3 
-        ( 4  u, 35  u), %  4 
-        ( 2.6u, 32  u), %  5 
-        ( 3.3u, 28  u));%  6 
- 
-    curlers := curlers - 10; % back to normal curliness 
-    draw postclip( puffhair( 
-        ( 3.3u, 28  u), %  1 
-        ( 5.2u, 25.2u), %  2 
-        ( 6.3u, 22.6u), %  3 
-        ( 6.5u, 18.5u), %  4 
-        ( 6.1u, 14.4u), %  5 
-        ( 6.4u, 11.1u), %  6 
-        ( 7.3u,  8.7u), %  7 
-        ( 9.3u,  6  u)),%  8 
-    neck); 
- 
-    % And the hairline above her eyes 
-   draw postclip( puffhair( 
-       ( 9.5u,  9.6u), %  1 
-       ( 9.5u, 12.2u), %  2 
-       (10  u, 14.3u), %  3 
-       (11.7u, 15  u), %  4 
-       (13.8u, 15  u), %  5 
-       (16.5u, 15.2u), %  6 
-       (17.9u, 14.1u), %  7 
-       (18.3u, 12.6u)),%  8 
-    eye_left); 
- 
-    % And finally, the eyelashes 
-    pickup lashpen; 
-    localpath lash; 
- 
-    rlash((12.0u, 12.5u), (11.8u, 14.0u), 3); 
-    rlash((13.0u, 13.2u), (13.0u, 14.4u), 2); 
-    rlash((14.1u, 13.2u), (14.2u, 14.4u),-2); 
-    rlash((14.9u, 12.8u), (15.5u, 14.2u),-3); 
- 
-    llash((16.5u, 13.4u), (16.6u, 14.3u),-1); 
-    llash((17.3u, 13.4u), (17.6u, 14.4u),-2); 
-    llash((18.0u, 13.0u), (18.5u, 14.4u),-3); 
-    llash((18.7u, 13.0u), (19.6u, 13.9u),-3); 
- 
-    eyepos(Marge, 12.5u#, 11.4u#, 16.5u#, 11.7u#); 
-endpicture; 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/simpsons.mf b/Master/texmf-dist/fonts/source/public/simpsons/simpsons.mf
deleted file mode 100644
index 7a1f991f85b..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/simpsons.mf
+++ /dev/null
@@ -1,309 +0,0 @@
-% simpsons.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-mode_setup; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Parameters (and typical values) 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Pen control 
-% 
-% u#            the basic unit. 
-%               A choice of 1/16in# makes Lisa fit into a 1.5" square. 
-% 
-% thin#         The pen used for everything, unless otherwise noted. 
-%               A value of 1/18u# produces a razor-sharp-ish pen, 
-%               good for low resolution work (and which scales nicely). 
-%               But a value of 1/9u# produces a slightly thicker line 
-%               which might show up better. 
-%               And a value of 1/5u# produces a heavy pen, more in keeping 
-%               with MG's drawing style. 
-% 
-% fine#         For fine detail, like the atom logo on the SNPP cooling tower. 
-% 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Physical attributes for everybody 
-% 
-% tau_top       Curviness of the top part of the little `t' that 
-%               forms the ridges inside the ear.  Recommend 45. 
-% 
-% tau_side      Curviness of the side part of the little `t' that 
-%               forms the ridges inside the ear.  Recommend 45. 
-% 
-% dimple_depth  Amount of curve (in degrees) to give the dimple. 
-%               Positive value makes the cheeks puffier. 
-%               Negative value makes the dimple deeper. 
-%               Recommend -10. 
-% 
-% innocence#    Size of pupils.  Suggest 0.5u#. 
-% 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Controls for the ladies 
-% 
-% lace#         The pen used for necklaces.  Recommend = thin#. 
-% 
-% pearl#        Size of pearls in the necklace.  Set pearl < 0 
-%               to suppress the necklace altogether. 
-%               Recommend 1.9u#. 
-% 
-% mascara       Thickness of the eyelashes, relative to thin#. 
-%               1.5 means eyelashes are 1.5 times thicker than regular strokes. 
-%               Recommend a value of 1.0. 
-% 
-% seductiveness Curliness of the eyelashes.  In degrees.  Suggest 5. 
-% 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Controls for the kids 
-% 
-% spikiness     Controls spikiness (tension) of Lisa and Maggie's hair. 
-%               Lower numbers make it wavier, 
-%               higher numbers make it spikier.  5 seems about right. 
-% 
-% kemptness#    How uniform the spikes of Bart's hair are. 
-%               Higher values make Bart's hair more erratic. 
-%               A value of 0 makes them perfectly evenly spaced. 
-%               I think 0.05u# looks about right. 
-% 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Controls for Homer 
-% 
-% starch        How much Homer's collar points flare outwards. 
-%               Larger values make Homer's collar stick out more. 
-%               In degrees 0..90.  Recommend 30. 
-% 
-% machismo      How much the front of Homer's shirt opens. 
-%               Larger values make it more open.  Degrees 0..90. Recommend 60. 
-% 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Controls for Marge 
-% 
-% curlers       How large to make the `bumps' the make up Marge's hair. 
-%               In degrees.  Suggest 30. 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-u# = 1/80in#; 
-%thin# = 1/9 u#;         % heavy lines 
-thin# = 1/5 u#;        % realistically heavy 
-fine# = 1/9u#; 
- 
-tau_top := 45; 
-tau_side := 45; 
-dimple_depth = -10; 
-innocence# := .5u#; 
- 
-lace# = thin#; 
-pearl# = 1.9u#; 
-mascara = 1.0; 
-seductiveness := 7; 
- 
-spikiness := 5; 
-kemptness# := 1/20u#; 
- 
-starch := 30; 
-machismo := 60; 
- 
-curlers := 30; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Preparing to do business 
- 
-define_pixels(u, pearl, innocence, kemptness); 
-define_whole_blacker_pixels(thin, fine, lace); 
- 
-pickup pencircle scaled thin; thinpen = savepen; 
-pickup pencircle scaled fine; finepen = savepen; 
-pickup pencircle scaled (thin * mascara); lashpen = savepen; 
-pickup pencircle scaled lace; lacepen = savepen; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Private macros 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-def openit =                            % so screen previewing works better 
-    openwindow currentwindow from origin to (screen_rows, screen_cols) 
-    at (0, screen_rows-1) enddef; 
- 
-def :: = ..tension spikiness.. enddef;     % For drawing the kids' spiky hair. 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% preclip     -- clips the path p to start at q. 
-% postclip    -- clips the path p to end at r. 
-% prepostclip -- clips the path p to start at q and end at r. 
-% hardjoin    -- start on p and end on q, transition when they intersect 
- 
-def preclip(expr p,q)= 
-    subpath (xpart(p intersectiontimes q), infinity) of p enddef; 
-def postclip(expr p, r) = reverse preclip(reverse p, r) enddef; 
-def prepostclip(expr p, q, r) = postclip(preclip(p, q), r) enddef; 
- 
-secondarydef p hardjoin q = 
-    begingroup dz_ := p intersectiontimes q; 
-        subpath (0, xpart dz_) of p .. subpath(ypart dz_, infinity) of q 
-    endgroup enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Drawing bent lines (i.e., shallowly curved).. Positive theta curves 
-% to the left, negative to the right. 
- 
-vardef bend(expr theta, p, q) = 
-    p{(q-p) rotated  theta}.. 
-     {(q-p) rotated -theta}q enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Drawing opaquely 
-def overdraw expr c = erase fill c; draw c enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Labelling shifted points 
-vardef labelsoffset@#(expr offset)(text t) = 
-    if proofing > 1: forsuffixes $=t: makelabel@#(str$, z$+offset); endfor 
-    fi enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Facial features 
- 
-def dimplepath(expr p, q) =             % top coordinate first 
-    if proofing>1: hide( makelabel("", p); makelabel("", q); ) fi 
-%    p{(q-p) rotated  dimple_depth}.. 
-%     {(q-p) rotated -dimple_depth}q 
-    bend(dimple_depth, p, q) 
-enddef; 
- 
-%   _s__q 
-% p/ | 
-%    | 
-%     \r 
- 
-def drawtau(expr p, q, r, s) = 
-    if proofing>1: makelabel("p", p); makelabel("q", q); 
-                   makelabel("r", r); makelabel("s", s); fi 
-    c_ := p{(q-p) rotated tau_top}..q; 
-    draw c_; 
-%    draw postclip( (r{(s-r) rotated tau_side}.. 
-%                     {(s-r) rotated -tau_side}s), c_) enddef; 
-    draw postclip( bend(tau_side, r, s), c_) enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Eyelashes either bend clockwise or counter-clockwise as they leave 
-% the eye. 
-% 
-% p = starting point, q = ending point, d = delta 
-%   d>0 = curves right, d<0 = curves left.  Bigger d means more curve. 
- 
-def makelash(expr ofs,p,q,d) = 
-    if proofing>1: hide( makelabel("", ofs+p); makelabel("", ofs+q); ) fi 
-    bend(d*seductiveness, ofs+p, ofs+q) enddef; 
- 
-% Right lashes clip to the right eye, left lashes to the left eye_ 
-vardef rlash@#(expr p,q,d) = 
-    lash@# := preclip(makelash( 
-                      if known z.eye_right: z.eye_right else:origin fi, p,q,d), 
-                      eye_right); 
-    draw lash@# enddef; 
-vardef llash@#(expr p,q,d) = 
-    lash@# := preclip(makelash( 
-                      if known z.eye_left: z.eye_left else:origin fi, p, q, d), 
-                      eye_left); 
-    draw lash@# enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Marge's hair contains little puffs. 
- 
-def puffhair(text t) =                  % t is a list of pairs 
-    hide( n_ := 0; for z=t: z_[incr n_] := z; 
-          if proofing>1: makelabel(decimal n_, z); fi endfor) 
-    z_1 
-        for k = 2 upto n_: 
-            {(z_[k] - z_[k-1]) rotated -curlers} .. 
-            {(z_[k] - z_[k-1]) rotated  curlers} z_[k] 
-        endfor enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Character positions 
- 
-def simpdochar(expr c, ht, wd, dp, name) = 
-    beginchar(c, ht, wd, dp); name enddef; 
- 
-string current_char_name; 
-def pictureof(suffix c)(expr wd, ht, dp) = 
-   beginchar(2c, wd, ht, dp); 
-    current_char_name := str c; 
-    current_char_name & " looking right, no pupils" enddef; 
- 
-def endpicture = 
-    pic_ := currentpicture; 
-    endchar; 
- 
-    beginchar(incr charcode, charwd, charht, chardp); 
-    current_char_name & " looking left, no pupils"; 
-    currentpicture := pic_ reflectedabout ((.5w, 0), (.5w, h)); 
-    endchar; 
-    pic_ := nullpicture enddef; 
- 
-def unreflectedpictureof(suffix c)(expr wd, ht, dp) = 
-    beginchar(c, wd, ht, dp); str c enddef; 
- 
-let unreflectedendpicture = endchar; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Draw grid marks during proofing 
- 
-def makebox(text rule) = 
-    for y = 0 step 4u.o_ until charht*hppp: 
-        rule((0, y), (w, y)); 
-    endfor 
-    rule((0, charht*hppp), (w, charht*hppp)); 
-    rule((0, chardp*hppp), (w, chardp*hppp)); 
- 
-    for x = 0 step 4u until charwd*hppp: 
-        rule ((x, -d.o_), (x, h.o_)); 
-    endfor 
-    rule ((charwd*hppp, -d.o_), (charwd*hppp, h.o_)); 
-enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Eye positions 
-% 
-% Eye positions are stored in the fontdimens. 
- 
-def eyepos(expr p, a, b, c, d) = fontdimen 4 + 4p: a, b, c, d enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% Local variables 
- 
-def local(text t, v) = 
-    forsuffixes $=v: save v; t v; endfor enddef; 
- 
-def localpath text v = local(path)(v) enddef; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-Lisa = 1; 
-Homer = 2; 
-Bart = 3; 
-Marge = 4; 
-Maggie = 5; 
-Burns = 6; 
- 
-proofing:=2; 
-% screenstrokes; 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-beginchar(0, 0, innocence#, 0); "A pupil (no width)"; 
-    fill fullcircle scaled innocence; 
-endchar; 
- 
-% and character 1 is SNPP. 
-input snpp 
- 
-%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% 
-% The x-height is 1pt.  The purpose of this is so that pupil positioning 
-% can be done in ex-units, which will therefore scale properly if the 
-% font is loaded at nonstandard magnifications. 
- 
-fontdimen 5: 1pt#; 
- 
-input lisa 
-input homer 
-input bart 
-input marge 
-input maggie 
-input burns 
-end 
diff --git a/Master/texmf-dist/fonts/source/public/simpsons/snpp.mf b/Master/texmf-dist/fonts/source/public/simpsons/snpp.mf
deleted file mode 100644
index 2b03af17ae9..00000000000
--- a/Master/texmf-dist/fonts/source/public/simpsons/snpp.mf
+++ /dev/null
@@ -1,89 +0,0 @@
-% snpp.mf by Raymond Chen (rjc@math.princeton.edu) 
- 
-% The SNPP logo. 
- 
-beginchar(1, 8u#, 8u#, 0); "Springfield Nuclear Power Plant"; 
- 
-    % We will need 8 symmetrically paired points 
-    forsuffixes $=range 1 thru 8: x$ = w - x$'; y$ = y$'; endfor 
- 
-    pickup thinpen; 
-    save u; u = w/8;                    % IMPORTANT! 
-    save v; v = h/8;                    % IMPORTANT! 
- 
-    z0 = (4u, 4v);                      % = 1/2(w,h), the center. 
- 
-    % The circular seal 
-    numeric r; r = y0; 
-    draw fullcircle scaled 2r shifted z0; 
- 
-    % The cooling tower 
- 
-    localpath tower; 
- 
-    z1 = (2.2u, 4v); 
-    z2 = (2.5u, 3.5v); 
-    z3 = (1.7u, 0); 
- 
-    tower = z3 .. tension 3 .. z2 .. 
-        z1{up} .. tension 3 .. z1'{down} .. 
-            z2'.. tension 3 .. z3'; 
-    draw prepostclip(tower, quartercircle scaled 2r rotated 180 shifted z0, 
-                            quartercircle scaled 2r rotated -90 shifted z0); 
- 
-    % The atom logo 
-    % The ellipse is 2u by .5u. 
-    x4 = .5w; 
-    y4 + u * sind 60 = y2; 
- 
-    pickup finepen; 
-    draw fullcircle xscaled 2u yscaled .5v shifted z4; 
-    draw fullcircle xscaled 2u yscaled .5v rotated 60 shifted z4; 
-    draw fullcircle xscaled 2u yscaled .5v rotated-60 shifted z4; 
-    pickup thinpen; 
- 
-    % The rising fumes 
-    z5 = (.5w - .8u, 6v); 
-    z5 - z5a = z5a - z5b = z5b - z5';       % equally spaced 
-    y5a := y5a + .3v; 
-    y5b := y5b - .3v; 
- 
-    forsuffixes $=,a,b,': draw preclip( (x5$,0) .. z5$, tower); endfor 
- 
-    % The outer cloud 
-    localpath cloud; 
-    y6 = y5; 
-    x6 = xpart z0 - (r +-+ (y6-y0));        % length(z0 - z6) = r 
- 
-    cloud = bend(-30, z6, z6'); 
- 
-    localpath puffcloud; 
-    numeric n; n = 13; 
-    puffcloud = 
-            point 0 of cloud 
-    for k = 1 upto n: 
-            {direction (k+.5)/n of cloud rotated -80} .. 
-            {direction (k+.5)/n of cloud rotated  80} point k/n of cloud 
-        endfor; 
- 
-    draw postclip(puffcloud, (x5, 0) .. z5); 
-    draw preclip(puffcloud, (x5', 0) .. z5'); 
- 
-    % the inner cloud 
-    y7 = h - v; 
-    x7 = 1/3[x5, x6]; 
- 
-    cloud := bend(-20, z7, z7'); 
-    n := 5; 
-    draw 
-            point 0 of cloud 
-    for k = 1 upto n: 
-            {direction (k+.5)/n of cloud rotated -80} .. 
-            {direction (k+.5)/n of cloud rotated  80} point k/n of cloud 
-        endfor; 
- 
-    labels(1', 2', 3', 4', 5', 6', 7'); 
-    labels(range 0 thru 7); 
-endchar; 
- 
-endinput 
diff --git a/Master/tlpkg/libexec/ctan2tds b/Master/tlpkg/libexec/ctan2tds
index 8068cf93357..655b74a6da0 100755
--- a/Master/tlpkg/libexec/ctan2tds
+++ b/Master/tlpkg/libexec/ctan2tds
@@ -670,6 +670,7 @@ $Master = "$mydir/../..";
  'showexpl',	"&MAKEflatten",
  'siam',	"die 'skipping, nonfree license'",
  'siggraph',	"die 'skipping, nonfree license'",
+ 'simpsons',	"die 'skipping, noinfo license'",
  'skak',	"&MAKEflatten",
  'slidenotes',	"die 'skipping, nonfree'",
  'smflatex',	"die 'skipping, nosource'",
diff --git a/Master/tlpkg/tlpsrc/collection-fontsextra.tlpsrc b/Master/tlpkg/tlpsrc/collection-fontsextra.tlpsrc
index 493192ff54f..e55b906050e 100644
--- a/Master/tlpkg/tlpsrc/collection-fontsextra.tlpsrc
+++ b/Master/tlpkg/tlpsrc/collection-fontsextra.tlpsrc
@@ -130,7 +130,6 @@ depend romande
 depend sauter
 depend sauterfonts
 depend semaphor
-depend simpsons
 depend skull
 depend staves
 depend starfont
diff --git a/Master/tlpkg/tlpsrc/simpsons.tlpsrc b/Master/tlpkg/tlpsrc/simpsons.tlpsrc
deleted file mode 100644
index e69de29bb2d..00000000000
--- a/Master/tlpkg/tlpsrc/simpsons.tlpsrc
+++ /dev/null