1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
define verb PSPRINT
image TEX_PS:PSPRINT.EXE
parameter p1,label=filespec,prompt="File",value(required,type=$infile)
qualifier prep, value(type=$infile,default="TEX_PS:LASERPREP70.PS")
qualifier output, value(required,type=$infile) ! default is print
qualifier landscape, nonnegatable ! default is portrait
!
! User can override the selection of file format based on file extension:
!
qualifier dvi, nonnegatable
qualifier ps, nonnegatable
qualifier text, nonnegatable
qualifier two, nonnegatable
qualifier wide, nonnegatable
disallow any2(dvi,ps,text,two,wide)
!
! PSPRINT only provides a few of the normal PRINT qualifiers:
!
qualifier delete, ! default is /NODELETE
qualifier notify, ! default is /NONOTIFY
qualifier copies, value(required,type=$number) ! default is 1
qualifier note, value(required)
qualifier form, value(required)
qualifier queue, value(required)
!
! We currently do not use different forms. Other sites might want to use
! /FORM to handle transparencies, manual feeding, proof/final copy, etc:
!
disallow form
!
! Here are the allowed PSDVI qualifiers (default values are set in PSDVI.CLD):
!
qualifier pages, nonnegatable,value(required)
qualifier increment, nonnegatable,value(required,type=$number)
qualifier magnification, nonnegatable,value(required,type=$number)
qualifier resolution, nonnegatable,value(required,type=$number)
qualifier units, nonnegatable,value(required)
qualifier hoffset, nonnegatable,value(required)
qualifier voffset, nonnegatable,value(required)
qualifier xsize, nonnegatable,value(required)
qualifier ysize, nonnegatable,value(required)
qualifier psprefix, nonnegatable,value(required)
qualifier tfm_directory, nonnegatable,value(required)
qualifier font_directory, nonnegatable,value(required)
qualifier dummy_font, nonnegatable,value(required)
qualifier stats,
!
! The /CONSERVE_VM and /REVERSE qualifiers are handled differently because
! we want PSPRINT to use default settings that depend on the /DEVICE value:
!
qualifier conserve_vm, nonnegatable
qualifier noconserve_vm, nonnegatable
disallow conserve_vm and noconserve_vm
!
qualifier reverse, nonnegatable
qualifier noreverse, nonnegatable
disallow reverse and noreverse
!
!
! PSPRINT runs a different command file for each different PostScript device:
!
qualifier device, nonnegatable,default,value(type=psprinter,required)
!
! This qualifier is only relevant if /DEVICE=LW or LINO:
!
qualifier banner, default ! default is print banner page
!
! This qualifier is only relevant if /DEVICE=LW:
!
qualifier manualfeed, nonnegatable ! default is auto feed
!
! These qualifiers are only relevant if /DEVICE=LINO:
!
qualifier cutmarks, default ! default is do them
qualifier lowres, nonnegatable ! default is high-res
qualifier size, nonnegatable,default,value(type=pagesize,required)
!
! The Linotronic supports a number of different page sizes and orientations.
! The /SIZE values defined below are used in LINO_PRINT.COM:
!
define type pagesize
keyword A3L ! A3 page size with landscape orientation
keyword A4P, default ! A4 page size with portrait orientation
keyword A4L ! A4 page size with landscape orientation
keyword A5P ! A5 page size with portrait orientation
keyword A5L ! A5 page size with landscape orientation
keyword B5P ! B5 page size with portrait orientation
keyword B5L ! B5 page size with landscape orientation
!
! Here are the different /DEVICE values currently supported:
!
define type psprinter
keyword LW , default ! LaserWriter
keyword LINO ! Linotronic 300
keyword PS40 ! PrintServer 40
|