path: root/fonts/futhorc/futhorc.mf

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  futhorc.mf
%
%  Das Anglofriesische Futhorc (The Anglofriesic Futhorc)
%  Parameter File (1993/05/02)
%
%  Design by Micaela "Stayka" Pantke + Sigrid "Shavana" Juckel
%
%  Email:     hz225wu@unidui.uni-duisburg.de (Micaela Pantke)
%  Snailmail: Micaela Pantke
%             Westhoffstrasse 111
%             46149 Oberhausen
%             Germany
%
%  You're free to use or copy this file as long as you leave this 
%  header intact and don't change the contents.
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

mode_setup;                 % switches into Metafont mode

ho#:=o#;                    % horizontal overshoot
leftstemloc#:=2.5u#+s#;     % position of left bottom lines
py#:=.9px#;                 % vertical thickness of the pen

define_pixels(s,u);
define_blacker_pixels(px,py);
pickup pencircle xscaled px yscaled py;
runen_pen:=savepen;
define_good_x_pixels(leftstemloc);
define_corrected_pixels(o);  % turns overshoot correction on
define_horizontal_corrected_pixels(ho);

def beginrunenchar(expr code, unit_width) =
 beginchar(code,unit_width*u#+2s#,ht#,0);
 pickup runen_pen enddef;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  There they are: the runes
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

beginrunenchar("F",20);
x1=x2=x3=x6=leftstemloc; x4=x5=w-s; 
bot y1=-o; y2=.4h; y3=.7h; y4=.6h; y5=.9h; top y6= h;
draw z1--z6;
draw z3--z5;
draw z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("U",30);
x1=x2=leftstemloc; x3=x4=w-s; 
bot y1=bot y4=-o; y3=.6h; top y2=h; 
draw z1--z2--z3--z4; 
labels(1,2,3,4); 
endchar;

beginrunenchar("t",20);                  % This should be a "TH"
x1=x2=x3=x4=leftstemloc; x5=w-s; 
bot y1=-o; y2=.25h; y5=.5h; y3=.75h; top y4=h;
draw z1--z4;
draw z2--z5--z3;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("O",30);  
x1=x2=x3=leftstemloc; x4=x5=.5(w+s); x6=x7=w-s; 
bot y1=-o; y2=.7h; y4=.5h; y6=.7h; y5=.8h; top y3=top y7=h;
draw z1--z3--z5--z7;
draw z2--z4--z6;
labels(1,2,3,4,5,6,7); 
endchar;

beginrunenchar("R",20); 
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=bot y4=-o; y2=.4h; y5=.7h; top y3=h;
draw z1--z3--z5--z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("C",20); 
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=bot y4=-o; y2=.65h; y5=.35h; top y3=h;
draw z1--z3;
draw z4--z5--z2;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("g",30);      % This should be a g(j/zh) 
x1=x2=leftstemloc; x3=x4=w-s; 
bot y1=bot y3=-o; top y2=top y4=h;
draw z1--z4;
draw z2--z3;
labels(1,2,3,4); 
endchar;

beginrunenchar("W",20); 
x1=x2=x3=leftstemloc; x4=w-s; 
bot y1=-o; y2=.4h; y4=.7h; top y3=h;
draw z1--z3--z4--z2;
labels(1,2,3,4); 
endchar;

beginrunenchar("H",30); 
x1=x2=x3=x7=leftstemloc; x4=x5=x6=x8=w-s; 
bot y1=bot y4=-o; y2=.75h; y5=.45h; y7=.55h; y8=.25h; top y3=top y6=h;
draw z1--z3;
draw z4--z6;
draw z2--z5;
draw z7--z8;
labels(1,2,3,4,5,6,7,8); 
endchar;

beginrunenchar("N",20); 
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
bot y2=-o; y1=.6h; y4=.4h; top y3=h;
draw z1--z4;
draw z2--z3;
labels(1,2,3,4); 
endchar;

beginrunenchar("I",10); 
x1=x2=leftstemloc; 
bot y1=-o; top y2=h;
draw z1--z2;
labels(1,2); 
endchar;

beginrunenchar("Y",30);
x1=leftstemloc; x2=x3=x5=x6=.5(w+s); x4=w-s; 
bot y5=-o; y2=.2h; y1=y4=.5h; y3=.8h; top y6=h;
draw z1--z3--z4--z2--z1;
draw z6--z5;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("o",30);       % This should be an "EO" 
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
bot y2=-o; y1=.3h; y4=.7h; top y3=h;
draw z1--z2--z3--z4;
labels(1,2,3,4); 
endchar;

beginrunenchar("P",30); 
x1=x2=leftstemloc; x3=x4=.5(w+s); x5=x6=w-s; 
bot y1=bot y5=-o; y3=.3h; y4=.7h; top y2=top y6=h;
draw z5--z3--z1--z2--z4--z6;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("X",30); 
x1=leftstemloc; x2=x3=x4=.5(w+s); x5=w-s; 
bot y2=-o; y3=.6h; top y1=top y4=top y5=h;
draw z2--z4;
draw z1--z3--z5;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("S",20); 
x2=x4=leftstemloc; x1=x3=w-s; 
bot y1=-o; y2=.3h; y3=.7h; top y4=h;
draw z1--z3--z2--z4;
labels(1,2,3,4); 
endchar;

beginrunenchar("T",30); 
x1=leftstemloc; x2=x3=.5(w+s); x4=w-s; 
bot y2=-o; y1=y4=.7h; top y3=h;
draw z2--z3;
draw z1--z3--z4;
labels(1,2,3,4); 
endchar;

beginrunenchar("B",20); 
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=-o; y4=.3h; y2=.5h; y5=.7h; top y3=h;
draw z1--z3--z5--z2--z4--z1;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("E",30); 
x1=x2=leftstemloc; x3=.5(w+s); x4=x5=w-s; 
bot y1=bot y5=-o; y3=.7h; top y2=top y4=h;
draw z1--z2--z3--z4--z5;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("M",30); 
x1=x2=x3=leftstemloc; x4=x5=x6=w-s; 
bot y1=bot y4=-o; y2=y5=.4h; top y6=top y3=h;
draw z1--z3--z5;
draw z2--z6--z4;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("L",20); 
x1=x2=leftstemloc; x3=w-s; 
bot y1=-o; y3=.6h; top y2=h;
draw z1--z2--z3;
labels(1,2,3); 
endchar;

beginrunenchar("n",30);                  % This should be a "NG"
x1=x2=leftstemloc; x3=.3(w+s); x4=.7(w+s); x5=x6=w-s; 
bot y1 = bot y5 = -o; y3=y4=.5h; top y2=top y6=h;
draw z1--z4--z2;
draw z5--z3--z6;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("D",30); 
x1=x2=x5=x6=leftstemloc; x3=x4=x7=x8=w-s; 
bot y1=bot y3=-o; y5=y7=.2h; y6=y8=.8h; top y2=top y4=h;
draw z1--z2;
draw z3--z4;
draw z6--z7;
draw z5--z8;
labels(1,2,3,4,5,6,7,8); 
endchar;

beginrunenchar("e",30);     % This should be  e (ay) oe 
x1=x2=leftstemloc; x3=.5(w+s); x4=x5=w-s; 
bot y1= bot y4=-o; y2=y5=.7h; top y3=h;
draw z1--z5--z3--z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("A",30); 
x1=x2=x3=leftstemloc; x4=x5=.7(w+s); x6=w-s; 
bot y1=-o; y2=.7h; y4=.5h; y5=.8h; top y3=top y6=h;
draw z1--z3--z5--z6;
draw z2--z4;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("a",20);   % bzw. ein ae  
x1=x2=x3=leftstemloc; x4=x5=w-s; 
bot y1=-o; y2=.7h; y4=.5h; y5=.8h; top y3=h;
draw z1--z3--z5;
draw z2--z4;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("y",30);
x1=x2=leftstemloc;x5=x6=.5(w+s); x3=x4=w-s; 
bot y1=bot y4= bot y5=-o; y6=.25h; y3=.6h; top y2=h; 
draw z1--z2--z3--z4;
draw z5--z6; 
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("r",30); % This is an  "ea"
x3=leftstemloc; x5=.25(w+s); x1=x2=.5(w+s); x6=.75(w+s); x4=w-s;
bot y1=-o; y5=y6=.7h; top y2=top y3=top y4=h;
draw z1--z2;
draw z3--z5--z2--z6--z4;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("i",20);  % This is an  eo/io
x3=x5=leftstemloc; x1=x2=.5(w+s); x4=x6=w-s;
bot y1=-o; y3=y4=.7h; y5=y6=.3h; top y2=h;
draw z1--z2;
draw z3--z6;
draw z4--z5;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("Q",30); 
x3=leftstemloc; x4=.25(w+s); x1=x2=.5(w+s); x5=.75(w+s); x6=w-s;
bot y1=bot y3=-o; y4=.3h; y5=.7h; top y2=top y6=h;
draw z3--z4--z1--z2--z5--z6;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("K",30); 
x1=leftstemloc; x2=x3=x4=.5(w+s); x5=w-s; 
bot y1=bot y4 =bot y5=-o; y3=.4h; top y2=h;
draw z2--z4;
draw z1--z3--z5;
labels(1,2,3,4,5); 
endchar;

beginrunenchar("s",30);  % This is a  "ST"
x1=x2=leftstemloc; x3=x6=.5(w+s); x4=x5=w-s; 
bot y1=bot y5=-o; y3=.7h; y6=.3h; top y2=top y4=h;
draw z1--z2--z3--z4--z5--z6--z1;
labels(1,2,3,4,5,6); 
endchar;

beginrunenchar("G",30);
x1=x7=x8=leftstemloc; x2=x3=.5(w+s); x4=x5=x6=w-s; 
bot y5=bot y7=-o; y2=.2h; y1=y4=.5h; y3=.8h; top y6=top y8=h;
draw z1--z3--z4--z2--z1;
draw z6--z7;
draw z5--z8;
labels(1,2,3,4,5,6,7,8); 
endchar;

beginrunenchar(":",10); 
x1=x2=x3=x4=leftstemloc; 
y1=.2h; y2=.35h; y3=.65h; y4=.8h;
draw z1--z2;
draw z3--z4;
labels(1,2,3,4); 
endchar;

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%
%  End of File
% 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%