summaryrefslogtreecommitdiff
path: root/graphics/asymptote/tests/template/imports/sortedset.asy
blob: bcef6889e016e7a7715a27dd1e363843026ab3bb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
typedef import(T);

from "template/imports/pureset"(T=T) access Set_T, operator cast, makeNaiveSet;

struct SortedSet_T {
  int size();
  bool empty() { return size() == 0; }
  bool contains(T item);
  T get(T item);         // Returns the item in the collection that is
                         // equivalent to item, or emptyresponse if there is no
                         // such item.
  // Returns the least element > item, or emptyresponse if there is no such
  // element.
  T after(T item);
  // Returns the greatest element < item, or emptyresponse if there is no such
  // element.
  T before(T item);
  T firstGEQ(T item) { return contains(item) ? get(item) : after(item); }
  T firstLEQ(T item) { return contains(item) ? get(item) : before(item); }
  T min();               // Returns emptyresponse if collection is empty.
  T popMin();            // Returns emptyresponse if collection is empty.
  T max();               // Returns emptyresponse if collection is empty.
  T popMax();            // Returns emptyresponse if collection is empty.
  bool insert(T item);   // Returns true iff the collection is modified.
  T replace(T item);     // Inserts item, and returns the item that was
                         // replaced, or emptyresponse if no item was replaced.
  bool delete(T item);   // Returns true iff the collection is modified.
  // Calls process on each item in the collection, in ascending order,
  // until process returns false.
  void forEach(bool process(T item));
}

T[] operator cast(SortedSet_T set) {
  T[] result;
  set.forEach(new bool(T item) {
                result.push(item);
                return true;
              });
  return result;
}

Set_T unSort(SortedSet_T sorted_set) {
  Set_T set = new Set_T;
  set.size = sorted_set.size;
  set.empty = sorted_set.empty;
  set.contains = sorted_set.contains;
  set.insert = sorted_set.insert;
  set.replace = sorted_set.replace;
  set.get = sorted_set.get;
  set.delete = sorted_set.delete;
  set.forEach = sorted_set.forEach;
  return set;
}

Set_T operator cast(SortedSet_T) = unSort;

// For testing purposes, we provide a naive implementation of SortedSet_T.
// This implementation is highly inefficient, but it is correct, and can be
// used to test other implementations of SortedSet_T.
struct NaiveSortedSet_T {
  private bool lt(T a, T b);
  private T[] buffer = new T[0];
  private T emptyresponse;

  private bool leq(T a, T b) {
    return !lt(b, a);
  }
  private bool gt(T a, T b) {
    return lt(b, a);
  }
  private bool geq(T a, T b) {
    return leq(b, a);
  }
  private bool equiv(T a, T b) {
    return leq(a, b) && leq(b, a);
  }

  void operator init(bool lessThan(T, T), T emptyresponse) {
    this.lt = lessThan;
    this.emptyresponse = emptyresponse;
  }

  int size() {
    return buffer.length;
  }

  bool contains(T item) {
    for (T possibility : buffer) {
      if (equiv(possibility, item)) return true;
    }
    return false;
  }

  T after(T item) {
    for (T possibility : buffer) {
      if (gt(possibility, item)) return possibility;
    }
    return emptyresponse;
  }

  T before(T item) {
    for (int ii = buffer.length - 1; ii >= 0; --ii) {
      T possibility = buffer[ii];
      if (lt(possibility, item)) return possibility;
    }
    return emptyresponse;
  }

  T min() {
    if (buffer.length == 0) return emptyresponse;
    return buffer[0];
  }

  T popMin() {
    if (buffer.length == 0) return emptyresponse;
    T toreturn = buffer[0];
    buffer.delete(0);
    return toreturn;
  }

  T max() {
    if (buffer.length == 0) return emptyresponse;
    return buffer[buffer.length - 1];
  }

  T popMax() {
    if (buffer.length == 0) return emptyresponse;
    return buffer.pop();
  }

  bool insert(T item) {
    for (int i = 0; i < buffer.length; ++i) {
      if (equiv(buffer[i], item)) return false;
      else if (gt(buffer[i], item)) {
        buffer.insert(i, item);
        return true;
      }
    }
    buffer.push(item);
    return true;
  }

  T replace(T item) {
    for (int i = 0; i < buffer.length; ++i) {
      if (equiv(buffer[i], item)) {
        T toreturn = buffer[i];
        buffer[i] = item;
        return toreturn;
      }
      else if (gt(buffer[i], item)) {
        buffer.insert(i, item);
        return emptyresponse;
      }
    }
    buffer.push(item);
    return emptyresponse;
  }

  T get(T item) {
    for (T possibility : buffer) {
      if (equiv(possibility, item)) return possibility;
    }
    return emptyresponse;
  }

  bool delete(T item) {
    for (int i = 0; i < buffer.length; ++i) {
      if (equiv(buffer[i], item)) {
        buffer.delete(i);
        return true;
      }
    }
    return false;
  }

  void forEach(bool process(T item)) {
    for (T item : buffer) {
      if (!process(item)) break;
    }
  }
}

SortedSet_T operator cast(NaiveSortedSet_T naive) {
  SortedSet_T toreturn;
  toreturn.size = naive.size;
  toreturn.contains = naive.contains;
  toreturn.after = naive.after;
  toreturn.before = naive.before;
  toreturn.min = naive.min;
  toreturn.popMin = naive.popMin;
  toreturn.max = naive.max;
  toreturn.popMax = naive.popMax;
  toreturn.insert = naive.insert;
  toreturn.replace = naive.replace;
  toreturn.get = naive.get;
  toreturn.delete = naive.delete;
  toreturn.forEach = naive.forEach;
  return toreturn;
}

// Compose cast operators, since implicit casting is not transitive.
T[] operator cast(NaiveSortedSet_T naive) {
  return (SortedSet_T)naive;
}

SortedSet_T makeNaiveSortedSet(bool lessThan(T, T), T emptyresponse) {
  return NaiveSortedSet_T(lessThan, emptyresponse);
}