summaryrefslogtreecommitdiff
path: root/language/arabic/arabtex/mfinput/nashdia.mf
blob: e4616d771104993ccee785a568c7ed5ac47b811d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
%%%%%%%%%%%%%%%%%%%%%%% nashdia.mf %%%%%%%%%%%%%%%%%%%%%%%%%%%%
% NASH Font
% 14.03.92
% 03.11.96
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% (c) Klaus Lagally
%     Institut fuer Informatik
%     Universitaet Stuttgart
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

if unknown nashbase: input nashbase fi;

%%%%%%%%%%%%%% diacritics %%%%%%%%%%%%%%%%%

diachar(damma, 4, 5);
z1 = z.l; x2 = 3dx; y2 = y.r; x3 = x.r; y3 = 2dy;
draw z1{dir 30}..z2{left}..z3{dir -45};
endchar;

diachar(fatha, 4, 2.5);
draw z.l--z.r;
endchar;

diachar(sukun, 4, 4);
%draw (.5w, y.l)..(.5w, y.r)..cycle;
%draw (.5w, y.r){dir -35}..(.5w, y.l){left}..{dir 35}(.5w, y.r);
%draw (.5w, y.r){dir -45}..(.5w, y.l){left}..{dir 45}(.5w, y.r);
draw (.5w, y.r){dir -45}..(.5w, y.l){left}..{dir 30}(.5w, y.r);
endchar;

diachar(dammatan, 5, 5);
x4 = x.l; x5 = x1 = dx; y4 = y5 = 3dy; y1 = y.l;
x2 - x.l = 3dx; y2 = y.r; x3 = x.r; y3 = 2dy;
draw z1{dir 30}..z2{left}..z3{dir -45};
draw z4..z5..z1{down};
endchar;

diachar(fathatan, 4, 4.5);
x1 = x.r; x2 = x.l; y1 = y.r - 2dy; y2 = y.l + 2dy;
draw z.l--z1; draw z2--z.r;
endchar;

diachar(hamza, 4, 5);
x1 = x.r; x2 = x.l; x3 = x.r -  dx;
y1 = 2dy; y2 = 2.5dy; y3 = y.r - .5dy;
draw z.l--z1;
draw z3{left}..z2..z1{z1-z.l};
endchar;

diachar(shadda, 5, 3);
z5 - z3 = z3 - z1 = z4 - z2 = whatever * (4dx, dy);
z5 = z.r; x1 = x.l; y2 = y.l; x2 = .5[x1, x3];
draw z1{down}..z2..z3{up}; draw z3{down}..z4..z5{up};
endchar;

diachar(quran_alif, 2, 5);
x1 = x.l; x2 = .5[x.l, x.r];
y1 = y.r; y2 = y.l;
draw z1--z2;
endchar;

diachar(wasla, 6, 2);
x1 - .4w = x2 - .7w = x4 - .7w = x5 = dx; x3 = x.r + dx;
%x1 = .4w; x2 = x4 = .7w; x3 = x.r;
y1 = y3 = h/2; y2 = y.l; y4 = y5 = y.r;
draw z5..z1..z2..z3..z4..z1;
endchar;

diachar(madda, 6, 1.5);
%x.r - x2 = x1 - x.l = .25(x.r - x.l);
%y1 = y.r; y2 = y.l;
%draw z.l..z1..z2..z.r;
x.r - x2 = x1 - x.l = .1(x.r - x.l);
y1 = y.r + dy; y3 = y2 = y.l; x3 = x.r; 
draw z.l--z1..z2..z3;
endchar;

diachar(ttah_dia, 4, 5);
z1 = z.l; x2 = x4 = dx; y2 = dy; y4 = y.r; x3 = x.r; y3 = 2dy;
draw z1{dir 45}..z2..z3..z1{left}; draw z2..z4;
endchar;

arabchar(one_dot_up, 0, 2, 4, -2);
one_dot(1);
endchar;

arabchar(two_dots_up, 0, 5, 4, -2);
two_dots(1);
endchar;

arabchar(three_dots_up, 0, 5, 7, -2);
three_dots(1);
endchar;

arabchar(two_dots_down, 0, 5, 2, 0);
two_dots(1);
endchar;

arabchar(three_dots_down, 0, 5, 2, 3);
three_dots_low(1);
endchar;

diachar(bow_dia, 4, 2);
draw (x.l,y.r)..(.5w, y.l)..z.r;
endchar;

diachar(e_dia, 4, 2.5);
draw z.l--(x.r,y.l);
endchar;

diachar(h_dia, 4, 5);
x1 = x2 = x3 = .5w;
y1 = y.r; y2 = y.l; y3 = .2[y2,y1];
draw z1{z.l-z1}..z2{right}..z3{left};
endchar;

%%%%%%%%%%%%%% EOF %%%%%%%%%%%%%%%%%