summaryrefslogtreecommitdiff
path: root/dviware/quicspool/wwfonts
diff options
context:
space:
mode:
Diffstat (limited to 'dviware/quicspool/wwfonts')
-rw-r--r--dviware/quicspool/wwfonts/b.mf83
-rw-r--r--dviware/quicspool/wwfonts/b.tfmbin0 -> 1260 bytes
-rw-r--r--dviware/quicspool/wwfonts/cw.mf83
-rw-r--r--dviware/quicspool/wwfonts/cw.tfmbin0 -> 799 bytes
-rw-r--r--dviware/quicspool/wwfonts/desc43
-rw-r--r--dviware/quicspool/wwfonts/i.mf83
-rw-r--r--dviware/quicspool/wwfonts/i.tfmbin0 -> 1348 bytes
-rw-r--r--dviware/quicspool/wwfonts/makefile40
-rw-r--r--dviware/quicspool/wwfonts/makefile.trw40
-rw-r--r--dviware/quicspool/wwfonts/makefonts30
-rw-r--r--dviware/quicspool/wwfonts/r.mf83
-rw-r--r--dviware/quicspool/wwfonts/r.tfmbin0 -> 1220 bytes
-rw-r--r--dviware/quicspool/wwfonts/s.mf83
-rw-r--r--dviware/quicspool/wwfonts/s.tfmbin0 -> 1028 bytes
-rw-r--r--dviware/quicspool/wwfonts/tcomlig.mf21
-rw-r--r--dviware/quicspool/wwfonts/tgreekl.mf418
-rw-r--r--dviware/quicspool/wwfonts/tgreeku.mf611
-rw-r--r--dviware/quicspool/wwfonts/titalig.mf206
-rw-r--r--dviware/quicspool/wwfonts/titalms.mf40
-rw-r--r--dviware/quicspool/wwfonts/titalp.mf114
-rw-r--r--dviware/quicspool/wwfonts/tmathit.mf1015
-rw-r--r--dviware/quicspool/wwfonts/tpunct.mf241
-rw-r--r--dviware/quicspool/wwfonts/troman.mf341
-rw-r--r--dviware/quicspool/wwfonts/tromlig.mf171
-rw-r--r--dviware/quicspool/wwfonts/tromms.mf42
-rw-r--r--dviware/quicspool/wwfonts/ttextit.mf336
26 files changed, 4124 insertions, 0 deletions
diff --git a/dviware/quicspool/wwfonts/b.mf b/dviware/quicspool/wwfonts/b.mf
new file mode 100644
index 0000000000..52ac9160af
--- /dev/null
+++ b/dviware/quicspool/wwfonts/b.mf
@@ -0,0 +1,83 @@
+% $Header: B.mf,v 1.1 88/01/15 13:14:32 simpson Rel $
+% $Log: B.mf,v $
+%Revision 1.1 88/01/15 13:14:32 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:20 simpson
+%beta test
+%
+% Computer Modern Bold Roman 10 point
+if unknown cmbase: input cmbase fi
+
+font_identifier:="CMB"; font_size 10pt#;
+
+u#:=20/36pt#; % unit width
+width_adj#:=10/36pt#; % width adjustment for certain characters
+serif_fit#:=0pt#; % extra sidebar near lowercase serifs
+cap_serif_fit#:=6/36pt#; % extra sidebar near uppercase serifs
+letter_fit#:=0pt#; % extra space added to all sidebars
+
+body_height#:=270/36pt#; % height of tallest characters
+asc_height#:=250/36pt#; % height of lowercase ascenders
+cap_height#:=247/36pt#; % height of caps
+fig_height#:=232/36pt#; % height of numerals
+x_height#:=160/36pt#; % height of lowercase without ascenders
+math_axis#:=90/36pt#; % axis of symmetry for math symbols
+bar_height#:=85/36pt#; % height of crossbar in lowercase e
+comma_depth#:=70/36pt#; % depth of comma below baseline
+desc_depth#:=70/36pt#; % depth of lowercase descenders
+
+crisp#:=0pt#; % diameter of serif corners
+tiny#:=13/36pt#; % diameter of rounded corners
+fine#:=10/36pt#; % diameter of sharply rounded corners
+thin_join#:=10/36pt#; % width of extrafine details
+hair#:=17/36pt#; % lowercase hairline breadth
+stem#:=41/36pt#; % lowercase stem breadth
+curve#:=46/36pt#; % lowercase curve breadth
+ess#:=38/36pt#; % breadth in middle of lowercase s
+flare#:=45/36pt#; % diameter of bulbs or breadth of terminals
+dot_size#:=56/36pt#; % diameter of dots
+cap_hair#:=19/36pt#; % uppercase hairline breadth
+cap_stem#:=51/36pt#; % uppercase stem breadth
+cap_curve#:=55/36pt#; % uppercase curve breadth
+cap_ess#:=53/36pt#; % breadth in middle of uppercase s
+rule_thickness#:=.6pt#; % thickness of lines in math symbols
+
+dish#:=1/36pt#; % amount erased at top or bottom of serifs
+bracket#:=10/36pt#; % vertical distance from serif base to tangent
+jut#:=25/36pt#; % protrusion of lowercase serifs
+cap_jut#:=34/36pt#; % protrusion of uppercase serifs
+beak_jut#:=11/36pt#; % horizontal protrusion of beak serifs
+beak#:=70/36pt#; % vertical protrusion of beak serifs
+vair#:=13/36pt#; % vertical diameter of hairlines
+notch_cut#:=10pt#; % maximum breadth above or below notches
+bar#:=17/36pt#; % lowercase bar thickness
+slab#:=17/36pt#; % serif and arm thickness
+cap_bar#:=17/36pt#; % uppercase bar thickness
+cap_band#:=17/36pt#; % uppercase thickness above/below lobes
+cap_notch_cut#:=10pt#; % max breadth above/below uppercase notches
+serif_drop#:=3/36pt#; % vertical drop of sloped serifs
+stem_corr#:=2/36pt#; % for small refinements of stem breadth
+vair_corr#:=1.5/36pt#; % for small refinements of hairline height
+apex_corr#:=0pt#; % extra width at diagonal junctions
+
+o#:=4/36pt#; % amount of overshoot for curves
+apex_o#:=3/36pt#; % amount of overshoot for diagonal junctions
+
+slant:=0; % tilt ratio $(\Delta x/\Delta y)$
+fudge:=1; % factor applied to weights of heavy characters
+math_spread:=.5; % extra openness of math symbols
+superness:=8/11; % parameter for superellipses
+superpull:=1/8; % extra openness inside bowls
+beak_darkness:=.4; % fraction of triangle inside beak serifs
+ligs:=2; % level of ligatures to be included
+
+square_dots:=false; % should dots be square?
+hefty:=false; % should we try hard not to be overweight?
+serifs:=true; % should serifs and bulbs be attached?
+monospace:=false; % should all characters have the same width?
+variant_g:=false; % should an italic-style g be used?
+low_asterisk:=false; % should the asterisk be centered at the axis?
+math_fitting:=false; % should math-mode spacing be used?
+
+generate troman % switch to the driver file
diff --git a/dviware/quicspool/wwfonts/b.tfm b/dviware/quicspool/wwfonts/b.tfm
new file mode 100644
index 0000000000..7d87d93696
--- /dev/null
+++ b/dviware/quicspool/wwfonts/b.tfm
Binary files differ
diff --git a/dviware/quicspool/wwfonts/cw.mf b/dviware/quicspool/wwfonts/cw.mf
new file mode 100644
index 0000000000..1073f46b76
--- /dev/null
+++ b/dviware/quicspool/wwfonts/cw.mf
@@ -0,0 +1,83 @@
+% $Header: CW.mf,v 1.1 88/01/15 13:14:34 simpson Rel $
+% $Log: CW.mf,v $
+%Revision 1.1 88/01/15 13:14:34 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:21 simpson
+%beta test
+%
+% Computer Modern Typewriter Text for use with 10 point
+if unknown cmbase: input cmbase fi
+
+font_identifier:="CMTT"; font_size 10pt#;
+
+u#:=21/36pt#; % unit width
+width_adj#:=0pt#; % width adjustment for certain characters
+serif_fit#:=0pt#; % extra sidebar near lowercase serifs
+cap_serif_fit#:=0pt#; % extra sidebar near uppercase serifs
+letter_fit#:=0pt#; % extra space added to all sidebars
+
+body_height#:=250/36pt#; % height of tallest characters
+asc_height#:=220/36pt#; % height of lowercase ascenders
+cap_height#:=220/36pt#; % height of caps
+fig_height#:=220/36pt#; % height of numerals
+x_height#:=155/36pt#; % height of lowercase without ascenders
+math_axis#:=110/36pt#; % axis of symmetry for math symbols
+bar_height#:=79/36pt#; % height of crossbar in lowercase e
+comma_depth#:=50/36pt#; % depth of comma below baseline
+desc_depth#:=80/36pt#; % depth of lowercase descenders
+
+crisp#:=22/36pt#; % diameter of serif corners
+tiny#:=22/36pt#; % diameter of rounded corners
+fine#:=21/36pt#; % diameter of sharply rounded corners
+thin_join#:=21/36pt#; % width of extrafine details
+hair#:=25/36pt#; % lowercase hairline breadth
+stem#:=25/36pt#; % lowercase stem breadth
+curve#:=25/36pt#; % lowercase curve breadth
+ess#:=22/36pt#; % breadth in middle of lowercase s
+flare#:=32/36pt#; % diameter of bulbs or breadth of terminals
+dot_size#:=36/36pt#; % diameter of dots
+cap_hair#:=25/36pt#; % uppercase hairline breadth
+cap_stem#:=25/36pt#; % uppercase stem breadth
+cap_curve#:=25/36pt#; % uppercase curve breadth
+cap_ess#:=25/36pt#; % breadth in middle of uppercase s
+rule_thickness#:=25/36pt#; % thickness of lines in math symbols
+
+dish#:=0pt#; % amount erased at top or bottom of serifs
+bracket#:=0pt#; % vertical distance from serif base to tangent
+jut#:=34/36pt#; % protrusion of lowercase serifs
+cap_jut#:=34/36pt#; % protrusion of uppercase serifs
+beak_jut#:=0pt#; % horizontal protrusion of beak serifs
+beak#:=34/36pt#; % vertical protrusion of beak serifs
+vair#:=22/36pt#; % vertical diameter of hairlines
+notch_cut#:=25/36pt#; % maximum breadth above or below notches
+bar#:=22/36pt#; % lowercase bar thickness
+slab#:=22/36pt#; % serif and arm thickness
+cap_bar#:=22/36pt#; % uppercase bar thickness
+cap_band#:=22/36pt#; % uppercase thickness above/below lobes
+cap_notch_cut#:=25/36pt#; % max breadth above/below uppercase notches
+serif_drop#:=0pt#; % vertical drop of sloped serifs
+stem_corr#:=0pt#; % for small refinements of stem breadth
+vair_corr#:=0pt#; % for small refinements of hairline height
+apex_corr#:=10/36pt#; % extra width at diagonal junctions
+
+o#:=4/36pt#; % amount of overshoot for curves
+apex_o#:=3/36pt#; % amount of overshoot for diagonal junctions
+
+slant:=0; % tilt ratio $(\Delta x/\Delta y)$
+fudge:=0.81; % factor applied to weights of heavy characters
+math_spread:=-1; % extra openness of math symbols
+superness:=1/sqrt2; % parameter for superellipses
+superpull:=0; % extra openness inside bowls
+beak_darkness:=0; % fraction of triangle inside beak serifs
+ligs:=2; % level of ligatures to be included
+
+square_dots:=false; % should dots be square?
+hefty:=true; % should we try hard not to be overweight?
+serifs:=true; % should serifs and bulbs be attached?
+monospace:=true; % should all characters have the same width?
+variant_g:=false; % should an italic-style g be used?
+low_asterisk:=true; % should the asterisk be centered at the axis?
+math_fitting:=false; % should math-mode spacing be used?
+
+generate troman % switch to the driver file
diff --git a/dviware/quicspool/wwfonts/cw.tfm b/dviware/quicspool/wwfonts/cw.tfm
new file mode 100644
index 0000000000..b2839c81b7
--- /dev/null
+++ b/dviware/quicspool/wwfonts/cw.tfm
Binary files differ
diff --git a/dviware/quicspool/wwfonts/desc b/dviware/quicspool/wwfonts/desc
new file mode 100644
index 0000000000..0d780bf4b5
--- /dev/null
+++ b/dviware/quicspool/wwfonts/desc
@@ -0,0 +1,43 @@
+# QMS QUIC printers
+# $Header: DESC,v 1.1 88/01/15 13:14:29 simpson Rel $
+# $Log: DESC,v $
+#Revision 1.1 88/01/15 13:14:29 simpson
+#initial release
+#
+#Revision 0.3 87/12/18 10:10:22 simpson
+#added l. and L. for pic dot boxes
+#
+#Revision 0.2 87/12/14 09:36:01 simpson
+#Moved S after CW in font list.
+#
+#Revision 0.1 87/12/11 19:03:59 simpson
+#beta test
+#
+fonts 5 R I B CW S
+sizes 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 22 24 26 28 30 32 34 36 40 44 48 0
+res 300
+hor 1
+vert 1
+unitwidth 10
+paperwidth 2550
+paperlength 3300
+charset
+\| \^ \- \_ \`
+** *A *B *G *D *E *Z *Y *H *I *K *L *M *N *C *O *P *R *S *T *U *F *X *Q *W
+*a *b *c *d *e *f *g *h *i
+*k *l *m *n *o *p *q *r *s *t *u
+*w *x *y *z +- -> <- <=
+== >=
+aa ap br bs bu bv bx ca cd
+ci co ct cu dd de dg di em en
+eq es fe fm ga gr hy
+ib if ip is lh li Li ma mi mo
+mu no ob or pd pl pp pt rg rh ru
+sb sc sl Sl sp sq sr tm tp ts ul vr
+~= ~~ rn
+lf rf lc rc lt rt lb rb
+lk rk != .. l. L.
+ua da
+12
+14 34
+fi fl ff fI fL Fi Fl
diff --git a/dviware/quicspool/wwfonts/i.mf b/dviware/quicspool/wwfonts/i.mf
new file mode 100644
index 0000000000..844fb51f03
--- /dev/null
+++ b/dviware/quicspool/wwfonts/i.mf
@@ -0,0 +1,83 @@
+% $Header: I.mf,v 1.1 88/01/15 13:14:36 simpson Rel $
+% $Log: I.mf,v $
+%Revision 1.1 88/01/15 13:14:36 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:22 simpson
+%beta test
+%
+% Computer Modern Text Italic 10 point
+if unknown cmbase: input cmbase fi
+
+font_identifier:="CMTI"; font_size 10pt#;
+
+u#:=18.4/36pt#; % unit width
+width_adj#:=0pt#; % width adjustment for certain characters
+serif_fit#:=0pt#; % extra sidebar near lowercase serifs
+cap_serif_fit#:=5/36pt#; % extra sidebar near uppercase serifs
+letter_fit#:=9.2/36pt#; % extra space added to all sidebars
+
+body_height#:=270/36pt#; % height of tallest characters
+asc_height#:=250/36pt#; % height of lowercase ascenders
+cap_height#:=246/36pt#; % height of caps
+fig_height#:=232/36pt#; % height of numerals
+x_height#:=155/36pt#; % height of lowercase without ascenders
+math_axis#:=90/36pt#; % axis of symmetry for math symbols
+bar_height#:=87/36pt#; % height of crossbar in lowercase e
+comma_depth#:=70/36pt#; % depth of comma below baseline
+desc_depth#:=70/36pt#; % depth of lowercase descenders
+
+crisp#:=8/36pt#; % diameter of serif corners
+tiny#:=8/36pt#; % diameter of rounded corners
+fine#:=7/36pt#; % diameter of sharply rounded corners
+thin_join#:=7/36pt#; % width of extrafine details
+hair#:=11/36pt#; % lowercase hairline breadth
+stem#:=23/36pt#; % lowercase stem breadth
+curve#:=28/36pt#; % lowercase curve breadth
+ess#:=27/36pt#; % breadth in middle of lowercase s
+flare#:=29/36pt#; % diameter of bulbs or breadth of terminals
+dot_size#:=38/36pt#; % diameter of dots
+cap_hair#:=11/36pt#; % uppercase hairline breadth
+cap_stem#:=29/36pt#; % uppercase stem breadth
+cap_curve#:=34/36pt#; % uppercase curve breadth
+cap_ess#:=31/36pt#; % breadth in middle of uppercase s
+rule_thickness#:=.4pt#; % thickness of lines in math symbols
+
+dish#:=1/36pt#; % amount erased at top or bottom of serifs
+bracket#:=20/36pt#; % vertical distance from serif base to tangent
+jut#:=30/36pt#; % protrusion of lowercase serifs
+cap_jut#:=34/36pt#; % protrusion of uppercase serifs
+beak_jut#:=9/36pt#; % horizontal protrusion of beak serifs
+beak#:=70/36pt#; % vertical protrusion of beak serifs
+vair#:=8/36pt#; % vertical diameter of hairlines
+notch_cut#:=10pt#; % maximum breadth above or below notches
+bar#:=11/36pt#; % lowercase bar thickness
+slab#:=11/36pt#; % serif and arm thickness
+cap_bar#:=11/36pt#; % uppercase bar thickness
+cap_band#:=11/36pt#; % uppercase thickness above/below lobes
+cap_notch_cut#:=10pt#; % max breadth above/below uppercase notches
+serif_drop#:=4/36pt#; % vertical drop of sloped serifs
+stem_corr#:=1/36pt#; % for small refinements of stem breadth
+vair_corr#:=1/36pt#; % for small refinements of hairline height
+apex_corr#:=0pt#; % extra width at diagonal junctions
+
+o#:=8/36pt#; % amount of overshoot for curves
+apex_o#:=8/36pt#; % amount of overshoot for diagonal junctions
+
+slant:=.25; % tilt ratio $(\Delta x/\Delta y)$
+fudge:=1; % factor applied to weights of heavy characters
+math_spread:=0; % extra openness of math symbols
+superness:=1/sqrt2; % parameter for superellipses
+superpull:=1/6; % extra openness inside bowls
+beak_darkness:=11/30; % fraction of triangle inside beak serifs
+ligs:=2; % level of ligatures to be included
+
+square_dots:=false; % should dots be square?
+hefty:=false; % should we try hard not to be overweight?
+serifs:=true; % should serifs and bulbs be attached?
+monospace:=false; % should all characters have the same width?
+variant_g:=true; % should an italic-style g be used?
+low_asterisk:=false; % should the asterisk be centered at the axis?
+math_fitting:=false; % should math-mode spacing be used?
+
+generate ttextit % switch to the driver file
diff --git a/dviware/quicspool/wwfonts/i.tfm b/dviware/quicspool/wwfonts/i.tfm
new file mode 100644
index 0000000000..90110292ec
--- /dev/null
+++ b/dviware/quicspool/wwfonts/i.tfm
Binary files differ
diff --git a/dviware/quicspool/wwfonts/makefile b/dviware/quicspool/wwfonts/makefile
new file mode 100644
index 0000000000..d7012e4b61
--- /dev/null
+++ b/dviware/quicspool/wwfonts/makefile
@@ -0,0 +1,40 @@
+# $Header: Makefile,v 1.1 88/01/15 13:14:23 simpson Rel $
+# $Log: Makefile,v $
+#Revision 1.1 88/01/15 13:14:23 simpson
+#initial release
+#
+#Revision 0.1 87/12/11 19:09:52 simpson
+#beta test
+#
+OTROFFFONT=/usr/lib/font
+DITROFFFONT=/usr/lib/font/devqms
+
+all: owidths diwidths desc
+
+configure:
+
+owidths:
+ ../src/tfm2ofont R.tfm I.tfm B.tfm CW.tfm
+ ../src/tfm2ofont -s S.tfm
+ cc -c ftR.c ftI.c ftB.c ftS.c ftCW.c
+ for i in ftR.o ftI.o ftB.o ftS.o ftCW.o;do \
+ mv $$i `basename $$i .o`;\
+ done
+
+diwidths:
+ ../src/tfm2difont R.tfm I.tfm B.tfm
+ ../src/tfm2difont -l fi -l ff -l fl -l ffi -l ffl -w 22 CW.tfm
+ ../src/tfm2difont -s S.tfm
+
+desc:
+ -makedev DESC
+
+install:
+ cp *pk $(DITROFFFONT)/wwfonts
+ chmod 644 $(DITROFFFONT)/wwfonts/*pk
+ for i in R I B S CW;do install -m 644 ft$$i $(OTROFFFONT); done
+ -install DESC.out $(DITROFFFONT)
+ -for i in R I B CW S;do install -m 644 $$i.out $(DITROFFFONT); done
+
+clean:
+ -rm *gf *.log *.c ft* *.out R I B S CW
diff --git a/dviware/quicspool/wwfonts/makefile.trw b/dviware/quicspool/wwfonts/makefile.trw
new file mode 100644
index 0000000000..e93ead4479
--- /dev/null
+++ b/dviware/quicspool/wwfonts/makefile.trw
@@ -0,0 +1,40 @@
+# $Header: Makefile.TRW,v 1.1 88/01/15 13:14:25 simpson Rel $
+# $Log: Makefile.TRW,v $
+#Revision 1.1 88/01/15 13:14:25 simpson
+#initial release
+#
+#Revision 0.1 87/12/11 19:09:54 simpson
+#beta test
+#
+OTROFFFONT=/usr/lib/font
+DITROFFFONT=/usr/lib/font/devqms
+
+all: owidths diwidths desc
+
+configure:
+
+owidths:
+ ../src/tfm2ofont R.tfm I.tfm B.tfm CW.tfm
+ ../src/tfm2ofont -s S.tfm
+ cc -c ftR.c ftI.c ftB.c ftS.c ftCW.c
+ for i in ftR.o ftI.o ftB.o ftS.o ftCW.o;do \
+ mv $$i `basename $$i .o`;\
+ done
+
+diwidths:
+ ../src/tfm2difont R.tfm I.tfm B.tfm
+ ../src/tfm2difont -l fi -l ff -l fl -l ffi -l ffl -w 22 CW.tfm
+ ../src/tfm2difont -s S.tfm
+
+desc:
+ -makedev DESC
+
+install:
+ cp *pk $(DITROFFFONT)/wwfonts
+ chmod 644 $(DITROFFFONT)/wwfonts/*pk
+ for i in R I B S CW;do install -m 644 ft$$i $(OTROFFFONT); done
+ -install DESC.out $(DITROFFFONT)
+ -for i in R I B CW S;do install -m 644 $$i.out $(DITROFFFONT); done
+
+clean:
+ -rm *gf *.log *.c ft* *.out R I B S CW
diff --git a/dviware/quicspool/wwfonts/makefonts b/dviware/quicspool/wwfonts/makefonts
new file mode 100644
index 0000000000..920e7e108e
--- /dev/null
+++ b/dviware/quicspool/wwfonts/makefonts
@@ -0,0 +1,30 @@
+#! /bin/sh
+# $Header: makefonts,v 1.1 88/01/15 13:14:27 simpson Rel $
+# $Log: makefonts,v $
+#Revision 1.1 88/01/15 13:14:27 simpson
+#initial release
+#
+#Revision 0.1 87/12/11 19:09:55 simpson
+#beta test
+#
+# Creates the sizes
+# 4 to 20
+# 22 to 36 step 2
+# 40 to 48 step 4
+# using METAFONT
+fontlist="`grep '^fonts' DESC | sed 's/fonts [0-9][0-9]* //'`"
+for font in $fontlist; do
+ i=4
+ while [ $i -le 48 ];do
+# Use mode type qms for a write-white engine
+ mf '\mode:=qms;' "mag:=$i/10;" input $font
+ gftopk $font.`expr $i \* 300 / 10`gf
+ if [ $i -ge 20 -a $i -le 34 ]; then
+ i=`expr $i + 2`
+ elif [ $i -ge 36 ]; then
+ i=`expr $i + 4`
+ else
+ i=`expr $i + 1`
+ fi
+ done
+done
diff --git a/dviware/quicspool/wwfonts/r.mf b/dviware/quicspool/wwfonts/r.mf
new file mode 100644
index 0000000000..8c293d0adc
--- /dev/null
+++ b/dviware/quicspool/wwfonts/r.mf
@@ -0,0 +1,83 @@
+% $Header: R.mf,v 1.1 88/01/15 13:14:38 simpson Rel $
+% $Log: R.mf,v $
+%Revision 1.1 88/01/15 13:14:38 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:23 simpson
+%beta test
+%
+% Computer Modern Roman 10 point
+if unknown cmbase: input cmbase fi
+
+font_identifier:="TCMR"; font_size 10pt#;
+
+u#:=20/36pt#; % unit width
+width_adj#:=0pt#; % width adjustment for certain characters
+serif_fit#:=0pt#; % extra sidebar near lowercase serifs
+cap_serif_fit#:=5/36pt#; % extra sidebar near uppercase serifs
+letter_fit#:=0pt#; % extra space added to all sidebars
+
+body_height#:=270/36pt#; % height of tallest characters
+asc_height#:=250/36pt#; % height of lowercase ascenders
+cap_height#:=246/36pt#; % height of caps
+fig_height#:=232/36pt#; % height of numerals
+x_height#:=155/36pt#; % height of lowercase without ascenders
+math_axis#:=90/36pt#; % axis of symmetry for math symbols
+bar_height#:=87/36pt#; % height of crossbar in lowercase e
+comma_depth#:=70/36pt#; % depth of comma below baseline
+desc_depth#:=70/36pt#; % depth of lowercase descenders
+
+crisp#:=0pt#; % diameter of serif corners
+tiny#:=8/36pt#; % diameter of rounded corners
+fine#:=7/36pt#; % diameter of sharply rounded corners
+thin_join#:=7/36pt#; % width of extrafine details
+hair#:=9/36pt#; % lowercase hairline breadth
+stem#:=25/36pt#; % lowercase stem breadth
+curve#:=30/36pt#; % lowercase curve breadth
+ess#:=27/36pt#; % breadth in middle of lowercase s
+flare#:=33/36pt#; % diameter of bulbs or breadth of terminals
+dot_size#:=38/36pt#; % diameter of dots
+cap_hair#:=11/36pt#; % uppercase hairline breadth
+cap_stem#:=32/36pt#; % uppercase stem breadth
+cap_curve#:=37/36pt#; % uppercase curve breadth
+cap_ess#:=35/36pt#; % breadth in middle of uppercase s
+rule_thickness#:=.4pt#; % thickness of lines in math symbols
+
+dish#:=1/36pt#; % amount erased at top or bottom of serifs
+bracket#:=20/36pt#; % vertical distance from serif base to tangent
+jut#:=28/36pt#; % protrusion of lowercase serifs
+cap_jut#:=37/36pt#; % protrusion of uppercase serifs
+beak_jut#:=10/36pt#; % horizontal protrusion of beak serifs
+beak#:=70/36pt#; % vertical protrusion of beak serifs
+vair#:=8/36pt#; % vertical diameter of hairlines
+notch_cut#:=10pt#; % maximum breadth above or below notches
+bar#:=11/36pt#; % lowercase bar thickness
+slab#:=11/36pt#; % serif and arm thickness
+cap_bar#:=11/36pt#; % uppercase bar thickness
+cap_band#:=11/36pt#; % uppercase thickness above/below lobes
+cap_notch_cut#:=10pt#; % max breadth above/below uppercase notches
+serif_drop#:=4/36pt#; % vertical drop of sloped serifs
+stem_corr#:=1/36pt#; % for small refinements of stem breadth
+vair_corr#:=1/36pt#; % for small refinements of hairline height
+apex_corr#:=0pt#; % extra width at diagonal junctions
+
+o#:=8/36pt#; % amount of overshoot for curves
+apex_o#:=8/36pt#; % amount of overshoot for diagonal junctions
+
+slant:=0; % tilt ratio $(\Delta x/\Delta y)$
+fudge:=1; % factor applied to weights of heavy characters
+math_spread:=0; % extra openness of math symbols
+superness:=1/sqrt2; % parameter for superellipses
+superpull:=1/6; % extra openness inside bowls
+beak_darkness:=11/30; % fraction of triangle inside beak serifs
+ligs:=2; % level of ligatures to be included
+
+square_dots:=false; % should dots be square?
+hefty:=false; % should we try hard not to be overweight?
+serifs:=true; % should serifs and bulbs be attached?
+monospace:=false; % should all characters have the same width?
+variant_g:=false; % should an italic-style g be used?
+low_asterisk:=false; % should the asterisk be centered at the axis?
+math_fitting:=false; % should math-mode spacing be used?
+
+generate troman % switch to the driver file
diff --git a/dviware/quicspool/wwfonts/r.tfm b/dviware/quicspool/wwfonts/r.tfm
new file mode 100644
index 0000000000..6fcd675997
--- /dev/null
+++ b/dviware/quicspool/wwfonts/r.tfm
Binary files differ
diff --git a/dviware/quicspool/wwfonts/s.mf b/dviware/quicspool/wwfonts/s.mf
new file mode 100644
index 0000000000..49ff11ce4c
--- /dev/null
+++ b/dviware/quicspool/wwfonts/s.mf
@@ -0,0 +1,83 @@
+% $Header: S.mf,v 1.1 88/01/15 13:14:41 simpson Rel $
+% $Log: S.mf,v $
+%Revision 1.1 88/01/15 13:14:41 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:24 simpson
+%beta test
+%
+% Computer Modern Math Italic 10 point
+if unknown cmbase: input cmbase fi
+
+font_identifier:="CMMI"; font_size 10pt#;
+
+u#:=20/36pt#; % unit width
+width_adj#:=0pt#; % width adjustment for certain characters
+serif_fit#:=0pt#; % extra sidebar near lowercase serifs
+cap_serif_fit#:=5/36pt#; % extra sidebar near uppercase serifs
+letter_fit#:=0pt#; % extra space added to all sidebars
+
+body_height#:=270/36pt#; % height of tallest characters
+asc_height#:=250/36pt#; % height of lowercase ascenders
+cap_height#:=246/36pt#; % height of caps
+fig_height#:=232/36pt#; % height of numerals
+x_height#:=155/36pt#; % height of lowercase without ascenders
+math_axis#:=90/36pt#; % axis of symmetry for math symbols
+bar_height#:=87/36pt#; % height of crossbar in lowercase e
+comma_depth#:=70/36pt#; % depth of comma below baseline
+desc_depth#:=70/36pt#; % depth of lowercase descenders
+
+crisp#:=8/36pt#; % diameter of serif corners
+tiny#:=8/36pt#; % diameter of rounded corners
+fine#:=7/36pt#; % diameter of sharply rounded corners
+thin_join#:=7/36pt#; % width of extrafine details
+hair#:=9/36pt#; % lowercase hairline breadth
+stem#:=24/36pt#; % lowercase stem breadth
+curve#:=29/36pt#; % lowercase curve breadth
+ess#:=27/36pt#; % breadth in middle of lowercase s
+flare#:=32/36pt#; % diameter of bulbs or breadth of terminals
+dot_size#:=38/36pt#; % diameter of dots
+cap_hair#:=11/36pt#; % uppercase hairline breadth
+cap_stem#:=30/36pt#; % uppercase stem breadth
+cap_curve#:=35/36pt#; % uppercase curve breadth
+cap_ess#:=33/36pt#; % breadth in middle of uppercase s
+rule_thickness#:=.4pt#; % thickness of lines in math symbols
+
+dish#:=1/36pt#; % amount erased at top or bottom of serifs
+bracket#:=20/36pt#; % vertical distance from serif base to tangent
+jut#:=30/36pt#; % protrusion of lowercase serifs
+cap_jut#:=37/36pt#; % protrusion of uppercase serifs
+beak_jut#:=10/36pt#; % horizontal protrusion of beak serifs
+beak#:=70/36pt#; % vertical protrusion of beak serifs
+vair#:=8/36pt#; % vertical diameter of hairlines
+notch_cut#:=10pt#; % maximum breadth above or below notches
+bar#:=11/36pt#; % lowercase bar thickness
+slab#:=11/36pt#; % serif and arm thickness
+cap_bar#:=11/36pt#; % uppercase bar thickness
+cap_band#:=11/36pt#; % uppercase thickness above/below lobes
+cap_notch_cut#:=10pt#; % max breadth above/below uppercase notches
+serif_drop#:=4/36pt#; % vertical drop of sloped serifs
+stem_corr#:=1/36pt#; % for small refinements of stem breadth
+vair_corr#:=1/36pt#; % for small refinements of hairline height
+apex_corr#:=0pt#; % extra width at diagonal junctions
+
+o#:=8/36pt#; % amount of overshoot for curves
+apex_o#:=8/36pt#; % amount of overshoot for diagonal junctions
+
+slant:=.25; % tilt ratio $(\Delta x/\Delta y)$
+fudge:=1; % factor applied to weights of heavy characters
+math_spread:=0; % extra openness of math symbols
+superness:=1/sqrt2; % parameter for superellipses
+superpull:=1/6; % extra openness inside bowls
+beak_darkness:=11/30; % fraction of triangle inside beak serifs
+ligs:=2; % level of ligatures to be included
+
+square_dots:=false; % should dots be square?
+hefty:=false; % should we try hard not to be overweight?
+serifs:=true; % should serifs and bulbs be attached?
+monospace:=false; % should all characters have the same width?
+variant_g:=true; % should an italic-style g be used?
+low_asterisk:=false; % should the asterisk be centered at the axis?
+math_fitting:=true; % should math-mode spacing be used?
+
+generate tmathit % switch to the driver file
diff --git a/dviware/quicspool/wwfonts/s.tfm b/dviware/quicspool/wwfonts/s.tfm
new file mode 100644
index 0000000000..529fe0dbd0
--- /dev/null
+++ b/dviware/quicspool/wwfonts/s.tfm
Binary files differ
diff --git a/dviware/quicspool/wwfonts/tcomlig.mf b/dviware/quicspool/wwfonts/tcomlig.mf
new file mode 100644
index 0000000000..78b5c56935
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tcomlig.mf
@@ -0,0 +1,21 @@
+% $Header: tcomlig.mf,v 1.1 88/01/15 13:14:44 simpson Rel $
+% $Log: tcomlig.mf,v $
+%Revision 1.1 88/01/15 13:14:44 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:25 simpson
+%beta test
+%
+% This file defines characters common to roman and italic text fonts
+% that appear only when |ligs>0|.
+
+% Character codes \006 is generated
+
+cmchar "Em dash";
+beginchar(oct"006",18u#,x_height#,0);
+italcorr .61803x_height#*slant+.5u#;
+adjust_fit(letter_fit#,letter_fit#);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
diff --git a/dviware/quicspool/wwfonts/tgreekl.mf b/dviware/quicspool/wwfonts/tgreekl.mf
new file mode 100644
index 0000000000..11020b137c
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tgreekl.mf
@@ -0,0 +1,418 @@
+% $Header: tgreekl.mf,v 1.1 88/01/15 13:14:46 simpson Rel $
+% $Log: tgreekl.mf,v $
+%Revision 1.1 88/01/15 13:14:46 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:27 simpson
+%beta test
+%
+% This lowercase Greek alphabet was prepared by D. E. Knuth in December, 1979,
+% inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
+% (It has been designed for math formulas, not Greek texts.)
+% The programs were revised for the new \MF\ conventions in 1985.
+
+cmchar "Lowercase Greek alpha";
+beginchar(oct"141",11u#,x_height#,0);
+italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.5u#);
+adjust_fit(0,0); pickup fine.nib;
+pos0(hair,0); pos1(vair,-90); pos2(curve,-180); pos3(vair,-270);
+z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
+numeric theta; theta=angle(z4-z5)-90;
+pos4(stem,theta); pos5(stem,theta);
+pos6(vair,90); pos7(hair,180);
+rt x0r=hround(w-u); x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
+x6=w-u; x7+.5hair=hround(w+.5hair-epsilon);
+top y0=vround .8[bar_height,h]; bot y1r=bot y6l=-oo;
+y2=.5[y1,y3]; top y3r=h+oo; y7=1/4bar_height;
+filldraw stroke z0e{down}...pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ ...z4e---z5e...z6e{right}...{up}z7e; % diagonal, bowl, and hook
+math_fit(-.3x_height#*slant+.5curve#-u#,1/3x_height#*slant+.5hair#+.5u#);
+penlabels(0,1,2,3,4,5,6,7); endchar;
+
+cmchar "Lowercase Greek beta";
+beginchar(oct"142",9.5u#,asc_height#,desc_depth#);
+italcorr .5[x_height#,asc_height#]*slant-u#;
+adjust_fit(0,0); pickup fine.nib;
+pos0(hair,180); pos1(hair,180); pos2(vair,90);
+pos3(stem,0); pos4(vair,-90); pos5(hair,-180);
+pos6(vair,-270); pos7(curve,-360); pos8(vair,-450); pos9(hair,-540);
+x0=x1=x9; lft x0l=hround(1.5u-.5hair); x2=x4=x6=x8=.5w+.25u;
+rt x3r=hround(w-1.5u); rt x7r=hround(w-1.5u+.5curve); rt x5l=hround(x4-u);
+bot y0=-d; y1=top y6r=x_height; top y2r=h+oo; y3=.5[y2,y4];
+y5=.5[y4,y6]; top y6r-bot y4r=vstem+eps; bot y8=-oo; y7=y9=.5[y6,y8];
+if y6l<y4l: y6l:=y4l:=y5; fi
+filldraw stroke z0e---z1e...pulled_arc.e(2,3)
+ & pulled_arc.e(3,4)...{up}z5e; % stem and upper bowl
+filldraw stroke z5e{up}...pulled_arc.e(6,7)
+ & pulled_arc.e(7,8)...{up}z9e; % lower bowl
+math_fit(desc_depth#*slant+.5hair#-u#,.7x_height#*slant+.5curve#-1.5u#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Lowercase Greek gamma";
+beginchar(oct"143",10u#,x_height#,desc_depth#);
+italcorr x_height#*slant-.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(hair,180); pos2(vstem+dw,90);
+pos4(hair,0); pos5(vair,-90); pos6(hair,-180); pos7(hair,-180);
+bot y1=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
+bot y5r=-d-o; top y7=h;
+lft x1r=hround(.5u-.5hair); x2=3u; rt x4r=hround(w-2u); x5=.5[x4,x6];
+rt x4r-lft x6r=hround 1/3[hair,stem]+eps; rt x7l=hround(w-u);
+if x4l<x6l: x4l:=x6l:=x5; fi
+pos3(hair,angle(z4-z2)+90); x3=superness[x2,x4]; y3=superness[y4,y2];
+filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
+ ...z4e{down}...{left}z5e; % arc
+filldraw stroke z5e{left}...z6e{up}..{2(x7-x6),y7-y6}z7e; % stem
+math_fit(-.5772156649x_height#*slant,ic#-u#);
+penlabels(1,2,3,4,5,6,7); endchar;
+
+cmchar "Lowercase Greek delta";
+beginchar(oct"144",8u#,asc_height#,0);
+italcorr .9asc_height#*slant+.5hair#-1.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(hair,-180); pos2(vair,-90);
+numeric theta; theta=angle(18u,-h);
+pos3(stem,theta+90); pos4(stem,theta+90); pos5(1/4[hair,stem],20);
+pos6(vair,-90); pos7(curve,-180); pos8(vair,-270);
+rt x1l=hround(w-2u+.5hair); x2=.5w; x3r=3u; rt x5r=hround(w-u);
+x4=x6=x8=.5w+.5u; lft x7r=hround(1.5u-.5curve);
+y1=.9h; top y2l=h+oo; top y8r=x_height+oo; y4=y8;
+z4-z3=whatever*(18u,-h); y5=y7=.5[y6,y8]; bot y6=-oo;
+filldraw stroke z1e{x2-x1,3(y2-y1)}...z2e{left}...z3e---z4e
+ ....z5e{down}...pulled_arc.e(6,7) & pulled_arc.e(7,8); % hook and bowl
+math_fit(-.3x_height#*slant+.5curve#-u#,.7x_height#*slant-.5u#);
+penlabels(1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Lowercase Greek epsilon";
+beginchar(oct"145",8u#,x_height#,0);
+italcorr x_height#*slant+.5hair#-2u#;
+adjust_fit(0,0); pickup fine.nib;
+pos0(bar,90); pos1(bar,90); pos2(curve,180);
+pos3(vair,270); pos4(hair,300); pos6(bar,90); pos7(bar,90);
+x1=.5w+.5u; x0=x1+u; lft x2r=hround(1.5u-.5curve); x3=.5[x0,x1];
+x4r=good.x(w-u); x5=w+.5u; x6=x0; z7=z2l;
+top y0r=top y1r=h; y2=y5=y6=bar_height; bot y3r=-oo;
+path p; p=z3r{right}...{up}z5;
+numeric t; t=ypart(((x4r,y3r)--(x4r,y5))intersectiontimes p);
+y4r=ypart point t of p;
+filldraw circ_stroke z0e..pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ ...z4e{direction t of p}; % arc
+filldraw circ_stroke z6e--z7e; % bar
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6,7); endchar;
+
+cmchar "Lowercase Greek zeta";
+beginchar(oct"146",9u#,asc_height#,desc_depth#);
+italcorr .75[x_height#,asc_height#]*slant-1.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos0(hair,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
+numeric theta; theta=90-angle(25u,x_height); slope:=-x_height/25u;
+pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
+lft x0l=hround 3.5u; x1=x3=.5[x0,x2]; rt x2l=hround max(rt x0r,w-2u)+eps;
+top y0=h; top y3l=bot y1l+vstem+eps=vround(y0-.25(h-x_height)); y2=.5[y1,y3];
+if y1r>y3r: y1r:=y3r:=y2; fi
+lft x4l=hround u; x4r-x4l=(hround .6[vair,stem])-fine;
+x6+.5u=x7=w-2u; x8=.5w+.75u;
+y6=-.1d; y8=-3/4d-oo; bot y7r=-d-oo;
+ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
+y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
+filldraw circ_stroke z0e{down}...z1e{right}...{up}z2e; % opening hook
+filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}
+ ...z6e---z5e....{up}z4e
+ ..tension 1 and atleast1.5..{right}z3e...{down}z2e; % main stroke
+math_fit(-.2asc_height#*slant-.5u#,0);
+penlabels(0,1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Lowercase Greek eta";
+beginchar(oct"147",9u#,x_height#,desc_depth#);
+italcorr .8x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
+hook_in(0,a,1); % opening hook
+filldraw circ_stroke z2e--z1e; % left stem
+x4+.5stem=hround(w-1.5u+.5stem); ital_arch(2,3,4); % arch
+pos5(stem,0); x5=x4; y5-.5stem=-d-o;
+filldraw circ_stroke z5e--z4e; % right stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
+penlabels(0,a,1,2,3,4,5); endchar;
+
+cmchar "Lowercase Greek theta";
+beginchar(oct"150",8.25u#,asc_height#,0);
+italcorr .7asc_height#*slant+.5curve#-u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
+x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
+top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
+filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
+pos2'(bar,90); pos4'(bar,90); z2'=z2l; z4'=z4l;
+filldraw stroke z2'e--z4'e; % bar
+math_fit(-.3asc_height#*slant-u#+.5curve#,ic#-.5u#);
+penlabels(1,2,3,4); endchar;
+
+cmchar "Lowercase Greek iota";
+beginchar(oct"151",5u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(if monospace: u#,u# else: 0,0 fi); pickup fine.nib;
+pos1(stem,0); lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo;
+x2=x1-.25u; x4=w; hook_out(2,3,4)(skewed); % closing hook
+filldraw circ_stroke z1e{down}...{-u,-x_height}z2e; % stem
+math_fit(0,ic#); penlabels(1,2,3,4); endchar;
+
+cmchar "Lowercase Greek kappa";
+beginchar(oct"152",9u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(stem,0); pos2(stem,0); pos3(vair,90); pos4(vair,90); pos5(flare,90);
+x1=x2=x3; lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo; y2-.5stem=-oo;
+filldraw z1l---z2l..z2r---z1r..cycle; % stem
+y3=bar_height; top y4r=h; x4+.5flare=hround(w-1.5u); z5r=z4r;
+path p,q; p=z3l{right}..{right}z4l; q=z5r{right}..z5l{left}...cycle;
+numeric t; t=ypart(p intersectiontimes q);
+filldraw stroke z3e{right}..{right}z4e; % upper diagonal
+filldraw subpath(0,t) of q--cycle; % bulb
+pos7(stem,0); pos8(vair,90); pos9(hair,180);
+x9+.5hair=hround(w+.5hair-epsilon); y9=1/3x_height;
+lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
+filldraw stroke z3e{right}...z7e{down}
+ ...z8e{right}...{up}z9e; % lower diagonal
+math_fit(0,ic#); penlabels(1,2,3,4,5,7,8,9); endchar;
+
+cmchar "Lowercase Greek lambda";
+beginchar(oct"153",10.5u#,asc_height#,0);
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,90); lft x1=hround .1u; top y1r=h;
+x2=x1+2u; y2=.7[x_height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
+z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
+pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
+filldraw circ_stroke z1e{right}...z2e---z3e
+ ...{2(x4e-x3e),y4e-y3e}z4e; % long diagonal
+y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
+x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
+filldraw circ_stroke z6e--z5e; % short diagonal
+penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Lowercase Greek mu";
+beginchar(oct"154",9u#,x_height#,desc_depth#);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+pos1(stem,-180); pos2(stem,-180); x1=x2=x3; lft x1r=hround(1.5u-.5stem);
+y1+.5stem=h+oo; y2-.5stem=-d-o;
+filldraw z1r---z2r..z2l---z1l..cycle; % left stem
+pos3(stem,-180); pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=w; hook_out(7,8,9); % closing hook
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
+filldraw stroke super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e; % right stem
+math_fit(desc_depth#*slant+.5stem#-u#,ic#);
+penlabels(1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Lowercase Greek nu";
+beginchar(oct"155",8.5u#,x_height#,0);
+italcorr x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pickup fine.nib;
+pos3(vair,-90); pos4(stem,0); bot y3r=0; y4+.5stem=h+oo;
+x3-.5stem=hround(1.5u-.5stem); x4+.5stem=hround(w-1.5u+.5stem);
+filldraw circ_stroke z4e{down}...{-36u,-h}z3e; % diagonal
+pickup tiny.nib; pos1(stem,0); pos2(stem,0);
+top y1=h+min(oo,serif_drop); bot y2=0; x1=x2=x3;
+z=((z4{down}...{-36u,-h}z3)intersectionpoint((x2r,0)--(x2r,h)));
+filldraw z1l--z2l--z--z1r--cycle; % stem
+sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
+math_fit(0,ic#-1/3x_height#*slant-.5u#); penlabels(1,2,3,4); endchar;
+
+cmchar "Lowercase Greek xi";
+beginchar(oct"156",9u#,asc_height#,desc_depth#);
+italcorr .75[x_height#,asc_height#]*slant-2u#;
+adjust_fit(0,0); pickup fine.nib;
+pos10(hair,-720); pos11(vair,-630); pos12(hair,-540); pos13(vair,-450);
+lft x10l=hround 1/3w; x11=x13=.5[x10,x12]; rt x12l=hround(w-2.5u);
+top y10=h; top y13l=bot y11l+vstem+eps=vround(y10-.25(h-x_height));
+y12=.5[y11,y13]; if y11r>y13r: y11r:=y13r:=y12; fi
+pos0(curve,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
+numeric theta; theta=90-angle(22u,x_height); slope:=-x_height/22u;
+pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
+lft x0l=hround u; x1=x3=x11; x2=x12;
+y0=.5[y13,y1]; top y3l=vround .5h=bot y1l+vstem+eps; y2=.5[y1,y3];
+if y1r>y3r: y1r:=y3r:=y2; fi
+lft x4l=hround u; x4r-x4l=hround .5[vair,stem]-fine;
+x6=x7=w-2u; x8=.5w+.5u; y6=-.3d; y8=-3/4d-oo; bot y7r=-d-oo;
+ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
+y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
+filldraw circ_stroke z10e{down}...z11e{right}...{up}z12e; % opening hook
+filldraw stroke z12e{up}...z13e{left}...z0e{down}
+ ...z1e{right}...{up}z2e; % upper arc
+filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
+ ---z5e...{up}z4e...{right}z3e...{down}z2e; % main stroke
+math_fit(-.2asc_height#*slant-.5u#,0);
+penlabels(0,1,2,3,4,5,6,7,8,10,11,12,13); endchar;
+
+% Stolen from romanl.mf
+cmchar "Lowercase Greek omicron";
+beginchar(oct"157",9u#,x_height#,0);
+italcorr .7x_height#*slant;
+adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
+penpos1(vair,90); penpos3(vair',-90);
+penpos2(curve,180); penpos4(curve,0);
+x2r=hround max(.5u,1.25u-.5curve);
+x4r=w-x2r; x1=x3=.5w; y1r=h+vround 1.5oo; y3r=-oo;
+y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
+penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
+penlabels(1,2,3,4); endchar;
+
+cmchar "Lowercase Greek pi";
+beginchar(oct"160",10u#,x_height#,0);
+italcorr x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pi_stroke; % hook and bar
+pos4(hair,0); pos6(hair,0); x4=3.5u; x6=w-4u; y4=y6=y2;
+x5=3u; x7=w-2.5u; y5=y7=.5stem-oo;
+pair v[]; v1=(z4-z5) xscaled 3.14159; v2=(z6-z7) xscaled 3.14159;
+pos5(stem,angle v1-90); pos7(stem,angle v2-90);
+filldraw circ_stroke z5e{v1}...{up}z4e; % left stem
+filldraw circ_stroke z7e{v2}...{up}z6e; % right stem
+math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
+penlabels(1,2,3,4,5,6,7); endchar;
+
+cmchar "Lowercase Greek rho";
+beginchar(oct"161",8.25u#,x_height#,desc_depth#);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos1(stem,180); pos2(stem,180); pos3(vair,90);
+pos4(curve,0); pos5(vair,-90); pos6(hair,-180);
+lft x2r=hround(1.5u-.5stem); x1=x2=x6; x3=x5=.5[x2,x4];
+rt x4r=hround(w-1.5u+.5curve);
+y1-.5stem=-d-o; y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
+filldraw circ_stroke z1e..pulled_arc.e(2,3) & pulled_arc.e(3,4)
+ & pulled_arc.e(4,5) & pulled_arc.e(5,6); % stem and bowl
+math_fit(desc_depth#*slant+.5stem#-u#,ic#);
+penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Lowercase Greek sigma";
+beginchar(oct"162",10.25u#,x_height#,0);
+italcorr x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vstem,90); pos2(stem,0); pos3(vair,-90);
+pos4(stem,-180); pos5(vstem,-270); pos6(vstem,-270);
+x1=x3=x5=.5[x2,x4]; rt x2r=hround(w-2.5u);
+lft x4r=hround(1.5u-.5curve);x6=w-1.5u;
+top y1r=h; y2=y4=.5[y1,y3]; bot y3r=-oo; y5=y6=y1;
+filldraw circ_stroke z6e..pulled_arc.e(5,4) & pulled_arc.e(4,3)
+ & pulled_arc.e(3,2) & pulled_arc.e(2,1); % ear and bowl
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
+penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Lowercase Greek tau";
+beginchar(oct"163",9u#,x_height#,0);
+italcorr x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pi_stroke; % hook and bar
+pos4(hair,0); pos5(stem,0);
+x4=x5; x5-.5stem=hround(.5w-.5u-.5stem); y4=y2; y5-.5stem=-oo;
+filldraw circ_stroke z5e--z4e; % stem
+math_fit(-.7x_height#*slant+.5hair#+.5u#,-.5u#);
+penlabels(1,2,3,4,5); endchar;
+
+cmchar "Lowercase Greek upsilon";
+beginchar(oct"164",9u#,x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed); % opening hook
+pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
+x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
+filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
+ ..tension atleast 1.05..{up}z5e; % left stem and arc
+v_bulb(5,6); % closing bulb
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Lowercase Greek phi";
+beginchar(oct"165",11u#,asc_height#,desc_depth#);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+numeric light_curve; light_curve=hround(.5[stem,curve]-2stem_corr);
+pos1(vair,90); pos2(light_curve,180); pos3(vair,270); pos4(light_curve,360);
+x1=x3=.5w; lft x2r=hround(1.5u-.5light_curve); x4=w-x2;
+top y1=x_height+oo; y2=y4=.5[y1,y3]; bot y3=-oo;
+filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
+pos5(hair,0); pos6(hair,0); x5=x6=.5w; top y5=h; bot y6=-d-oo;
+filldraw stroke z5e--z6e; % stem
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Lowercase Greek chi";
+beginchar(oct"166",11u#,x_height#,desc_depth#);
+italcorr x_height#*slant+.5hair#-1.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(hair,180); pos2(vair,80); pos5(vair,80); pos6(hair,180);
+x1-.5hair=hround-.5hair; x6=w-x1; x2=w-x5=u;
+y1=y2l-h/8; top y2r=h+oo; bot y5l=-d-oo; y6=y5r+h/8;
+z0=.5[z2,z5]; z2'=z2l+(.5u,0); z5'=z5r-(.5u,0);
+numeric theta; theta=angle(z5'-z2')+90;
+pos3(stem,theta); pos4(stem,theta);
+y3r=y2r-h/8; y4l=y5l+h/8; z3l=whatever[z2',z0]; z4r=whatever[z0,z5'];
+filldraw stroke z1e{up}...z2e{right}...z3e{z4r-z3l}
+ ..z4e{z4r-z3l}...{right}z5e...{up}z6e; % major diagonal and hooks
+x8=w-x7=2u; y7+.5hair=h; y8-.5hair=-d;
+numeric theta; theta=angle(z7-z8)-90;
+pos7(hair,theta); pos8(hair,theta);
+filldraw z7l---z8l..z8r---z7r..cycle; % minor diagonal
+math_fit((desc_depth#-x_height#)*slant+ic#,ic#);
+penlabels(0,1,2,2',3,4,5',5,6,7,8); endchar;
+
+cmchar "Lowercase Greek psi";
+beginchar(oct"167",11u#,asc_height#,desc_depth#);
+italcorr x_height#*slant;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed); % opening hook
+pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
+x4=.5w+u; rt x5r=hround(w-.5u);
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57x_height;
+filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
+ ..tension atleast 1.05..{up}z5e; % left stem and arc
+v_bulb(5,6); % closing bulb
+pos7(hair,0); pos8(hair,0); x7=x8=.5w+.5u; top y7=h; bot y8=-d-oo;
+filldraw stroke z7e--z8e; % stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
+penlabels(0,1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Lowercase Greek omega";
+beginchar(oct"170",11u#,x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(0,0); pickup fine.nib;
+pos2(hair,-180); lft x2r=hround.5u; y2=y4=y6=y8=bar_height;
+y1+.5hair=h; x1=x2+.75u; pos1(hair,angle(2(x1-x2),y1-y2)+90);
+pos3(vstem+dw,-90); pos4(hair,0); pos5(vair,90);
+pos6(hair,180); pos7(vstem+dw,270); pos8(hair,360);
+bot y3r=bot y7r=-oo; top y5r=vround(.2[y4,h]+.5vair);
+x3=.5[x2,x4]; x7+.25u=.5[x6,x8]; rt x8r=hround(w-.5u);
+x5+.5stem=hround(.5w+.5stem)+eps;
+x5=.5[x4,x6]; rt x4r-lft x6r=min(stem,2hair)+2eps;
+if x4l<x6l: x4l:=x6l:=x5; fi
+filldraw circ_stroke z1e{2(x2-x1),y2-y1}...z2e{down}...z3e{right}
+ ...{up}z4e...{left}z5e; % left arc
+filldraw stroke z5e{left}...z6e{down}...z7e{right}...{up}z8e; % right arc
+v_bulb(8,9); % closing bulb
+math_fit(-bar_height#*slant,2/3ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Variant lowercase Greek sigma";
+beginchar(oct"014",8u#,x_height#,.5min(desc_depth#,.5x_height#));
+italcorr x_height#*slant-.5u#;
+adjust_fit(0,0); pickup fine.nib;
+numeric heavy_vair; heavy_vair=.25[vair,vstem];
+pos1(heavy_vair,-110); pos2(vair,-90);
+x1+.5heavy_vair=hround(w-u); y1=.1[y2r,bar_height];
+x2=min(.5w+u,x1r-eps); top y2l=h+oo;
+filldraw circ_stroke z1e{x2-x1,2(y2-y1)}...{left}z2e; % upper bulb
+numeric theta; theta=90-angle(16u,x_height); slope:=-x_height/16u;
+pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
+lft x4l=hround u; x4r-x4l=(hround .5[vair,stem])-fine;
+x6=x7=w-2u; x8=.5w+u; y6=.25[y8,y2]; y8=y7+1/8d; bot y7r=-d-oo;
+ellipse_set(2l,4l,5l,6l); ellipse_set(2r,4r,5r,6r); y4=y4r;
+filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
+ ---z5e...{up}z4e...{right}z2e; % main stroke
+math_fit(-.5x_height#*slant-.5u#,0); penlabels(1,2,4,5,6,7,8); endchar;
+
diff --git a/dviware/quicspool/wwfonts/tgreeku.mf b/dviware/quicspool/wwfonts/tgreeku.mf
new file mode 100644
index 0000000000..328b2f2906
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tgreeku.mf
@@ -0,0 +1,611 @@
+% $Header: tgreeku.mf,v 1.1 88/01/15 13:14:50 simpson Rel $
+% $Log: tgreeku.mf,v $
+%Revision 1.1 88/01/15 13:14:50 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:28 simpson
+%beta test
+%
+% Computer Modern Greek caps, analogous to the uppercase Roman letters.
+
+cmchar "Uppercase Greek Gamma";
+beginchar(oct"103",11u#-width_adj#,cap_height#,0);
+italcorr cap_height#*slant-beak_jut#-.25u#;
+adjust_fit(cap_serif_fit#,0);
+h:=vround(h-stem_corr);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+pickup crisp.nib; pos3(slab,90); pos4(hair,0);
+top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
+arm(3,4,e,beak_darkness,beak_jut); % arm and beak
+if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
+ dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi % lower serif
+math_fit(0,ic#-2.5u#); penlabels(1,2,3,4); endchar;
+
+cmchar "Uppercase Greek Delta";
+beginchar(oct"104",15u#,cap_height#,0);
+adjust_fit(0,0);
+numeric left_stem,alpha;
+left_stem=cap_hair if hefty: -3stem_corr fi;
+x1l=w-x4r=.75u; y1=y4=0;
+x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
+alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
+penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
+penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
+fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle; % triangle
+z0=whatever[z1r,z2r]=whatever[z3l,z4l];
+y5=y6=cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
+if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
+ unfill z0+.5right{down}...{z4-z3}z6--z5{z2-z1}
+ ...{up}z0+.5left--cycle; % counter
+else: unfill z0--z5--z6--cycle; fi % counter
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Theta";
+beginchar(oct"110",14u#,cap_height#,0);
+italcorr .7cap_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric light_curve; light_curve=hround(cap_curve-2stem_corr);
+penpos1(vair,90); penpos3(vround(vair+.5vair_corr),-90);
+penpos2(light_curve,180); penpos4(light_curve,0);
+if monospace: x2r=hround 1.5u;
+ interim superness:=sqrt superness; % make |"O"|, not |"0"|
+else: x2r=hround u; fi
+x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
+penstroke pulled_super_arc.e(1,2)(.5superpull)
+ & pulled_super_arc.e(2,3)(.5superpull)
+ & pulled_super_arc.e(3,4)(.5superpull)
+ & pulled_super_arc.e(4,1)(.5superpull) & cycle; % bowl
+pickup crisp.nib; pos5(cap_vstem,90); pos6(cap_vstem,90);
+lft x5=w-rt x6=hround(x2l+u)+1; y5=y6=.5[y1l,y3l];
+filldraw stroke z5e--z6e; % bar
+if serifs: pos7(hair,0); pos8(hair,0); pos9(hair,0); pos10(hair,0);
+ x7l=x8l=x5; x9r=x10r=x6;
+ y7-y5r=y9-y6r=y5l-y8=y6l-y10=vround .05h;
+ filldraw stroke z7e--z8e; % left serif
+ filldraw stroke z9e--z10e; fi % right serif
+math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#);
+penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
+
+cmchar "Uppercase Greek Lambda";
+beginchar(oct"113",12u#,cap_height#,0);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric left_stem,outer_jut,alpha;
+left_stem=cap_hair if hefty: -3stem_corr fi;
+outer_jut=.7cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
+x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
+alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
+penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
+penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
+z0=whatever[z1r,z2r]=whatever[z3l,z4l];
+if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
+ fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
+ --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
+ ...{up}z0+.5left--cycle; % left and right diagonals
+else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
+ --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
+if serifs: numeric inner_jut; pickup tiny.nib;
+ prime_points_inside(1,2); prime_points_inside(4,3);
+ if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
+ else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
+ dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark); % left serif
+ dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi % right serif
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Xi";
+beginchar(oct"116",12u#,cap_height#,0);
+italcorr cap_height#*slant-.35u#;
+adjust_fit(0,0);
+h:=vround(h-2stem_corr);
+numeric shaved_stem; shaved_stem=hround .9[vair,.85cap_stem];
+pickup crisp.nib; pos1(shaved_stem,90); pos2(hair,0);
+top y1r=h; x1=.5w; rt x2r=hround(w-.85u); y2=good.y(y1l-4/9beak)-eps;
+arm(1,2,a,.4beak_darkness,.3beak_jut); % upper right arm and beak
+pos3(hair,180); x3=w-x2; y3=y2;
+arm(1,3,b,.4beak_darkness,-.3beak_jut); % upper left arm and beak
+pos4(shaved_stem,-90); pos5(hair,0);
+bot y4r=0; x4=.5w; rt x5r=hround(w-.75u); y5=good.y(y4l+.5beak)+eps;
+arm(4,5,c,.4beak_darkness,.3beak_jut); % lower right arm and beak
+pos6(hair,180); x6=w-x5; y6=y5;
+arm(4,6,d,.4beak_darkness,-.3beak_jut); % lower left arm and beak
+pos7(shaved_stem,90); pos8(shaved_stem,90);
+lft x7=w-rt x8=hround if serifs: 2.5 else: 2 fi\\ u;
+top y7r=top y8r=vround(.52h+.5shaved_stem);
+filldraw stroke z7e--z8e; % middle bar
+if serifs: numeric xjut;
+ if bot y2>top y7r+.75cap_jut: xjut=.5cap_jut;
+ else: bot y2=top y7r+1.5xjut; fi
+ pos11(hair,0); pos12(hair,0); y11=y12;
+ pos13(hair,0); pos14(hair,0); y13=y14;
+ lft x11l=lft x13l=w-rt x12r=w-rt x14r=hround 2.5u;
+ top y11-bot y13=shaved_stem+2xjut; .5[y11,y13]=y7;
+ filldraw stroke z11e--z13e; filldraw stroke z12e--z14e; fi % middle serifs
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,11,12,13,14); endchar;
+
+cmchar "Uppercase Greek Pi";
+beginchar(oct"120",13u#+width_adj#,cap_height#,0);
+italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
+adjust_fit(cap_serif_fit#,cap_serif_fit#); pickup tiny.nib;
+h:=vround(h-stem_corr);
+pos1(cap_stem,0); pos2(cap_stem,0); pos3(cap_stem,0); pos4(cap_stem,0);
+lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
+top y1=top y3=h; bot y2=bot y4=0;
+filldraw stroke z1e--z2e; % left stem
+filldraw stroke z3e--z4e; % right stem
+penpos5(cap_bar,90); penpos6(cap_bar,90);
+x5=x1; x6=x3; y5r=y6r=h;
+fill stroke z5e--z6e; % bar
+if serifs: numeric inner_jut;
+ if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
+ else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
+ dish_serif(1,2,a,1/3,cap_jut,b,1/3,eps); % upper left serif
+ dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
+ dish_serif(3,4,e,1/3,eps,f,1/3,cap_jut); % upper left serif
+ dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi % lower left serif
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Sigma";
+beginchar(oct"122",13u#,cap_height#,0);
+italcorr cap_height#*slant-beak_jut#-.5u#;
+adjust_fit(0,0);
+numeric bot_arm_thickness;
+bot_arm_thickness=Vround .25[slab,cap_vstem];
+pickup tiny.nib; lft x1l=hround u; x1l=x2l=x4l;
+top y1=h; bot y2=h-slab; bot y4=0; x3l-x1l=4/11(w-2u); y3=.5h;
+numeric alpha[]; alpha1=((x3l-x1l)++(y2-y3))/(y2-y3);
+penpos1(alpha1*(cap_stem-tiny),0); penpos2(alpha1*(cap_stem-tiny),0);
+penpos3(alpha1*(cap_stem-tiny),0);
+alpha2=diag_ratio(1,cap_hair-tiny,y3-y4,x3r-x4l);
+penpos4(alpha2*(cap_hair-tiny),0);
+z0=whatever[z2l,z3l]=z4l+whatever*(z3r-z4r);
+filldraw z1l--z2l--z0--z4l--z4r--z3r--z2r--z1r--cycle; % diagonals
+pickup crisp.nib; pos5(slab,90); pos6(hair,0);
+top y5r=h; x5=x1; rt x6r=hround(w-u); y6=good.y(y5l-beak)-eps;
+arm(5,6,a,beak_darkness,beak_jut); % upper arm and beak
+pos7(bot_arm_thickness,-90); pos8(hair,0);
+bot y7r=0; z7l=whatever[z4,z3]; x7r:=x4; x8=x6; y8=good.y(y7l+beak)+eps;
+arm(7,8,b,beak_darkness,beak_jut); % lower arm and beak
+math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Uppercase Greek Upsilon";
+beginchar(oct"124",14u#,cap_height#,0);
+italcorr .8cap_height#*slant-.5u#;
+adjust_fit(0,0);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+lft x1l=lft x2l=hround(.5w-.5cap_stem); y1=.5h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+penpos3(.6cap_stem,0); penpos4(.75cap_curve,90); penpos5(cap_hair,180);
+z3l=lft z1l; x5r=hround u; y5=bot .8h; x4=.61803[x3l,x5l]; y4r=h+o;
+penpos5'(cap_hair,180); x5'=x5; y5'=h;
+fill z3r{up}...z4r{left}...{down}diag_end(5'r,5r,1,1,5l,5'l){up}
+ ...{right}z4l...{down}z3l--cycle; % left arc
+penpos6(.6cap_stem,0); penpos7(.75cap_curve,-90); penpos8(cap_hair,-180);
+z6r=rt z1r; x8=w-x5; y8=y5; x7=w-x4; y7=y4;
+penpos8'(cap_hair,-180); x8'=x8; y8'=h;
+fill z6r{up}...z7r{right}...{down}diag_end(8'r,8r,1,1,8l,8'l){up}
+ ...{left}z7l...{down}z6l--cycle; % right arc
+if serifs: dish_serif(2,1,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); fi % serif
+math_fit(-.8cap_height#*slant-.5u#,ic#-2.5u#);
+penlabels(1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Uppercase Greek Phi";
+beginchar(oct"125",13u#,cap_height#,0);
+italcorr .5cap_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric shaved_stem,light_curve;
+shaved_stem=cap_stem-hround 2stem_corr;
+light_curve=cap_curve-hround stem_corr;
+pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
+lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+penpos3(vair,90); penpos5(vair,-90);
+penpos4(light_curve,180); penpos6(light_curve,0);
+x4r=hround u; x6r=w-x4r; x3=x5=.5w;
+y3r=vround(.85h if serifs:-slab fi); y4=y6=.5[y3,y5];
+y5r=vround(.15h if serifs:+slab fi);
+penstroke pulled_arc.e(3,4) & pulled_arc.e(4,5)
+ & pulled_arc.e(5,6) & pulled_arc.e(6,3) & cycle; % bowl
+if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); % upper serif
+ dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi % lower serif
+math_fit(-.5cap_height#*slant-.5u#,ic#); penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Psi";
+beginchar(oct"127",14u#,cap_height#,0);
+italcorr .8cap_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric shaved_stem;
+shaved_stem=cap_stem-hround 2stem_corr;
+pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
+lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+pos3(shaved_stem,-180); pos4(shaved_stem,-180);
+pos5(vair,-90); x5=x1; bot y5r=vround(.15h if serifs:+slab fi);
+pos6(shaved_stem,0); pos7(shaved_stem,0);
+lft x3r=hround u; x7=w-x3; lft x4r=hround(3u-.5shaved_stem); x6=w-x4;
+pos3'(vair,90); pos7'(vair,90); z3'r=z3r; z7'r=z7r;
+y3=y7; y4=y6=.6h; y3=good.y(y3+.84h if serifs:-slab fi-y3');
+interim superness:=more_super;
+filldraw z3'l{right}...z4r{down} & super_arc.r(4,5)
+ & super_arc.r(5,6) & z6r{up}...z7'l{right}
+ --z7r---z7l...z6l{down} & super_arc.l(6,5)
+ & super_arc.l(5,4) & z4l{up}...z3l---z3r--cycle; % stroke
+if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); % upper serif
+ dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi % lower serif
+math_fit(-.8cap_height#*slant-.5u#,.4cap_height#*slant-1.25u#);
+penlabels(1,2,3,4,5,6,7); endchar;
+
+cmchar "Uppercase Greek Omega";
+beginchar(oct"130",13u#,cap_height#,0);
+italcorr .75cap_height#*slant-.5u#;
+adjust_fit(0,0);
+pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
+pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
+x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
+rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
+filldraw stroke z3e{up}...{up}z2e
+ & pulled_super_arc.e(2,1)(.5superpull)
+ & pulled_super_arc.e(1,4)(.5superpull)
+ & z4e{down}...{down}z5e; % bowl
+numeric arm_thickness; path p; p=z3{up}...{up}z2;
+arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
+pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
+bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
+(x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
+arm(6,7,a,.5beak_darkness,-1.2beak_jut); % left arm and beak
+pos8(arm_thickness,-90); pos9(fudged.hair,0);
+y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
+arm(8,9,b,.5beak_darkness,1.2beak_jut); % right arm and beak
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
+
+% The following letters are stolen from cmr10
+cmchar "Uppercase Greek Alpha";
+beginchar(oct"101",13u#,cap_height#,0);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric left_stem,right_stem,outer_jut,alpha;
+right_stem=cap_stem-stem_corr;
+left_stem=min(cap_hair if hefty: -3stem_corr fi,right_stem);
+outer_jut=.8cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
+x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
+alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
+penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
+penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
+z0=whatever[z1r,z2r]=whatever[z3l,z4l];
+if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
+ fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
+ --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
+ ...{up}z0+.5left--cycle; % left and right diagonals
+else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
+ --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
+penpos5(whatever,angle(z2-z1)); z5=whatever[z1,z2];
+penpos6(whatever,angle(z3-z4)); z6=whatever[z3,z4]; y6=y5;
+if hefty: y5r else: y5 fi =5/12y0;
+y5r-y5l=y6r-y6l=cap_band; penstroke z5e--z6e; % bar line
+if serifs: numeric inner_jut; pickup tiny.nib;
+ prime_points_inside(1,2); prime_points_inside(4,3);
+ if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
+ else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
+ dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark); % left serif
+ dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi % right serif
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Beta";
+beginchar(oct"102",12.5u#,cap_height#,0);
+italcorr .75cap_height#*slant-.5u#;
+adjust_fit(cap_serif_fit#,0);
+numeric left_stem,right_curve,middle_weight;
+left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
+pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
+lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+penpos3(cap_band,90); penpos4(cap_band,90);
+penpos6(middle_weight,-90); penpos7(middle_weight,-90);
+penpos8(middle_weight,90); penpos9(middle_weight,90);
+penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
+penpos11(cap_band,-90); penpos12(cap_band,-90);
+z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
+z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52h;
+x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
+x5r=hround(w-1.5u); x10r=hround(w-u);
+if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
+else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
+ x4l:=x4l-.5u; x9l:=x9l-.5u; fi
+x6l:=x6l-.5u; x11l:=x11l-.5u;
+fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e; % upper lobe
+fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e; % lower lobe
+if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
+ dish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi % lower serif
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
+
+cmchar "Uppercase Greek Epsilon";
+beginchar(oct"105",12u#-width_adj#,cap_height#,0);
+italcorr cap_height#*slant-beak_jut#-.5u#;
+adjust_fit(cap_serif_fit#,0);
+h:=vround(h-stem_corr);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+pickup crisp.nib; pos3(slab,90); pos4(hair,0);
+top y3r=h; x3=x1; rt x4r=hround(w-u); y4=good.y(y3l-beak)-eps;
+arm(3,4,e,beak_darkness,beak_jut); % upper arm and beak
+pos5(cap_bar,-90); pos6(hair,0);
+top y5l=vround(.52[y2,y1]+.5cap_bar); x5=x1;
+pos0(cap_bar,90); pos7(hair,0);
+z0=z5; x6=x7; y6-y5l=y0l-y7;
+if serifs: rt x6r=hround(w-4.4u+.5hair); y6=good.y(y5l+.6beak)+eps;
+ rt x9r=hround(w-.5u);
+else: rt x6r=hround(w-1.5u); y6=y5l+eps; rt x9r=hround(w-.75u); fi
+arm(5,6,f,beak_darkness,0); arm(0,7,g,beak_darkness,0); % middle arm and serif
+pos8(slab if not serifs:+2stem_corr fi,-90); pos9(hair,0);
+bot y8r=0; x8=x2; y9=good.y(y8l+7/6beak)+eps;
+arm(8,9,h,beak_darkness,1.5beak_jut); % lower arm and beak
+if serifs: dish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
+ dish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi % lower serif
+math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Uppercase Greek Zeta";
+beginchar(oct"106",11u#,cap_height#,0);
+italcorr cap_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric arm_thickness[],z_stem;
+if hefty: arm_thickness1=Vround(slab-vair_corr); arm_thickness2=slab;
+ z_stem=.8[vair,cap_stem];
+else: arm_thickness1=slab; arm_thickness2=vround(slab+vair_corr);
+ z_stem=.9[vair,cap_stem]; fi
+pickup tiny.nib; x3l=x4l=w-x1r=w-x2r; lft x3l=hround u;
+top y1=h; y2=min(y1,h-2/3arm_thickness1);
+bot y4=0; y3=max(y4,2/3arm_thickness2);
+numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l);
+penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
+penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
+pair delta; delta=penoffset z3-z2 of currentpen;
+fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
+ ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
+ ---cycle; % diagonal
+pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
+top y5r=h; x5=x1; lft x6r=hround 1.25u; y6=good.y(y5l-beak)-eps;
+arm(5,6,a,beak_darkness**.8,-.4beak_jut); % upper arm and beak
+pos7(arm_thickness2,-90); pos8(hair,0);
+bot y7r=0; x7=x4; rt x8r=hround(w-.9u); y8=good.y(y7l+1.2beak)+eps;
+arm(7,8,b,beak_darkness**.9,.6beak_jut); % lower arm and beak
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Uppercase Greek Eta";
+beginchar(oct"107",13u#+width_adj#,cap_height#,0);
+italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+pos3(cap_stem,0); pos4(cap_stem,0);
+lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
+top y1=top y3=h; bot y2=bot y4=0;
+filldraw stroke z1e--z2e; % left stem
+filldraw stroke z3e--z4e; % right stem
+penpos5(cap_bar,90); penpos6(cap_bar,90);
+x5=x1; x6=x3; y5=y6=.52h;
+fill stroke z5e--z6e; % bar
+if serifs: numeric inner_jut;
+ if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
+ else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
+ dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut); % upper left serif
+ dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
+ dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut); % upper left serif
+ dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi % lower left serif
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Iota";
+beginchar(oct"111",max(6u#,4u#+cap_stem#),cap_height#,0);
+italcorr cap_height#*slant-.25u#;
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut); % upper serif
+ dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut); fi % lower serif
+math_fit(0,.5ic#); penlabels(1,2); endchar;
+
+cmchar "Uppercase Greek Kappa";
+beginchar(oct"112",13.5u#,cap_height#,0);
+italcorr cap_height#*slant-.5u#;
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric right_jut,stem[],alpha[];
+if serifs: right_jut=.6cap_jut;
+else: right_jut=.4tiny; fi
+pickup tiny.nib; pos1(fudged.cap_stem,0); pos2(fudged.cap_stem,0);
+lft x1l=lft x2l=hround max(2u,3u-.5fudged.cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+stem2=max(tiny.breadth,fudged.cap_stem-3stem_corr);
+stem1=max(tiny.breadth,fudged.hair if hefty:-3stem_corr fi);
+top y3=h; rt x3r=hround(r-letter_fit-u-right_jut);
+bot y6=0; rt x6r=hround(r-letter_fit-.75u-right_jut);
+x4=x1; y4=1/3h;
+alpha1=diag_ratio(1,.5(stem1-tiny),y3-y4,x3r-x4);
+penpos3(alpha1*(stem1-tiny),0); penpos4(whatever,-90);
+alpha2=diag_ratio(1,.5(stem2-tiny),y1-y6,x6r-x1);
+penpos6(alpha2*(stem2-tiny),0);
+forsuffixes $=l,r: y3'$=h; y6'$=0; z4$=z3'$+whatever*(z3-z4);
+ z5$=z6'$+whatever*(z1-z6)=whatever[z3,z4]; endfor
+z5=.5[z5l,z5r];
+z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
+% we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
+z6'r=z6r+penoffset z1-z6 of currentpen+whatever*(z1-z6);
+z6'l=z6l+penoffset z6-z1 of currentpen+whatever*(z1-z6);
+fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle; % upper diagonal
+fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle; % lower diagonal
+if serifs: numeric inner_jut;
+ if rt x2r+cap_jut+.5u+1<=lft x6l-cap_jut: inner_jut=cap_jut;
+ else: rt x2r+cap_jut+.5u+1=lft x6l-inner_jut; fi
+ dish_serif(1,2,a,1/3,cap_jut,b,1/3,cap_jut); % upper stem serif
+ dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower stem serif
+ dish_serif(3,4,e,2/3,1.2cap_jut,f,1/2,right_jut)(dark); % upper diagonal serif
+ dish_serif(6,5,g,1/2,inner_jut,h,1/3,right_jut)(dark);fi % lower diagonal serif
+math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Mu";
+beginchar(oct"114",16u#+width_adj#,cap_height#,0);
+italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric stem[]; % thicknesses of the four strokes
+stem1=hround(fudged.hair+stem_corr);
+stem2=hround(fudged.cap_stem-4stem_corr);
+stem3=hround(fudged.hair-stem_corr);
+stem4=hround(fudged.cap_stem-3stem_corr);
+if stem4<stem1: stem4:=stem1; fi
+pickup tiny.nib; pos1(stem1,0); pos2(stem1,0);
+pos3(stem4,0); pos4(stem4,0);
+x1=x2; x3=x4; x1l=w-x3r; rt x3r=hround min(w-2u,w-3u+.5stem4);
+top y1=top y3=h; bot y2=bot y4=0;
+filldraw stroke z1e--z2e; % left stem
+filldraw stroke z3e--z4e; % right stem
+penpos5(stem2,0); penpos6(stem2,0); penpos7(stem3,0); penpos8(stem3,0);
+x5l=x1; x6l=x7l; x8=lft x3l; x6-x5=x8-x7; y5=y8=h; y6=y7;
+if hefty: y6=if monospace: vround 1/3h else: o fi;
+ numeric upper_notch,lower_notch;
+ upper_notch=h-cap_notch_cut; lower_notch=y6+cap_notch_cut;
+ x1'=rt x1r; z1'=whatever[z5l,z6l]; x3'=lft x3l; z3'=whatever[z7r,z8r];
+ z0=whatever[z5r,z6r]=whatever[z7l,z8l];
+ fill z5l..
+ if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
+ {z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
+ if y3'<upper_notch: ...{up}(x3'-1,upper_notch){right} fi
+ ..z8r--diag_out(8r,1,8l,7l){z7-z8}
+ if y0<=lower_notch: ..{z7-z8}z0{z5-z6}..
+ else: ...{down}(x0+.5,lower_notch)--(x0-.5,lower_notch){up}... fi
+ {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonals
+else: y6=0; z0=whatever[z5r,z6r]=whatever[z7l,z8l];
+ fill z5l..{z6-z5}diag_in(5l,6l,1,6r)..diag_out(7l,1,7r,8r){z8-z7}
+ ..z8r--diag_out(8r,1,8l,7l){z7-z8}..{z7-z8}z0{z5-z6}
+ ..{z5-z6}diag_in(6r,5r,1,5l)--cycle; fi % diagonals
+if serifs: serif(1,2,a,1/3,-cap_jut); % upper left serif
+ dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
+ serif(3,4,d,1/3,cap_jut); % upper right serif
+ dish_serif(4,3,e,1/3,cap_jut,f,1/3,cap_jut); fi % lower right serif
+math_fit(0,max(.5ic#-.5u#,0));
+penlabels(0,1,1',2,3,3',4,5,6,7,8); endchar;
+
+cmchar "Uppercase Greek Nu";
+beginchar(oct"115",13u#+width_adj#,cap_height#,0);
+italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
+pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
+pos3(thin_stem,0); pos4(thin_stem,0);
+pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
+x1=x2; x3=x4; x1l=w-x3r;
+rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
+filldraw stroke z1e--z2e; % left stem
+filldraw stroke z3e--z4e; % right stem
+if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
+ x5l=x1; x6r=x4; y5=h; y6=0;
+ numeric upper_notch,lower_notch;
+ upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
+ x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
+ fill z5l..
+ if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
+ {z6-z5}diag_in(5l,6l,1,6r)--z6r..
+ if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
+ {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
+else: penpos5(whatever,0); penpos6(whatever,90);
+ z5l=z1l; z6l=z4l;
+ z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
+ z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
+ filldraw stroke z5e..z6e; fi % diagonal
+if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
+ else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
+ dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
+ dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi % upper right serif
+math_fit(0,max(.5ic#-.5u#,0)); penlabels(1,1',2,3,4,4',5,6,7); endchar;
+
+cmchar "Uppercase Greek Omicron";
+beginchar(oct"117",14u#-width_adj#,cap_height#,0);
+italcorr .7cap_height#*slant-.5u#;
+adjust_fit(0,0);
+penpos1(vair',90); penpos3(vround(vair+1.5vair_corr),-90);
+penpos2(cap_curve,180); penpos4(cap_curve,0);
+if monospace: x2r=hround 1.5u;
+ interim superness:=sqrt superness; % make |"O"|, not |"0"|
+else: x2r=hround u; fi
+x4r=w-x2r; x1=x3=.5w; y1r=h+o; y3r=-o;
+y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
+penstroke pulled_super_arc.e(1,2)(.5superpull)
+ & pulled_super_arc.e(2,3)(.5superpull)
+ & pulled_super_arc.e(3,4)(.5superpull)
+ & pulled_super_arc.e(4,1)(.5superpull) & cycle; % bowl
+math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#); penlabels(1,2,3,4); endchar;
+
+cmchar "Uppercase Greek Rho";
+beginchar(oct"121",12u#,cap_height#,0);
+italcorr .75cap_height#*slant-.5u#;
+adjust_fit(cap_serif_fit#,0);
+pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
+pos0(cap_stem',0); pos0'(cap_stem,0);
+lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
+x1l=x2l=x0l=x0'l; y0=y0'=y7;
+penpos3(cap_band,90); penpos4(cap_band,90);
+penpos5(cap_curve if hefty:-3stem_corr fi,0);
+penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
+z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
+x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
+x4l:=x6l:=x4-.25cap_curve;
+filldraw stroke z1e--z0e--z0'e--z2e; % stem
+fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
+if serifs: dish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
+ dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi % lower serif
+math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); endchar;
+
+cmchar "Uppercase Greek Tau";
+beginchar(oct"123",13u#-width_adj#,cap_height#,0);
+italcorr cap_height#*slant-beak_jut#-.25u#;
+adjust_fit(0,0);
+h:=vround(h-2stem_corr);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+pickup crisp.nib; pos3(slab,90); pos4(hair,0);
+top y3r=h; x3=x1; rt x4r=hround(w-.65u); y4=good.y(y3l-beak)-eps;
+arm(3,4,e,beak_darkness,.7beak_jut); % right arm and beak
+pos5(hair,180); x5=w-x4; y5=y4;
+arm(3,5,f,beak_darkness,-.7beak_jut); % left arm and beak
+if serifs: dish_serif(1,2,a,1/3,.5cap_jut,b,1/3,.5cap_jut); % upper bracketing
+ dish_serif(2,1,c,1/3,1.414cap_jut,d,1/3,1.414cap_jut); fi % lower serif
+math_fit(-.75cap_height#*slant,ic#-2.5u#); penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Uppercase Greek Chi";
+beginchar(oct"126",13u#,cap_height#,0);
+italcorr cap_height#*slant-.25u#;
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric stem[],outer_jut,xjut,alpha[];
+stem1=cap_stem-2stem_corr; stem2=min(cap_hair,stem1);
+outer_jut=.75cap_jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
+x1l=l+letter_fit+.5u+outer_jut; x2r=r-letter_fit-u-outer_jut-xjut;
+x3l=l+letter_fit+.25u+outer_jut+xjut; x4r=r-letter_fit-.25u-outer_jut;
+y1=y2=h; y3=y4=0;
+alpha1=diag_ratio(1,stem1,h,x4r-x1l);
+alpha2=diag_ratio(1,stem2,h,x2r-x3l);
+penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
+penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
+if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
+ x12=x34=x0; y13=y24=y0;
+ z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
+ z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
+ forsuffixes $=13,24,34: z$'=.1[z$,z0]; endfor
+ fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
+ --diag_end(34',4l,.5,1,4r,24')--z24'
+ --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
+else: fill diag_end(4r,1r,.5,1,1l,4l)
+ --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
+ fill diag_end(2l,3l,.5,1,3r,2r)
+ --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi % right diagonal
+if serifs: numeric inner_jut[]; pickup tiny.nib;
+ prime_points_inside(1,4); prime_points_inside(2,3);
+ prime_points_inside(3,2); prime_points_inside(4,1);
+ if rt x1'r+cap_jut+.5u+1<=lft x2'l-cap_jut-xjut: inner_jut1=cap_jut;
+ else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
+ if rt x3'r+cap_jut+.5u+1<=lft x4'l-cap_jut-xjut: inner_jut2=cap_jut;
+ else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
+ dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1); % upper left serif
+ dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut); % lower right serif
+ dish_serif(2',3,e,2/3,inner_jut1+xjut,
+ f,1/2,outer_jut+xjut)(dark); % upper right serif
+ dish_serif(3',2,g,1/2,outer_jut+xjut,
+ h,2/3,inner_jut2+xjut)(dark); fi % lower left serif
+math_fit(0,.5ic#); penlabels(0,1,2,3,4,12,13,24,34); endchar;
diff --git a/dviware/quicspool/wwfonts/titalig.mf b/dviware/quicspool/wwfonts/titalig.mf
new file mode 100644
index 0000000000..411d79b003
--- /dev/null
+++ b/dviware/quicspool/wwfonts/titalig.mf
@@ -0,0 +1,206 @@
+% $Header: titalig.mf,v 1.1 88/01/15 13:14:56 simpson Rel $
+% $Log: titalig.mf,v $
+%Revision 1.1 88/01/15 13:14:56 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:31 simpson
+%beta test
+%
+% This file describes five italic ligatures that begin with `f'
+% and puts them in code positions \0013--\0017.
+
+numeric itc; % modified italic correction on `f' and `ff'
+itc=(asc_height#-x_height#)*slant+.75u#;
+
+ligtable "f": "i"=:oct"001", "f"=:oct"003", "l"=:oct"002",
+ "?" kern itc, "!" kern itc, ")" kern itc, "]" kern itc;
+ligtable oct"003": "i"=:oct"011", "l"=:oct"012",
+ "?" kern itc, "!" kern itc, ")" kern itc, "]" kern itc;
+
+cmchar "Italic ligature ff";
+beginchar(oct"003",5u#+max(1.5u#,stem#)+max(3.5u#,2flare#)+2letter_fit#,
+ asc_height#,desc_depth#);
+italcorr asc_height#*slant+.75u#;
+adjust_fit(0,0); pickup fine.nib;
+z98-z88=z99-z89=z14-z4=z15-z5=(4.8u+2letter_fit,0);
+.5[x88,x99]=.5w-.1u; x89-x88=u; y98=h; y99=-d;
+numeric theta; theta=angle(z88-z89);
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(.5[hair,stem],180); pos4(stem,theta+90);
+pos5(stem,theta-90); pos6(.5[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
+rt x1r=hround(.5w+1.25u); lft x8r=hround-.35u; x2=.5[x1,x4]; x7=.6[x8,x5];
+y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
+y4=.25[x_height,h]; y5=.5[-d,y4];
+z4=whatever[z88,z89]; z5=whatever[z88,z89];
+x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
+bulb(2,1,0); bulb(7,8,9); % left bulbs
+filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper middle arc
+filldraw z4r--z5l--z5r--z4l--cycle; % left stem
+filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower left arc
+pos10(flare,0); pos11(hair,0); pos12(vair,90);
+pos13(.5[hair,stem],180); pos14(stem,theta+90);
+pos15(stem,theta-90); pos16(.5[hair,stem],0);
+pos17(vair,-90); pos18(hair,-180); pos19(flare,-180);
+rt x11r=hround(w+.25u); lft x18r=hround(.5w-1.25u);
+x12=.6[x11,x14]; x17=.5[x18,x15];
+x13=.8[x12+x14-x98,x98]; x16=.8[x17+x15-x99,x99];
+y0=y10; y2=y12; y3=y13; y6=y16; y7=y17; y9=y19;
+bulb(12,11,10); bulb(17,18,19); % right bulbs
+filldraw stroke z12e{left}...z13e...{z99-z98}z14e; % upper right arc
+filldraw z14r--z15l--z15r--z14l--cycle; % right stem
+filldraw stroke z15e{z99-z98}...z16e...{left}z17e; % lower middle arc
+pickup crisp.nib; pos20(bar,90); pos21(bar,90);
+top y20r=top y21r=x_height;
+lft x20=lft x4r-.5stem-u; rt x21=rt x14l+.5stem+1.5u;
+filldraw stroke z20e--z21e; % crossbar
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
+ 20,21,88,89,98,99); endchar;
+
+cmchar "Italic ligature fi";
+beginchar(oct"001",6.5u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
+ +2letter_fit#,asc_height#,desc_depth#);
+italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
+adjust_fit(0,0); pickup fine.nib;
+.5[x88,x89]=.5(w-4u-2letter_fit); x89-x88=u; y88=h; y89=-d;
+numeric theta; theta=angle(z88-z89);
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(.5[hair,stem],180); pos4(stem,theta+90);
+pos5(stem,theta-90); pos6(.5[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
+pos11(stem,0); rt x11r=hround(w-2.5u+.5stem);
+x12=x11; x14=w; hook_out(12,13,14); % closing hook
+x1r=x11r; lft x8r=hround-.35u; x2=.5[x1,x4]; x7=.6[x8,x5];
+y9-.5flare=vround-.85d; bot y7r=-d-oo;
+y0+.5flare=vround(.85[x_height,h]); top y2r=h+oo;
+y4=.25[x_height,h]; y5=.5[-d,y4];
+z4=whatever[z88,z89]; z5=whatever[z88,z89];
+x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
+bulb(2,1,0); bulb(7,8,9); % bulbs
+filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper arc
+filldraw z4r--z5l--z5r--z4l--cycle; % left stem
+filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower arc
+top y11=x_height; filldraw stroke z11e--z12e; % right stem
+pickup crisp.nib; pos20(bar,90); pos21(bar,90);
+top y20r=top y21r=x_height;
+lft x20=lft x4r-.5stem-u; x21=x11;
+filldraw stroke z20e--z21e; % crossbar
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,20,21,88,89); endchar;
+
+cmchar "Italic ligature fl";
+beginchar(oct"002",7u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
+ +2letter_fit#,asc_height#,desc_depth#);
+italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
+adjust_fit(0,0); pickup fine.nib;
+.5[x88,x89]=.5(w-4.5u-2letter_fit); x89-x88=u; y88=h; y89=-d;
+numeric theta; theta=angle(z88-z89);
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(.5[hair,stem],180); pos4(stem,theta+90);
+pos5(stem,theta-90); pos6(.5[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
+pos11(stem,0); rt x11r=hround(w-2.5u+.5stem); rt x1r=lft x11l;
+x12=x11; x14=w; hook_out(12,13,14); % closing hook
+lft x8r=hround-.35u; x2=.5[x1,x4]; x7=.6[x8,x5];
+y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
+y4=.25[x_height,h]; y5=.5[-d,y4];
+z4=whatever[z88,z89]; z5=whatever[z88,z89];
+x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
+bulb(2,1,0); bulb(7,8,9); % bulbs
+filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper arc
+filldraw z4r--z5l--z5r--z4l--cycle; % left stem
+filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower arc
+top y11=h; filldraw stroke z11e--z12e; % right stem
+pickup crisp.nib; pos20(bar,90); pos21(bar,90);
+top y20r=top y21r=x_height;
+lft x20=lft x4r-.5stem-u; x21=x11;
+filldraw stroke z20e--z21e; % crossbar
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,20,21,88,89); endchar;
+
+cmchar "Italic ligature ffi";
+beginchar(oct"011",11.75u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
+ +4letter_fit#,asc_height#,desc_depth#);
+italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
+adjust_fit(0,0); pickup fine.nib;
+z98-z88=z99-z89=z14-z4=z15-z5=(5u+2letter_fit,0);
+numeric theta,mid_f;
+mid_f=.5[x88,x99]=.5(w-4.25u-2letter_fit); x89-x88=u;
+y98=h; y99=-d; theta=angle(z88-z89);
+pos21(stem,0); rt x21r=hround(w-2.5u+.5stem);
+x22=x21; x24=w; hook_out(22,23,24); % closing hook
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(.5[hair,stem],180); pos4(stem,theta+90);
+pos5(stem,theta-90); pos6(.5[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
+rt x1r=hround(mid_f+1.75u); lft x8r=hround-.35u;
+x2=.5[x1,x4]; x7=.6[x8,x5];
+y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
+y4=.25[x_height,h]; y5=.5[-d,y4];
+z4=whatever[z88,z89]; z5=whatever[z88,z89];
+x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
+bulb(2,1,0); bulb(7,8,9); % left bulbs
+filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper middle arc
+filldraw z4r--z5l--z5r--z4l--cycle; % left stem
+filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower left arc
+pos10(flare,0); pos11(hair,0); pos12(vair,90);
+pos13(.5[hair,stem],180); pos14(stem,theta+90);
+pos15(stem,theta-90); pos16(.5[hair,stem],0);
+pos17(vair,-90); pos18(hair,-180); pos19(flare,-180);
+x11r=x21r; lft x18r=hround(mid_f-1.25u); x12=.5[x11,x14]; x17=.5[x18,x15];
+x13=.8[x12+x14-x98,x98]; x16=.8[x17+x15-x99,x99];
+y10+.5flare=vround .85[x_height,h];
+y2=y12; y3=y13; y6=y16; y7=y17; y9=y19;
+bulb(12,11,10); bulb(17,18,19); % right bulbs
+filldraw stroke z12e{left}...z13e...{z99-z98}z14e; % upper right arc
+filldraw z14r--z15l--z15r--z14l--cycle; % middle stem
+filldraw stroke z15e{z99-z98}...z16e...{left}z17e; % lower middle arc
+top y21=x_height; filldraw stroke z21e--z22e; % right stem
+pickup crisp.nib; pos30(bar,90); pos31(bar,90);
+top y30r=top y31r=x_height;
+lft x30=lft x4r-.5stem-u; x31=x21;
+filldraw stroke z30e--z31e; % crossbar
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
+ 20,21,22,23,24,30,31,88,89,98,99); endchar;
+
+cmchar "Italic ligature ffl";
+beginchar(oct"012",12u#+.5max(1.5u#,stem#)+.5max(3.5u#,2flare#)
+ +4letter_fit#,asc_height#,desc_depth#);
+italcorr max(asc_height#*slant+.5stem#-2u#,1/3x_height#*slant+.5hair#+.5u#);
+adjust_fit(0,0); pickup fine.nib;
+z98-z88=z99-z89=z14-z4=z15-z5=(5u+2letter_fit,0);
+numeric theta,mid_f;
+mid_f=.5[x88,x99]=.5(w-4.5u-2letter_fit); x89-x88=u;
+y98=h; y99=-d; theta=angle(z88-z89);
+pos21(stem,0); rt x21r=hround(w-2.5u+.5stem);
+x22=x21; x24=w; hook_out(22,23,24); % closing hook
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(.5[hair,stem],180); pos4(stem,theta+90);
+pos5(stem,theta-90); pos6(.5[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
+rt x1r=hround(mid_f+1.25u); lft x8r=hround-.35u;
+x2=.5[x1,x4]; x7=.6[x8,x5];
+y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
+y4=.25[x_height,h]; y5=.5[-d,y4];
+z4=whatever[z88,z89]; z5=whatever[z88,z89];
+x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
+bulb(2,1,0); bulb(7,8,9); % left bulbs
+filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper middle arc
+filldraw z4r--z5l--z5r--z4l--cycle; % left stem
+filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower left arc
+pos10(flare,0); pos11(hair,0); pos12(vair,90);
+pos13(.5[hair,stem],180); pos14(stem,theta+90);
+pos15(stem,theta-90); pos16(.5[hair,stem],0);
+pos17(vair,-90); pos18(hair,-180); pos19(flare,-180); rt x11r=lft x21l;
+lft x18r=hround(mid_f-1.25u); x12=.5[x11,x14]; x17=.5[x18,x15];
+x13=.8[x12+x14-x98,x98]; x16=.8[x17+x15-x99,x99];
+y0=y10; y2=y12; y3=y13; y6=y16; y7=y17; y9=y19;
+bulb(12,11,10); bulb(17,18,19); % right bulbs
+filldraw stroke z12e{left}...z13e...{z99-z98}z14e; % upper right arc
+filldraw z14r--z15l--z15r--z14l--cycle; % middle stem
+filldraw stroke z15e{z99-z98}...z16e...{left}z17e; % lower middle arc
+top y21=h; filldraw stroke z21e--z22e; % right stem
+pickup crisp.nib; pos30(bar,90); pos31(bar,90);
+top y30r=top y31r=x_height;
+lft x30=lft x4r-.5stem-u; x31=x21;
+filldraw stroke z30e--z31e; % crossbar
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,
+ 20,21,22,23,24,30,31,88,89,98,99); endchar;
diff --git a/dviware/quicspool/wwfonts/titalms.mf b/dviware/quicspool/wwfonts/titalms.mf
new file mode 100644
index 0000000000..c783512b95
--- /dev/null
+++ b/dviware/quicspool/wwfonts/titalms.mf
@@ -0,0 +1,40 @@
+% $Header: titalms.mf,v 1.1 88/01/15 13:14:59 simpson Rel $
+% $Log: titalms.mf,v $
+%Revision 1.1 88/01/15 13:14:59 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:33 simpson
+%beta test
+%
+% This file contains miscellaneous symbols of math italic fonts.
+
+cmchar "Partial differential sign";
+beginchar(oct"171",10u#,asc_height#,0);
+italcorr .7asc_height#*slant+.5curve#-1.5u#;
+adjust_fit(0,0);
+numeric top_thickness,bot_thickness,side_thickness,pull;
+top_thickness=max(fine.breadth,vround(slab-2vair_corr));
+bot_thickness=max(fine.breadth,vround(slab-vair_corr));
+side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
+pull=min(.25,1.5superpull);
+pickup fine.nib; pos2(top_thickness,90);
+pos3(side_thickness,0); pos4(bot_thickness,-90);
+pos5(side_thickness,-180); pos6(vair,-270);
+lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side_thickness);
+x4=x6+.1u=x2+u=.5w;
+top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
+y5=.5[y4,y6]; top y6=vround 5/8h+o;
+path p; p=pulled_super_arc.l(3,4)(pull);
+numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
+pos7(thin_join,0); z7l=point t of p;
+(x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
+filldraw stroke pulled_super_arc.e(2,3)(pull)
+ & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
+ & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
+ & z6e{right}...{direction t of p}z7e; % arc and bowl
+pos1(hair,180); pos0(flare,180);
+lft x0r=min(lft x2-eps,hround 1.2u);
+y0=vround min(.85h-.5flare,.8h+.5flare)+o;
+{{less_tense; bulb(2,1,0)}}; % arc and bulb
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#-u#);
+penlabels(0,1,2,3,4,5,6,7); endchar;
diff --git a/dviware/quicspool/wwfonts/titalp.mf b/dviware/quicspool/wwfonts/titalp.mf
new file mode 100644
index 0000000000..1bc7530b36
--- /dev/null
+++ b/dviware/quicspool/wwfonts/titalp.mf
@@ -0,0 +1,114 @@
+% $Header: titalp.mf,v 1.1 88/01/15 13:15:05 simpson Rel $
+% $Log: titalp.mf,v $
+%Revision 1.1 88/01/15 13:15:05 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:34 simpson
+%beta test
+%
+% This file contains `\$' and `\&' and `?' in the so-called italic style.
+
+% Codes \0044, \0046, and \0077 are generated, as well as code |spanish_query|
+% (for a Spanish question mark) if that code value is known.
+
+cmchar "Dollar sign";
+beginchar("$",9u#,body_height#,body_height#-asc_height#);
+italcorr fig_height#*slant-.5u#; % same as for digits
+adjust_fit(0,0);
+numeric theta; theta=90-angle(50u,asc_height); slope:=-asc_height/50u;
+pickup fine.nib; pos2(slab,-90);
+pos0(cap_stem,theta); pos7(slab,-90);
+x2=x0=x7=.5w; top y2l=asc_height+oo; bot y7r=-oo;
+y0=.52asc_height; lft x3l=hround u; rt x6r=hround(w-u);
+x3r-x3l=x6r-x6l=hround .35[slab,cap_stem]-fine;
+ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
+ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
+filldraw stroke super_arc.e(2,3) & z3e{down}
+ ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
+if serifs: pos1(hair,0); pos8(hair,180);
+ pos10(flare,0); pos9(flare,180);
+ rt x1r=hround(w-u); lft x8r=hround u; y1=.5[y0,y2]; y8=.5[y0,y7];
+ {{less_tense; pos2'(slab,90); z2'=z2; bulb(2',1,10); % upper arc and bulb
+ bulb(7,8,9)}}; % lower arc and bulb
+else: pos1(.6[slab,flare],-100); pos8(flare,-100);
+ rt x1l=hround(w-1.3u); lft x8r=hround .8u;
+ top y1l=vround .92asc_height+oo; bot y8r=vround .1asc_height-oo;
+ filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
+ filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
+pickup crisp.nib; pos12(bar,0); pos11(bar,0);
+lft x12l=lft x11l=hround(.5w-.5bar); top y12=h; bot y11=-d;
+filldraw stroke z12e--z11e; % vertical crossbar
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12); endchar;
+
+cmchar "Italic ampersand";
+beginchar("&",14u#,asc_height#,0);
+italcorr asc_height#*slant-1.5u#;
+adjust_fit(if monospace:-u#,-2u# else: 0,0 fi); pickup fine.nib;
+pos1(flare,0); pos2(hair,0); pos3(vair,90);
+rt x2r=hround.5w; x3=1/3(w-u);
+top y3r=h+o; y2=.5[x_height,h]; bulb(3,2,1); % left bulb
+pos4(stem,180); pos5(vair,270); pos6(hair,360); pos7(vair,450);
+pos8(curve,540); pos9(vair,630); pos10(hair,720);
+lft x4r=hround 1.25u; x5=x7=x3+1/6u; rt x6r=hround(x5+1.5u);
+lft x8r=hround u; x9=.5w; rt x10r=hround(w-1.5u);
+y4=.5[y3,y5]; top y5l=vround .77x_height; y6=.5[y5,y7];
+y7l=good.y 1/3[y5,y3]; y8=.5[y7,y9]; bot y9r=-o; y10=bar_height;
+pos12(hair,0); pos13(curve,0); pos14(hair,0); pos15(vair,90); pos16(curve,90);
+rt x12r=rt x13r=hround(w-2u); lft x14l=hround(.5w+.5u);
+x15=x16=rt x14r+u;
+y12=y13=h-.5curve; y14=.5[bar_height,x_height];
+bot y15l=bot y16l=vround y10;
+numeric theta; theta=angle((z12-z14)xscaled 2);
+pos11(hair,theta); x11=w-4u; y11=.5[y13,y16];
+filldraw stroke pulled_arc.e(3,4) & pulled_arc.e(4,5) & pulled_arc.e(5,6)
+ & pulled_arc.e(6,7) & pulled_arc.e(7,8) & pulled_arc.e(8,9)
+ & {{interim superness:=more_super; pulled_arc.e(9,10)}}
+ ..tension .9 and 1..{dir(theta+100)}z11e; % bowls, loop, and stem
+pos11'(hair,theta-90); z11'=z11;
+forsuffixes $=l,r: path p$;
+ p$=z12${down}..z11'${-dir theta}..{down}z14$...{right}z15$; endfor
+filldraw p.l--reverse p.r--cycle; % arms
+path q[]; q1=z13r{up}..z13l{down}..cycle;
+q2=z16l{right}..z16r{left}..cycle;
+filldraw subpath(0,ypart(p.l intersectiontimes q1)) of q1--cycle; % upper bulb
+filldraw subpath(0,ypart(p.r intersectiontimes q2)) of q2--cycle; % lower bulb
+penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16); endchar;
+
+cmchar "Italic question mark";
+beginchar("?",9u#,asc_height#,0);
+italcorr asc_height#*slant-u#;
+adjust_fit(0,0); pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
+lft x10l=hround(.5w-.5dot_size); bot y11l=0; z10=z11; dot(10,11); % dot
+pickup fine.nib; pos1(flare,180); pos2(hair,180); pos3(vair,90);
+lft x1r=hround u; x3=.5w;
+y1-.5flare=x_height; top y3r=h+o; bulb(3,2,1); % bulb
+pos8(vair,-90); x8=.5w; bot y8r=.25[top y11r,x_height]+1;
+numeric theta; theta=90+angle(10u,y3-y8); slope:=(y3-y8)/10u;
+pos3'(vair,-90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
+rt x4l=hround(w-1.5u); lft x7r=hround 1/3w;
+x4l-x4r=x7l-x7r=hround .5[vair,vstem]-fine;
+ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
+ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
+pos9(hair,0); rt x9r=hround(2/3w+.5hair); y9=good.y .5[y8,y0];
+filldraw stroke super_arc.e(3',4) & z4e{down}
+ ..z5e---z6e..z7e{down} & super_arc.e(7,8)...{up}z9e; % main stroke
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
+
+iff known spanish_query: cmchar "Spanish open italic question mark";
+beginchar(spanish_query,9u#,asc_height#-desc_depth#,desc_depth#);
+adjust_fit(0,0); pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
+lft x10l=hround(.5w-.5dot_size); top y11r=h; z10=z11; dot(10,11); % dot
+pickup fine.nib; pos1(flare,0); pos2(hair,0); pos3(vair,-90);
+rt x1r=hround(w-u); x3=.5w; y1+.5flare=asc_height-x_height-d;
+bot y3r=-d-o; bulb(3,2,1); % bulb
+pos8(vair,90); x8=.5w; top y8r=.25[bot y11l,y1+.5flare]-1;
+numeric theta; theta=angle(10u,y8-y3)-90; slope:=(y8-y3)/10u;
+pos3'(vair,90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
+lft x4l=hround 1.5u; rt x7r=hround 2/3w;
+x4r-x4l=x7r-x7l=hround .5[vair,vstem]-fine;
+ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
+ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
+pos9(hair,180); lft x9r=hround(1/3w-.5hair); y9=good.y .5[y8,y0];
+filldraw stroke super_arc.e(3',4) & z4e{up}
+ ..z5e---z6e..z7e{up} & super_arc.e(7,8)...{down}z9e; % main stroke
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
diff --git a/dviware/quicspool/wwfonts/tmathit.mf b/dviware/quicspool/wwfonts/tmathit.mf
new file mode 100644
index 0000000000..54186b8678
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tmathit.mf
@@ -0,0 +1,1015 @@
+% $Header: tmathit.mf,v 1.1 88/01/15 13:15:08 simpson Rel $
+% $Log: tmathit.mf,v $
+%Revision 1.1 88/01/15 13:15:08 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:36 simpson
+%beta test
+%
+% The Computer Modern Math Italic family (by D. E. Knuth, 1979--1985)
+
+font_coding_scheme:="TeX math italic";
+mode_setup; font_setup;
+
+input tgreekl; % lower case Greek letters
+
+% From file italms.mf, font cmmi10 (output with slant)
+cmchar "Lowercase italic script l";
+beginchar(oct"044",4.5u#+max(1.5u#,stem#),asc_height#,0);
+italcorr .8asc_height#*slant-u#;
+adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
+pos1(hair,-45); pos2(hair,0); pos3(vair,90);
+pos4(stem,180); pos5(vair,270); pos6(hair,315);
+lft x1l=hround(lft x1l-x1); rt x2r=hround(w-1.5u); x3=.5w;
+lft x4r=hround .5u; x5=x3+.75u; x6=x1+w+1;
+y1=y6=.125h; y2=.8h; top y3r=h+oo; y4=.5[y3,y5]; bot y5=-oo;
+filldraw stroke z1e{10u,asc_height}...z2e{up}...pulled_arc.e(3,4)
+ & pulled_arc.e(4,5)...z6e{10u,asc_height}; % bowl and hook
+math_fit(0,ic#); penlabels(1,2,3,4,5,6); endchar;
+
+font_slant slant;
+font_x_height x_height#;
+font_quad 18u#+4letter_fit#;
+
+slant:=mono_charic#:=0; % the remaining characters will not be slanted
+currenttransform:=identity yscaled aspect_ratio scaled granularity;
+
+input titalms; % special symbols for math italic
+input tgreeku; % upper case greek letters
+input tromms; % roman math specials
+
+% The following characters come from a hodge-podge of files.
+
+% My own creation (created in just 1 hour!)
+cmchar "Right hand";
+beginchar(oct"004", 2.1body_height#, body_height#, 0);
+adjust_fit(0,0);
+picture hand;
+% On the graph I drew this on, the hand is 40 units tall and 84 (2.1*40) units
+% wide.
+handunit# := body_height#/40;
+define_pixels(handunit);
+z1=(4handunit,0); z2=(handunit,handunit); z3=(0,4handunit);
+z4=(0,34handunit); z5=(handunit,36handunit); z6=(4handunit,37handunit);
+z7=(9handunit,35handunit); z8=(16handunit,36handunit);
+z9=(30handunit,38handunit); z10=(50handunit,40handunit);
+z11=(70handunit,40handunit); z12=(78handunit,40handunit);
+z13=(84handunit,38handunit); z14=(83handunit,34handunit);
+z15=(80handunit,33handunit); z16=(56handunit,30handunit);
+z17=(52handunit,29handunit); z18=(51handunit,24handunit);
+z19=(46handunit,18handunit); z20=(45handunit,14handunit);
+z21=(40handunit,8handunit); z22=(37handunit,handunit);
+z23=(35handunit,0); z24=(27handunit,handunit); z25=(13handunit,2handunit);
+fill z1{dir 180}..z2{z3-z1}..{dir 90}z3--z4{dir 90}..z5{z6-z4}..z6{dir 0}
+..z7{dir 0}..z8..z9..z10..z11{dir 0}--z12{dir 0}..z13{dir -80}..z14{dir 225}
+..z15{dir 190}--z16..{dir 200}z17 & flex(z17,z18,z19) & flex(z19,z20,z21)
+..z22{dir 225}..z23{dir 180}..z24{z25-z23}..z25..cycle;
+hand:=currentpicture;
+endchar;
+
+% My own creation
+cmchar "Left hand";
+beginchar(oct"036", 2.1body_height#, body_height#, 0);
+adjust_fit(0,0);
+currentpicture:=hand reflectedabout ((.5w,0),(.5w,h));
+endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Subset or equal to sign";
+compute_spread(.45x_height#,.55x_height#);
+spread#':=spread#; spread':=spread; % the spread of `$=$'
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"133",14u#,v_center(spread#'+spread#+rule_thickness#));
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x2=hround 1.5u-eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]; top y1=h;
+x4=x5=.5w; y4=y1; y5=y3;
+draw z1---z4...z2{down}...z5---z3; % arc and bars
+x8=x1; lft x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
+labels(1,2,3,4,5,8,9); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Superset or equal to sign";
+compute_spread(.45x_height#,.55x_height#);
+spread#':=spread#; spread':=spread; % the spread of `$=$'
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"002",14u#,v_center(spread#'+spread#+rule_thickness#));
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
+y1-y3=spread; y2=.5[y1,y3]; top y1=h;
+x4=x5=.5w; y4=y1; y5=y3;
+draw z1---z4...z2{down}...z5---z3; % arc and bars
+x8=x1; rt x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
+labels(1,2,3,4,5,8,9); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Times operator";
+beginarithchar(oct"052"); pickup rule.nib;
+x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
+x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
+draw z1--z2; draw z3--z4; % diagonals
+labels(1,2,3,4); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Asterisk at the axis";
+beginchar(oct"071",9u#,v_center(x_height#));
+adjust_fit(0,0);
+numeric ast_flare; ast_flare=hround .7[thin_join,stem];
+x0=.5w; y0=h-.5x_height;
+for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
+ numeric theta; theta=angle(z[d]-z0);
+ fill z0+.5(0,-thin_join)rotated theta
+ ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
+ ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
+ ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
+labels(0,[-150],[-90],[-30],30,90,150); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Elementary division operator";
+beginarithchar(oct"057"); pickup rule.nib;
+x3-.5dot_size=hround(.5w-.5dot_size); w:=r:=2x3;
+y3+.5dot_size=vround(math_axis+math_spread[.5x_height,.6x_height]+.5dot_size);
+lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
+draw z1--z2; % bar
+pos3(dot_size,0); pos4(dot_size,90); z3=z4;
+pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
+dot(3,4); dot(5,6); % dots
+penlabels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Similarity sign";
+compute_spread(.45x_height#,.55x_height#);
+beginchar(oct"062",14u#,v_center(spread#+rule_thickness#));
+adjust_fit(0,0);
+pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
+if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
+lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
+bot y1=bot y3=-d; top y2=top y4=h;
+draw z1{up}...z2{right}..{right}z3...{up}z4; % stroke
+labels(1,2,3,4); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Similar or equal sign";
+compute_spread(.45x_height#,.55x_height#);
+beginchar(oct"061",14u#,v_center(2spread#+rule_thickness#));
+adjust_fit(0,0);
+pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
+if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
+lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
+bot y1=bot y3=floor math_axis; top y2=top y4=h;
+draw z1{up}...z2{right}..{right}z3...{up}z4; % stroke
+pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
+draw z5--z6; % bar
+labels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Proportionality sign";
+beginchar(oct"003",16.5u#,x_height#,0);
+italcorr x_height#*slant-.5u#;
+adjust_fit(0,-2.5u#); pickup fine.nib;
+numeric theta,phi; phi=angle(3u,h); theta=angle(5u,-h);
+pos1(vair,180); pos2(.5[vair,stem],90+.5theta); pos3(stem,90+theta);
+pos4(stem,90+theta); pos5(.5[vair,stem],90+.5theta);
+pos6(vair,180); pos7(.2[vair,stem],270+.5phi);
+pos8(.3[vair,stem],270+phi); pos9(.2[vair,stem],270+.5phi);
+lft x1r=w-rt x6l=hround u; x2=x9=.4[x1,x8]; x5=x7=.6[x8,x6];
+if monospace: x2l:=x2r; x5r:=x5l; x7r:=x7l; x9l:=x9r; fi
+y1=y6=.5h; top y2r=top y7l=h+oo; bot y5l=bot y9r=-oo;
+x8=.5[x3,x4]=.5w; y8=.5[y3,y4]=.5h;
+y3-y4=h/3; z3-z4=whatever*dir theta;
+filldraw stroke z1e{up}...z2e{right}...z3e---z4e...z5e{right}...z6e{up}
+ ...z7e{left}...{-dir phi}z8e...{left}z9e...z1e{up}; % `infinity' bowls
+erase fill (w-3.5u,h+o)--(w,h+o)
+ --(w,-o)--(w-3.5u,-o)--cycle; % erase excess
+penlabels(1,2,3,4,5,6,7,8,9); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Empty set symbol";
+beginchar(oct"172",9u#,body_height#,body_height#-asc_height#);
+adjust_fit(0,0);
+penpos1(vair,90); penpos3(vair,-90); penpos2(stem,180); penpos4(stem,0);
+if not monospace: interim superness:=sqrt(more_super*hein_super); fi
+x2r=hround max(.7u,1.45u-.5stem);
+x4r=w-x2r; x1=x3=.5w; y1r=asc_height+o; y3r=-o;
+y2=y4=.5asc_height-vair_corr; y2l:=y4l:=.52asc_height;
+penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
+pickup rule.nib; lft x6=hround 2u-eps; x5=w-x6; top y5=h+o; bot y6=-d-o;
+draw z5--z6; % diagonal
+penlabels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Nabla or backwards-difference operator";
+beginchar(oct"050",15u#,cap_height#,0);
+adjust_fit(0,0);
+numeric right_stem,alpha;
+right_stem=cap_hair if hefty: -3stem_corr fi;
+x1l=w-x4r=.75u; y1=y4=h;
+x2-x1=x4-x3; x3l=x2l+apex_corr; y2=y3=-apex_o-apex_oo;
+alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
+penpos1(alpha*cap_stem,0); penpos2(alpha*cap_stem,0);
+penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
+fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle; % triangle
+z0=whatever[z1r,z2r]=whatever[z3l,z4l];
+y5=y6=h-cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
+if y0>cap_notch_cut: y0:=cap_notch_cut;
+ unfill z0+.5right{up}...{z4-z3}z6--z5{z2-z1}
+ ...{down}z0+.5left--cycle; % counter
+else: unfill z0--z5--z6--cycle; fi % counter
+penlabels(0,1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Section sign";
+beginchar(oct"070",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
+adjust_fit(0,0); pickup fine.nib;
+numeric sstem; sstem=hround .75[hair,stem];
+pos0(stem,0); pos1(hair,0); pos2(vair,90); pos3(sstem,180); pos4(vair,270);
+pos5'(sstem,0); pos5(sstem,180);
+pos6(vair,90); pos7(sstem,0); pos8(vair,-90); pos9(hair,-180); pos10(stem,-180);
+top y2r=h+oo; bot y8r=-d-oo; y2-y1=y9-y8=(y2-y8)/8;
+y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
+y2-y4=y4-y6=y6-y8;
+rt x1r=hround(w-1.5u); lft x3r=hround 1.25u;
+x2=x4=x6=x8=.5w; x5=x7=w-x3; x5'=x3; x9=w-x1;
+bulb(2,1,0); bulb(8,9,10); % bulbs
+filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
+ ...z5e{down}...{left}z6e; % upper stroke
+filldraw stroke z4e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
+ ...z7e{down}...{left}z8e; % upper stroke
+penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Double dagger mark";
+beginchar(oct"131",8u#,asc_height#,desc_depth#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
+pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
+x1=x2=x3; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
+x4-.5stem=hround u; x5=w-x4;
+y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
+filldraw circ_stroke z1e{down}..{down}z2e; % top stem
+filldraw circ_stroke z3e{up}..{up}z2e; % upper middle stem
+filldraw circ_stroke z4e{right}..{right}z2'e; % top left bulb
+filldraw circ_stroke z5e{left}..{left}z2'e; % top right bulb
+pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
+pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
+x6=x7=x8=x1; x9=x4; x0=x5;
+y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
+filldraw circ_stroke z6e{down}..{down}z7e; % lower middle stem
+filldraw circ_stroke z8e{up}..{up}z7e; % bottom stem
+filldraw circ_stroke z9e{right}..{right}z7'e; % bottom left bulb
+filldraw circ_stroke z0e{left}..{left}z7'e; % bottom right bulb
+penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Minus";
+beginarithchar(oct"055"); pickup rule.nib;
+lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
+draw z1--z2; % bar
+labels(1,2); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Plus-or-minus sign";
+beginarithchar(oct"010"); pickup rule.nib;
+numeric shiftup; shiftup=vround 1.5u;
+x1=x2=.5w; lft x3=lft=x5=hround u-eps; x4=x6=w-x3;
+.5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y2;
+draw z1--z2; % stem
+draw z3--z4; % plus bar
+draw z5--z6; % minus bar
+labels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Downward arrow";
+beginchar(oct"067",9u#,asc_height#,asc_depth#);
+adjust_fit(0,0); pickup crisp.nib;
+pos1(rule_thickness,0); pos2(rule_thickness,0);
+pos3(bar,90); pos4(bar,90);
+lft x1l=hround(.5w-.5rule_thickness); y1+.5rule_thickness=h;
+x0=x1=x2; bot y0=-d; x0-x3=x4-x0=3u+eps;
+y3=y4=y0+.24asc_height+eps;
+pos5(bar,angle(z4-z0)); z5l=z0;
+pos6(bar,angle(z3-z0)); z6l=z0;
+z9=.381966[.5[z3,z4],z0];
+numeric t; path p; p=z4r{z9-z4}..z6r;
+t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
+filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
+ --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
+ --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
+penlabels(0,1,2,3,4,5,6,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Upward arrow";
+beginchar(oct"066",9u#,asc_height#,asc_depth#);
+italcorr .76asc_height#*slant+.5crisp#-u#;
+adjust_fit(0,0); pickup crisp.nib;
+pos1(rule_thickness,0); pos2(rule_thickness,0);
+pos3(bar,90); pos4(bar,90);
+lft x1l=hround(.5w-.5rule_thickness); y1-.5rule_thickness=-d;
+x0=x1=x2; top y0=h; x0-x3=x4-x0=3u+eps;
+y3=y4=y0-.24asc_height-eps;
+pos5(bar,angle(z4-z0)); z5l=z0;
+pos6(bar,angle(z3-z0)); z6l=z0;
+z9=.381966[.5[z3,z4],z0];
+numeric t; path p; p=z4l{z9-z4}..z6r;
+t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
+filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
+ --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3l{z9-z3}..z5r)
+ --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
+penlabels(0,1,2,3,4,5,6,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Leftward arrow";
+compute_spread(.45x_height#,.55x_height#);
+beginchar(oct"064",18u#,v_center(spread#+rule_thickness#));
+adjust_fit(0,0); pickup crisp.nib;
+pos1(rule_thickness,90); pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
+y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft x0=hround u;
+y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
+pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); z6l=z0;
+z9=.381966[.5[z3,z4],z0];
+numeric t; path p; p=z4r{z9-z4}..z6r;
+t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
+filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
+ --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
+ --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
+penlabels(0,1,2,3,4,5,6,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Rightward arrow";
+compute_spread(.45x_height#,.55x_height#);
+beginchar(oct"065",18u#,v_center(spread#+rule_thickness#));
+adjust_fit(0,0); pickup crisp.nib;
+pos1(rule_thickness,90); pos2(rule_thickness,90); pos3(bar,0); pos4(bar,0);
+y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt x0=hround(w-u);
+y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
+pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); z6l=z0;
+z9=.381966[.5[z3,z4],z0];
+numeric t; path p; p=z4l{z9-z4}..z6r;
+t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
+filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
+ --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
+ --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
+penlabels(0,1,2,3,4,5,6,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Proper subset sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"032",14u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x2=hround 1.5u-eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]=math_axis;
+x4=x5=.5w; y4=y1; y5=y3;
+draw z1---z4...z2{down}...z5---z3; % arc and bars
+labels(1,2,3,4,5); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Proper superset sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"033",14u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
+y1-y3=spread; y2=.5[y1,y3]=math_axis;
+x4=x5=.5w; y4=y1; y5=y3;
+draw z1---z4...z2{down}...z5---z3; % arc and bars
+labels(1,2,3,4,5); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Element sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"037",12u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x2=hround 1.5u-eps; x1=x3=x6=w-x2;
+y1-y3=spread; y2=y6=.5[y1,y3]=math_axis;
+x4=x5=.5w+u; y4=y1; y5=y3;
+draw z1---z4...z2{down}...z5---z3; % arc and bars
+draw z2--z6; % middle bar
+labels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Logical not sign";
+beginchar(oct"035",12u#,x_height#,0);
+italcorr x_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround u-eps; x2=x3=w-x1;
+y1=y2=good.y .5[bar_height,h]; y2-y3=1.2(h-bar_height);
+draw z1--z2--z3; % bar and stem
+labels(1,2,3); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Less than sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"074",14u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x2=hround 1.5u-eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]=math_axis;
+draw z1--z2--z3; % diagonals
+labels(1,2,3); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Greater than sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"076",14u#,v_center(spread#+rule_thickness#));
+italcorr math_axis#*slant-u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x2=hround(w-1.5u)+eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]=math_axis;
+draw z1--z2--z3; % diagonals
+labels(1,2,3); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Unequals sign";
+compute_spread(.45x_height#,.55x_height#);
+beginchar(oct"063",14u#,v_center(4spread#+rule_thickness#));
+italcorr h#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
+y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
+draw z1--z2; draw z3--z4; % bars
+lft x6=hround 3.5u-eps; x5=w-x6; top y5=h+o; bot y6=-d-o;
+draw z5--z6; % diagonal
+labels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Less than or equal to sign";
+compute_spread(.45x_height#,.55x_height#);
+spread#':=spread#; spread':=spread; % the spread of `$=$'
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"011",14u#,v_center(spread#'+spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x2=hround 1.5u-eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]; top y1=h;
+draw z1--z2--z3; % diagonals
+x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % bar
+labels(1,2,3,8,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Greater than or equal to sign";
+compute_spread(.45x_height#,.55x_height#);
+spread#':=spread#; spread':=spread; % the spread of `$=$'
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(oct"012",14u#,v_center(spread#'+spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
+y1-y3=spread; y2=.5[y1,y3]; top y1=h;
+draw z1--z2--z3; % diagonals
+x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % bar
+labels(1,2,3,8,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Equivalence or congruence sign";
+compute_spread(.45x_height#,.55x_height#);
+beginchar(oct"060",14u#,v_center(2spread#+rule_thickness#));
+italcorr h#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround u-eps; x3=x5=x1; x2=x4=x6=w-x1;
+y1=y2; y3=y4=math_axis; y5=y6; y1-y3=y3-y5=spread;
+draw z1--z2; % upper bar
+draw z3--z4; % middle bar
+draw z5--z6; % lower bar
+labels(1,2,3,4,5,6); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Reverse slash (backslash)";
+beginchar(oct"134",9u#,body_height#,paren_depth#);
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround u-eps; top y1=h+eps;
+rt x2=hround(w-u)+eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+labels(1,2); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Vertical line";
+beginchar(oct"174",5u#,body_height#,paren_depth#);
+italcorr body_height#*slant+.5rule_thickness#-2u#;
+adjust_fit(0,0); pickup rule.nib;
+x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
+draw z1--z2; % stem
+labels(1,2); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Left curly brace";
+beginchar(oct"173",9u#,body_height#,paren_depth#);
+italcorr body_height#*slant+.5vair#-u#;
+adjust_fit(0,0); pickup fine.nib;
+forsuffixes $=1,1',4,4',7,7': pos$(vair,0); endfor
+forsuffixes $=2,3,5,6: pos$(stem,0); endfor
+x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
+lft x4l=hround(1.5u-.5vair); lft x2l=hround(.5w-.5stem);
+top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
+y1-y2=y3-y4=(y1-y4)/4; y1-y1'=y4-y4'=y7'-y7=vair-fine;
+filldraw z1l{left}...z2l---z3l...{left}z4l
+ --z4'l{right}...z5l---z6l...{right}z7l
+ --z7r--z7'r{left}...z6r---z5r...{left}.5[z4r,z4'r]{right}
+ ...z3r---z2r...{right}z1'r--z1r--cycle; % stroke
+penlabels(1,2,3,4,5,6,7); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Right curly brace";
+beginchar(oct"175",9u#,body_height#,paren_depth#);
+italcorr math_axis#*slant+.5vair#-u#;
+adjust_fit(0,0); pickup fine.nib;
+forsuffixes $=1,1',4,4',7,7': pos$(vair,0); endfor
+forsuffixes $=2,3,5,6: pos$(stem,0); endfor
+x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
+rt x4r=hround(w-1.5u+.5vair); rt x2r=hround(.5w+.5stem);
+top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
+y1-y2=y3-y4=(y1-y4)/4; y1-y1'=y4-y4'=y7'-y7=vair-fine;
+filldraw z1r{right}...z2r---z3r...{right}z4r
+ --z4'r{left}...z5r---z6r...{left}z7r
+ --z7l--z7'l{right}...z6l---z5l...{right}.5[z4l,z4'l]{left}
+ ...z3l---z2l...{left}z1'l--z1l--cycle; % stroke
+penlabels(1,2,3,4,5,6,7); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Straight double quotes";
+beginchar(oct"042",9u#,asc_height#,0);
+numeric top_width#,spread#; top_width#=if serifs: flare# else: stem# fi;
+spread#=max(3u#,top_width#+.5u#); define_pixels(spread);
+italcorr asc_height#*slant+.5top_width#+.5spread#-4u#;
+adjust_fit(0,0);
+x1=x2; x3=x4=w-x1; x3-x1=spread+2; y1=y3;
+y2=y4=max(.5[bar_height,x_height]+.5vair,h-x_height);
+if serifs: pickup crisp.nib; pos1(flare,0); pos2(vair,0);
+ pos3(flare,0); pos4(vair,0);
+ y1+.5stem=h; filldraw circ_stroke z1e--z2e; % left stem and bulb
+ filldraw circ_stroke z3e--z4e; % right stem and bulb
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ pos3(stem,0); pos4(vair,0);
+ top y1=h; filldraw stroke z1e--z2e; % left stem
+ filldraw stroke z3e--z4e; fi % right stem
+penlabels(1,2,3,4); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Infinity";
+beginchar(oct"001",18u#,x_height#,0);
+italcorr .7x_height#*slant-.5u#;
+adjust_fit(0,0); pickup fine.nib;
+numeric theta,phi;
+if monospace: phi=-theta=90;
+else: phi=angle(4u,h); theta=angle(6u,-h); fi
+pos1(vair,180); pos2(.5[vair,curve],90+.5theta); pos3(curve,90+theta);
+pos4(curve,90+theta); pos5(.5[vair,curve],90+.5theta);
+pos6(vair,180); pos7(.2[vair,curve],270+.5phi);
+pos8(.3[vair,curve],270+phi); pos9(.2[vair,curve],270+.5phi);
+lft x1r=w-rt x6l=hround u; x2=x9=.4[x1,x8]; x5=x7=.6[x8,x6];
+if monospace: x2l:=x2r; x5r:=x5l; x7r:=x7l; x9l:=x9r; fi
+y1=y6=.5h; top y2r=top y7l=h+oo; bot y5l=bot y9r=-oo;
+x8=.5[x3,x4]=.5w; y8=.5[y3,y4]=.5h;
+y3-y4=h/3; z3-z4=whatever*dir theta;
+filldraw stroke z1e{up}...z2e{right}...z3e---z4e...z5e{right}
+ ...z6e{up}...z7e{left}...{-dir phi}z8e...{left}z9e...z1e{up}; % bowls
+penlabels(1,2,3,4,5,6,7,8,9); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Set union sign";
+beginchar(oct"005",12u#,.8asc_height#,0);
+italcorr .8asc_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
+y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
+draw z1---z2...z3...z4---z5; % stems and cup
+labels(1,2,3,4,5); endchar;
+
+% From font cmsy10, file sym.mf
+cmchar "Set intersection sign";
+beginchar(oct"034",12u#,.8asc_height#,0);
+italcorr .8asc_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
+y3=good.y h+o; bot y1=-o; y2=y4=2/3[y1,y3]; y5=y1;
+draw z1---z2...z3...z4---z5; % stems and cap
+labels(1,2,3,4,5); endchar;
+
+% My own creation
+cmchar "Square root extender";
+beginchar(oct"006",12u#,14u#,0);
+ adjust_fit(0,0); pickup rule.nib;
+ bot lft z1=(0,h); bot rt z2=(w+2u,h); draw z1--z2;
+ penlabels(1,2);
+endchar;
+
+% From font cmsy10, file symbol.mf (hacked up to be above baseline)
+cmchar "Radical sign";
+beginchar(oct"013",15u#,14u#,2u#);
+ adjust_fit(0,-letter_fit#); pickup rule.nib;
+ x1=good.x 4/9w; x2=good.x(w+.5); bot y1=-2u; bot y2=14u;
+ draw z1--z2; % diagonal
+ pickup crisp.nib; pos3(max(curve,rule_thickness),0);
+ x3l=1.5[x2,x1]; y3=.5[y1,y2];
+ pos4(rule_thickness,0); x4=x1; bot y4=-2u;
+ pos5(vair,-45); x5l=good.x(x3l-u); z5l=whatever[z3r,z2];
+ z6=z5r+whatever*(z2-z3r)=whatever[z3l,z4l];
+ z7=whatever[z1,z2]=z3r+whatever*(z4l-z3l);
+ filldraw z5r--z6--z4l--z4--z7--z3r--z5l--cycle; % left diagonal and serif
+ penlabels(1,2,3,4,5,6,7);
+endchar;
+
+% The following TRW logo is designed by Mike Urban and put in the Bell
+% System logo position. The Bell System logo is not even used by AT&T
+% anymore and I work for TRW---so there. There is some perverse
+% appropriateness in having the escape sequence \(bs.
+def fixpt(expr pta,ptb,theta)=
+ if known xpart pta:
+ ((ypart pta)-(ypart ptb))/((xpart pta)-(xpart ptb))=
+ (sind theta)/(cosd theta);
+ else:
+ ((xpart pta)-(xpart ptb))/((ypart pta)-(ypart ptb))=
+ (cosd theta)/(sind theta);
+ fi;
+enddef;
+
+def over(expr pta,ptb,delta)=
+ xpart pta = (xpart ptb)+(delta/cosd 20);
+enddef;
+
+input logodesign;
+
+a#:=cap_height#/3.91;
+define_pixels(a);
+beginchar(oct"007", 12.82a#, 3.91a#, 0);
+LOGO;
+endchar;
+
+% From the font cmsy10, file sym.mf
+cmchar "Integral sign";
+beginchar(oct"015",5.25u#+max(1.25u#,stem#)+2max(1.5u#,curve#),
+ asc_height#,desc_depth#);
+italcorr asc_height#*slant-.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(curve,0); pos2(hair,0); pos3(vair,90); pos4(.6[hair,stem],180);
+pos5(stem,180); pos5'(stem,0); z5'=z5; pos6(.6[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(curve,-180);
+x7=w-x3=2.4u; rt x1r=max(rt x3+eps,hround(w-u)); x9=w-x1;
+x5=.5[x4,x6]; x4-x6=1.5u; lft x5r=hround(.5w-.5stem);
+y9-.5curve=vround(-.9d-o+vair); y3-y1=y9-y7;
+top y3r=h+o; bot y7r=-d-o; y5=.5[y3,y7]=.5[y4,y6]; y4-y6=2/3(y3-y7);
+bulb(3,2,1); bulb(7,8,9); % bulbs
+filldraw stroke z3e{left}...z4e{(z5e-z4e)xscaled 1.1}
+ ..tension atleast 1 and atleast .8..{z5-z4}z5e; % upper stem
+filldraw stroke z5'e{z6-z5}..tension atleast.8 and atleast 1
+ ..{(z6e-z5'e)xscaled 1.1}z6e...{left}z7e; % lower stem
+math_fit(0,-2u#);
+% It looks better with troff if we move it over 1 unit to the left
+currentpicture:=currentpicture shifted (-1u,0);
+penlabels(1,2,3,4,5,6,7,8,9); endchar;
+
+% From the font cmr10, file punct.mf
+cmchar "Hash mark (number sign)";
+if monospace: compute_spread(.6x_height#,.7x_height#);
+else: compute_spread(.45x_height#,.55x_height#); fi
+beginchar("#",15u#,asc_height#,asc_depth#);
+italcorr (math_axis#+.5(spread#+rule_thickness#))*slant-.5u#;
+adjust_fit(0,0);
+pickup rule.nib; lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
+y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
+draw z1--z2; % upper bar
+draw z3--z4; % lower bar
+lft x6=hround 3u; rt x7=hround(w-3u); x5-x6=x7-x8;
+x8=good.x if monospace: .6 else: .5 fi\\w;
+top y5=top y7=h+eps; bot y6=bot y8=-d-eps;
+y15=y1; z15=whatever[z5,z6]; y36=y3; z36=whatever[z5,z6];
+y27=y2; z27=whatever[z7,z8]; y48=y4; z48=whatever[z7,z8];
+draw z5--if x5>x6+1:(good.x(x15+.5),y1)--(good.x(x15-.5),y1)
+ --(good.x(x36+.5),y3)--(good.x(x36-.5),y3)--fi\\z6; % left diagonal
+draw z7--if x7>x8+1:(good.x(x27+.5),y2)--(good.x(x27-.5),y2)
+ --(good.x(x48+.5),y4)--(good.x(x48-.5),y4)--fi\\z8; % right diagonal
+labels(1,2,3,4,5,6,7,8,15,27,36,48); endchar;
+
+% From font cmr10, file punct.mf
+cmchar "Plus sign";
+beginarithchar("+"); pickup rule.nib;
+x1=x2=good.x .5w; top y1=h+eps; .5[y1,y2]=math_axis;
+lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
+draw z1--z2; % stem
+draw z3--z4; % crossbar
+labels(1,2,3,4); endchar;
+
+% From font cmr10, file accent.mf
+cmchar "Grave accent";
+beginchar(oct"140",9u#,min(asc_height#,2x_height#),0);
+adjust_fit(0,0);
+if serifs: pickup crisp.nib; x1-.5stem=hround 2u; x2=2/3[x1,w-x1];
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ lft x1l=hround 1.5u; rt x2r=hround(.5w+.25u+.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+% From font cmr10, file accent.mf
+cmchar "Acute accent";
+beginchar(oct"047",9u#,min(asc_height#,2x_height#),0);
+italcorr h#*slant-if serifs: 1.5 fi u#;
+adjust_fit(0,0);
+if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+% From font cmr10, file punct.mf
+cmchar "Equals sign";
+compute_spread(.45x_height#,.55x_height#);
+beginchar("=",14u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
+y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
+draw z1--z2; % upper bar
+draw z3--z4; % lower bar
+labels(1,2,3,4); endchar;
+
+% From font cmr10, file punct.mf
+cmchar "At sign";
+beginchar("@",14u#,asc_height#,0);
+italcorr .7asc_height#*slant-.5u#;
+adjust_fit(0,if hefty or monospace:-2u# else: 0 fi);
+pickup fine.nib; pos0(fudged.hair,0); pos1(vair,90);
+pos2(fudged.stem,180); pos3(vair,270);
+pos4(fudged.stem,-180); pos5(fudged.stem,-180);
+pos6(vair,-90); pos7(fudged.hair,0);
+pos8(vair,90); pos9(fudged.hair,180);
+pos10(vair,270); pos11(.5[vair,flare],360);
+x1=x3=.5[x0,x2]; y0=y2=.5[y1,y3];
+x8=x10=.5w; y7=y9=.5[y8,y10];
+lft x9r=hround u; x7=w-x9; top y8r=h+oo; bot y10r=-oo;
+top y1r=vround(.8[y10,y8]+.5vair); bot y3r=vround(.2[y10,y8]-.5vair);
+x6l=1/3[x5l,x7l]; y6=y3; y11=good.y(.1[y10,y8]-.5);
+x0=x4=x5; y4=.8[y3,y1]; y5=2/3[y7,y6];
+if hefty or monospace: lft x2r=hround(5u-.5fudged.stem);
+ rt x0r=hround(w-3u); x11r=x0r;
+else: lft x2r=hround 3.4u; x0=w-x2; x11r=x7r; fi
+filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % left inner bowl
+filldraw stroke super_arc.e(3,0) & super_arc.e(0,1); % right inner bowl
+filldraw stroke super_arc.e(8,9) & super_arc.e(9,10)
+ & term.e(10,11,right,1,4); % left outer bowl and terminal
+if hefty or monospace: {{interim superness:=hein_super;
+ filldraw stroke super_arc.e(0,8)}}; % link
+else: (x,y6r)=whatever[z6l,z7l]; x6r:=x;
+ filldraw stroke z4e---z5e...z6e{right}...{up}z7e
+ & super_arc.e(7,8); fi % stem and link
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
+
+% From font cmr10, file accent.mf
+cmchar "Tilde (squiggle) accent";
+beginchar(oct"176",9u#,min(asc_height#,10/7x_height#+.5dot_size#),0);
+italcorr h#*slant-u#;
+adjust_fit(0,0);
+if serifs: numeric theta; theta=angle(1/6(6u-vair),1/4(h-x_height));
+ pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
+ pos1(vair,theta+90); pos2(vair,theta+90);
+ pos3(vair,theta+90); pos4(vair,theta+90);
+ z2-z1=z4-z3=(mid_width-crisp)*dir theta;
+ lft x1r=w-rt x4l=hround 1.5u; top y4r=h;
+ bot y1l=vround(bot y1l+min(2/3[x_height,h],y3l-.25vair)-top y1r);
+ pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
+ filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
+ --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
+else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
+ pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
+ lft x1r=w-rt x5l=hround 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
+ bot y1=bot y4l=vround(.75[x_height,h]-vair);
+ top y2r=top y5=h; y3=.5[y2,y4];
+ filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
+penlabels(1,2,3,4,5); endchar;
+
+% From font cmsy10, file symbol.mf
+cmchar "Circle for copyright, etc.";
+beginchar(oct"135",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points; draw_circle; % circle
+labels(1,2,3,4,5,6,7,8); endchar;
+
+% From font cmr10, file accent.mf
+cmchar "Circumflex (hat) accent";
+beginchar(oct"041",9u#,min(asc_height#,2x_height#),0);
+if serifs: italcorr .5[x_height#,h#]*slant+.5hair#-1.75u#;
+ adjust_fit(0,0);
+ pickup crisp.nib; pos2(.5[vair,curve],90); top y2r=h; x2=.5w;
+ x1=w-x3=good.x 2.25u; y1=y3=.5[x_height,y2];
+ pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
+ filldraw stroke z1e--z2e--z3e; % diagonals
+else: italcorr 2/3[x_height#,h#]*slant-.5stem#+.5vair#-.75u#;
+ adjust_fit(0,0);
+ pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
+ pos2(stem,0); top y2=h; x2=.5w; bot y1=bot y3=vround 2/3[h,x_height]-eps;
+ lft x1l=hround(rt x2r-3.25u-.5vair); % same slope as in the acute accent
+ z0=whatever[z1r,z2r]=whatever[z2l,z3l];
+ y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=w-x4l;
+ filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
+penlabels(0,1,2,3,4); endchar;
+
+% From font cmr10, file accent.mf
+cmchar "Circumflex (hat) accent";
+beginchar(oct"136",9u#,min(asc_height#,2x_height#),0);
+if serifs: italcorr .5[x_height#,h#]*slant+.5hair#-1.75u#;
+ adjust_fit(0,0);
+ pickup crisp.nib; pos2(.5[vair,curve],90); top y2r=h; x2=.5w;
+ x1=w-x3=good.x 2.25u; y1=y3=.5[x_height,y2];
+ pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
+ filldraw stroke z1e--z2e--z3e; % diagonals
+else: italcorr 2/3[x_height#,h#]*slant-.5stem#+.5vair#-.75u#;
+ adjust_fit(0,0);
+ pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
+ pos2(stem,0); top y2=h; x2=.5w; bot y1=bot y3=vround 2/3[h,x_height]-eps;
+ lft x1l=hround(rt x2r-3.25u-.5vair); % same slope as in the acute accent
+ z0=whatever[z1r,z2r]=whatever[z2l,z3l];
+ y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=w-x4l;
+ filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
+penlabels(0,1,2,3,4); endchar;
+
+% My own creation
+cmchar "Box rule";
+beginchar(oct"132",1u#,cap_height#+2u#,4.3u#);
+italcorr body_height#*slant+.5rule_thickness#-2u#;
+adjust_fit(0,0); pickup crisp.nib;
+pos1(vair,0); pos2(vair,0);
+x1=x2=hround 0; y1=h; y2=-d;
+filldraw stroke z1e--z2e; % stem
+penlabels(1,2); endchar;
+
+% My own creation. Only used by otroff. See note below.
+cmchar "Underscore";
+beginchar("_",9.4u#,x_height#,.7u#);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric below_baseline; below_baseline#:=4u#;
+define_pixels(below_baseline);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(-below_baseline); x2=hround(w);
+x1=0;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% My own creation (This is only used by ditroff. Ditroff's underscore
+% needs to be a frog's hair longer than otroff's.)
+cmchar "Underscore";
+beginchar(oct"041",9.4u#,x_height#,.7u#);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric below_baseline; below_baseline#:=4u#;
+define_pixels(below_baseline);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(-below_baseline); x2=hround(w+1u);
+x1=0;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% The delimiters are from the font cmex10, file bigdel.mf. I had to hack
+% them up extensively though to get them to work with troff. Troff wants
+% everything lined up in the center and the widths of the floor and ceiling
+% characters are the same as the parentheses.
+cmchar "Extensible left bracket---top";
+beginchar(oct"022",8u#,cap_height#+2u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(heavy_rule_thickness,0); pos2(heavy_rule_thickness,0);
+top y1=h; y2=-d; x1=x2=hround(.5w);
+filldraw stroke z1e--z2e; % stem
+pos3(heavy_rule_thickness,90); pos4(heavy_rule_thickness,90);
+x3=x1l; rt x4=hround(w-.75u+.5heavy_rule_thickness); y3r=y4r=y1;
+filldraw stroke z3e--z4e; % upper bar
+penlabels(1,2,3,4); endchar;
+
+cmchar "Extensible left bracket---bottom";
+beginchar(oct"020",8u#,cap_height#+4u#,2u#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(heavy_rule_thickness,0); pos2(heavy_rule_thickness,0);
+y1=h; bot y2=-d; x1=x2=hround(.5w);
+filldraw stroke z1e--z2e; % stem
+pos5(heavy_rule_thickness,90); pos6(heavy_rule_thickness,90);
+x5=x1l; rt x6=hround(w-.75u+.5heavy_rule_thickness); y5l=y6l=y2;
+filldraw stroke z5e--z6e; % lower bar
+penlabels(1,2,5,6); endchar;
+
+cmchar "Extensible right bracket---top";
+beginchar(oct"023",8u#,cap_height#+2u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(heavy_rule_thickness,0); pos2(heavy_rule_thickness,0);
+top y1=h; y2=-d; x1=x2=hround(.5w);
+filldraw stroke z1e--z2e; % stem
+pos3(heavy_rule_thickness,90); pos4(heavy_rule_thickness,90);
+x3=x1r; lft x4=hround(.75u-.5heavy_rule_thickness); y3r=y4r=y1;
+filldraw stroke z3e--z4e; % upper bar
+penlabels(1,2,3,4); endchar;
+
+cmchar "Extensible right bracket---bottom";
+beginchar(oct"021",8u#,cap_height#+4u#,2u#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(heavy_rule_thickness,0); pos2(heavy_rule_thickness,0);
+y1=h; bot y2=-d; x1=x2=hround(.5w);
+filldraw stroke z1e--z2e; % stem
+pos5(stem,90); pos6(stem,90);
+x5=x1r; lft x6=hround(.75u-.5heavy_rule_thickness); y5l=y6l=y2;
+filldraw stroke z5e--z6e; % lower bar
+penlabels(1,2,5,6); endchar;
+
+cmchar "Extensible left curly brace---middle";
+beginchar(oct"030",8u#,cap_height#+4u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
+pos4(min_breadth,0); pos4'(min_breadth,0);
+forsuffixes $=2,3,5,6: pos$(heavy_rule_thickness,0); endfor
+lft x4l=lft x4'l=hround(1.5u-.5min_breadth);
+x2=x3=x5=x6; x2=hround(.5w);
+y2=h; y6=-d; .5[y4,y4']=.5[y2,y6]=.5[y3,y5];
+y3-y4=(y2-y6)/4; y4-y4'=min_breadth-fine;
+filldraw z2l---z3l...{3(x4l-x3l),y4-y3}z4l
+ --z4'l{3(x5l-x4l),y5-y4'}...z5l---z6l--z6r---z5r
+ ...{3(x4r-x5r),.5[y4,y4']-y5}.5[z4r,z4'r]{3(x3r-x4r),y3-.5[y4,y4']}
+ ...z3r---z2r--cycle; % stroke
+penlabels(2,3,4,5,6); endchar;
+
+cmchar "Extensible right curly brace---middle";
+beginchar(oct"031",8u#,cap_height#+4u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
+pos4(min_breadth,0); pos4'(min_breadth,0);
+forsuffixes $=2,3,5,6: pos$(heavy_rule_thickness,0); endfor
+rt x4r=rt x4'r=hround(w-1.5u+.5min_breadth);
+x2=x3=x5=x6; x2=hround(.5w);
+y2=h; y6=-d; .5[y4,y4']=.5[y2,y6]=.5[y3,y5];
+y3-y4=(y2-y6)/4; y4-y4'=min_breadth-fine;
+filldraw z2r---z3r...{3(x4r-x3r),y4-y3}z4r
+ --z4'r{3(x5r-x4r),y5-y4'}...z5r---z6r--z6l---z5l
+ ...{3(x4l-x5l),.5[y4,y4']-y5}.5[z4l,z4'l]{3(x3l-x4l),y3-.5[y4,y4']}
+ ...z3l---z2l--cycle; % stroke
+penlabels(2,3,4,5,6); endchar;
+
+cmchar "Extension module";
+beginchar(oct"017",8u#,cap_height#+4u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric max_breadth; max_breadth=bold+2dw;
+pos2(heavy_rule_thickness,0); pos2'(heavy_rule_thickness,0);
+x2=x2'=hround(.5w); y2=h; y2'=-d;
+filldraw stroke z2e--z2'e; % link
+penlabels(2,2'); endchar;
+
+cmchar "Extensible left curly brace---top";
+beginchar(oct"024",8u#,cap_height#+2u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
+pos1(min_breadth,0); pos1'(min_breadth,0);
+pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0);
+rt x1r=rt x1'r=hround(w-1.5u+.5min_breadth);
+x2=x3=hround(.5w);
+top y1=h; y3=-d; y2=.5[y1,y3]; y1-y1'=min_breadth-fine;
+filldraw z1l{3(x2l-x1l),y2-y1}...z2l---z3l
+ --z3r---z2r...{3(x1r-x2r),y1'-y2}z1'r--z1r--cycle; % stroke
+penlabels(1,2,3); endchar;
+
+cmchar "Extensible left curly brace---bottom";
+beginchar(oct"025",8u#,cap_height#+4u#,2u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
+pos7(min_breadth,0); pos7'(min_breadth,0);
+pos5(heavy_rule_thickness,0); pos6(heavy_rule_thickness,0);
+rt x7r=rt x7'r=hround(w-1.5u+.5min_breadth);
+x5=x6=hround(.5w);
+y5=h; y7=-d; y6=.5[y5,y7]; y7'-y7=min_breadth-fine;
+filldraw z5l---z6l...{3(x7l-x6l),y7-y6}z7l
+ --z7r--z7'r{3(x6r-x7r),y6-y7'}...z6r---z5r--cycle; % stroke
+penlabels(5,6,7); endchar;
+
+cmchar "Extensible right curly brace---top";
+beginchar(oct"026",8u#,cap_height#+2u#,4u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
+pos1(min_breadth,0); pos1'(min_breadth,0);
+pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0);
+lft x1l=lft x1'l=hround(1.5u-.5min_breadth);
+x2=x3=hround(.5w);
+top y1=h; y3=-d; y2=.5[y1,y3]; y1-y1'=min_breadth-fine;
+filldraw z1r{3(x2r-x1r),y2-y1}...z2r---z3r
+ --z3l---z2l...{3(x1l-x2l),y1'-y2}z1'l--z1l--cycle; % stroke
+penlabels(1,2,3); endchar;
+
+cmchar "Extensible right curly brace---bottom";
+beginchar(oct"027",8u#,cap_height#+4u#,2u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric min_breadth; min_breadth=hround(rule_thickness+.6dw);
+pos7(min_breadth,0); pos7'(min_breadth,0);
+pos5(heavy_rule_thickness,0); pos6(heavy_rule_thickness,0);
+lft x7l=lft x7'l=hround(1.5u-.5min_breadth);
+x5=x6=hround(.5w);
+top y5=h; bot y7=-d; y6=.5[y5,y7]; y7'-y7=min_breadth-fine;
+filldraw z5r---z6r...{3(x7r-x6r),y7-y6}z7r
+ --z7l--z7'l{3(x6l-x7l),y6-y7'}...z6l---z5l--cycle; % stroke
+penlabels(5,6,7); endchar;
+
+bye.
diff --git a/dviware/quicspool/wwfonts/tpunct.mf b/dviware/quicspool/wwfonts/tpunct.mf
new file mode 100644
index 0000000000..80ec5125c4
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tpunct.mf
@@ -0,0 +1,241 @@
+% $Header: tpunct.mf,v 1.1 88/01/15 13:15:17 simpson Rel $
+% $Log: tpunct.mf,v $
+%Revision 1.1 88/01/15 13:15:17 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:40 simpson
+%beta test
+%
+% This file contains punctuation marks common to roman and italic styles.
+
+% Codes \0041, \0043, \0045, \0047--\0054,\ %
+%% \0056, \0057, \0072, \0073, \0075, \0100,\par
+% \0133, \0135, and \0140 are generated, as well as code |spanish_shriek|
+% (for a Spanish exclamation point) if that code value is known.
+
+cmchar "Exclamation point";
+beginchar("!",5u#+width_adj#,asc_height#,0);
+italcorr asc_height#*slant-2u#-.5width_adj#+.5dot_size#;
+adjust_fit(0,0);
+pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
+lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
+numeric bot_width;
+bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
+pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
+x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
+if square_dots: top y1=h;
+ filldraw stroke z1e--z2e; % stem
+else: top z0=(x1,h+o); y1+.5dot_size=h+o;
+ filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
+penlabels(0,1,2,3,4); endchar;
+
+iff known spanish_shriek: cmchar "Spanish open exclamation point";
+beginchar(spanish_shriek,5u#+width_adj#,asc_height#-desc_depth#,desc_depth#);
+italcorr h#*slant-2u#-.5width_adj#+.5dot_size#;
+adjust_fit(0,0);
+pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
+lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4); % dot
+numeric top_width;
+top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
+pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
+x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
+if square_dots: bot y1=-d;
+ filldraw stroke z1e--z2e; % stem
+else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
+ filldraw z1l...z0...z1r---z2r--z2l---cycle; fi % stem and bulb
+penlabels(0,1,2,3,4); endchar;
+
+cmchar "Per cent sign";
+beginchar("%",9u#+max(6u#,2fudge*(hair#+stem#)),
+ body_height#,body_height#-asc_height#);
+italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
+adjust_fit(0,0); pickup fine.nib;
+numeric left_curve,right_curve;
+left_curve=hround 5/6[fudged.hair,fudged.stem];
+right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
+pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
+top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
+bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
+x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
+filldraw stroke pulled_super_arc.e(1,2)(superpull)
+ & pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
+filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
+pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
+bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
+top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
+x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
+filldraw stroke pulled_super_arc.e(5,6)(superpull)
+ & pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
+filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
+pickup rule.nib; top y9=h; bot y10=-d;
+if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
+ draw z9--z10; % diagonal
+else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
+ pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
+ pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
+ path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
+ filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
+penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
+
+cmchar "Apostrophe";
+beginchar("'",5u#,asc_height#,0);
+italcorr asc_height#*slant+.5dot_size#-2u#;
+adjust_fit(0,0);
+x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h;
+if monospace: comma(1,a,dot_size,.28u,vround 1.5comma_depth); % large comma
+else: comma(1,a,dot_size,.25u,comma_depth); fi % comma with increased jut
+penlabels(1); endchar;
+
+cmchar "Left parenthesis";
+beginchar("(",7u# if monospace: -u# fi,body_height#,paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
+rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
+top y1=h; y2=.5[y1,y3]=math_axis;
+filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
+ ...{3(x3e-x2e),y3-y2}z3e; % arc
+penlabels(1,2,3); endchar;
+
+cmchar "Right parenthesis";
+beginchar(")",7u# if monospace: -u# fi,body_height#,paren_depth#);
+italcorr math_axis#*slant-.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
+lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
+top y1=h; y2=.5[y1,y3]=math_axis;
+filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
+ ...{3(x3e-x2e),y3-y2}z3e; % arc
+penlabels(1,2,3); endchar;
+
+cmchar "Asterisk";
+beginchar("*",9u#,
+ if low_asterisk:math_axis#+.5x_height# else: body_height# fi,0);
+italcorr h#*slant-.75u#;
+adjust_fit(0,0);
+numeric ast_flare; ast_flare=hround .7[thin_join,stem];
+x0=.5w; y0=h-.5x_height;
+for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
+ numeric theta; theta=angle(z[d]-z0);
+ fill z0+.5(0,-thin_join)rotated theta
+ ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
+ ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
+ ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
+labels(0,[-150],[-90],[-30],30,90,150); endchar;
+
+cmchar "Plus sign";
+beginarithchar("+"); pickup rule.nib;
+x1=x2=good.x .5w; top y1=h+eps; .5[y1,y2]=math_axis;
+lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
+draw z1--z2; % stem
+draw z3--z4; % crossbar
+labels(1,2,3,4); endchar;
+
+cmchar "Comma";
+numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
+define_whole_blacker_pixels(dot_diam);
+beginchar(",",5u#,dot_diam#,comma_depth#);
+adjust_fit(0,0);
+x1-.5dot_diam=hround(.5w-.5dot_diam); y1-.5dot_diam=0;
+comma(1,a,dot_diam,.2u,comma_depth); % dot and tail
+penlabels(1); endchar;
+
+cmchar "Period";
+numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
+define_whole_blacker_pixels(dot_diam);
+beginchar(".",5u#,dot_diam#,0);
+adjust_fit(0,0); pickup fine.nib;
+pos1(dot_diam,0); pos2(dot_diam,90);
+lft x1l=hround(.5w-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
+penlabels(1,2); endchar;
+
+cmchar "Virgule (slash)";
+beginchar("/",9u#,body_height#,paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+penlabels(1,2); endchar;
+
+cmchar "Colon";
+numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
+define_whole_blacker_pixels(dot_diam);
+beginchar(":",5u#,x_height#,0);
+italcorr x_height#*slant+.5dot_diam#-2u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(dot_diam,0); pos2(dot_diam,90);
+lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
+pos3(dot_diam,0); pos4(dot_diam,90);
+x3=x1; bot y4l=0; z3=z4; dot(3,4); % lower dot
+penlabels(1,2,3,4); endchar;
+
+cmchar "Semicolon";
+numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
+define_whole_blacker_pixels(dot_diam);
+beginchar(";",5u#,x_height#,comma_depth#);
+italcorr x_height#*slant+.5dot_diam#-2u#;
+adjust_fit(0,0); pickup fine.nib;
+pos1(dot_diam,0); pos2(dot_diam,90);
+lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2); % upper dot
+x3-.5dot_diam=hround(.5w-.5dot_diam); y3-.5dot_diam=0;
+comma(3,a,dot_diam,.05u,comma_depth); % lower dot and tail
+penlabels(1,2,3); endchar;
+
+cmchar "Equals sign";
+compute_spread(.45x_height#,.55x_height#);
+beginchar("=",14u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
+y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
+draw z1--z2; % upper bar
+draw z3--z4; % lower bar
+labels(1,2,3,4); endchar;
+
+cmchar "Left bracket";
+numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
+beginchar("[",wd#,body_height#,paren_depth#);
+italcorr body_height#*slant;
+adjust_fit(0,0);
+numeric top_thickness,side_thickness;
+if hefty: top_thickness=vair;
+ side_thickness=max(crisp.breadth,stem-2stem_corr);
+else: top_thickness=side_thickness=rule_thickness; fi;
+pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
+top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side_thickness)-1-eps;
+filldraw stroke z1e--z2e; % stem
+pos3(top_thickness,90); pos4(top_thickness,90);
+pos5(top_thickness,90); pos6(top_thickness,90);
+x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
+filldraw stroke z3e--z4e; % upper bar
+filldraw stroke z5e--z6e; % lower bar
+penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Right bracket";
+numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
+beginchar("]",wd#,body_height#,paren_depth#);
+italcorr body_height#*slant-2u#+.5if hefty:stem# else:rule_thickness# fi;
+adjust_fit(0,0);
+numeric top_thickness,side_thickness;
+if hefty: top_thickness=vair;
+ side_thickness=max(crisp.breadth,stem-2stem_corr);
+else: top_thickness=side_thickness=rule_thickness; fi;
+pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
+top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side_thickness)+1+eps;
+filldraw stroke z1e--z2e; % stem
+pos3(top_thickness,90); pos4(top_thickness,90);
+pos5(top_thickness,90); pos6(top_thickness,90);
+x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
+filldraw stroke z3e--z4e; % upper bar
+filldraw stroke z5e--z6e; % lower bar
+penlabels(1,2,3,4,5,6); endchar;
+
+cmchar "Reverse apostrophe";
+beginchar("`",5u#,asc_height#,0);
+italcorr asc_height#*slant+.5dot_size#-2u#;
+adjust_fit(0,0);
+x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h-comma_depth;
+if monospace: ammoc(1,a,dot_size,.28u,vround 1.5comma_depth); % large ammoc
+else: ammoc(1,a,dot_size,.25u,comma_depth); fi % normal ammoc
+penlabels(1); endchar;
diff --git a/dviware/quicspool/wwfonts/troman.mf b/dviware/quicspool/wwfonts/troman.mf
new file mode 100644
index 0000000000..bce9d447b7
--- /dev/null
+++ b/dviware/quicspool/wwfonts/troman.mf
@@ -0,0 +1,341 @@
+% $Header: troman.mf,v 1.1 88/01/15 13:15:20 simpson Rel $
+% $Log: troman.mf,v $
+% Revision 1.1 88/01/15 13:15:20 simpson
+% initial release
+%
+% Revision 0.1 88/01/07 08:15:18 simpson
+% beta test
+%
+% The Computer Modern Roman family of fonts (by D. E. Knuth, 1979--1985)
+
+if ligs>1: font_coding_scheme:="Troff text";
+else: font_coding_scheme:=if ligs=0: "TeX typewriter text"
+ else: "TeX text without f-ligatures" fi;
+ spanish_shriek=oct"016"; spanish_query=oct"017"; fi
+minus=oct"004"; vertical=oct"174";
+
+mode_setup; font_setup;
+
+% We need to create space characters with no bitmap for \| and \^. I put
+% them in oct"000" and oct"177" since these characters are not normally
+% used by ditroff.
+% My own creation (...creation being a generous term), for \|, 1/6 em
+beginchar(oct"000", 16/6u#, 0, 0);
+endchar;
+
+% My own creation, for \^, 1/12 em
+beginchar(oct"177", 16/12u#, 0, 0);
+endchar;
+
+% From the font lasy10.mf, file lasy.mf
+cmchar "Box";
+beginchar(oct"024",2.1math_axis#+4u#,v_center(7u#));
+italcorr math_axis#*slant;
+adjust_fit(0,0); pickup rule.nib;
+numeric a; a=round(2.1math_axis);
+x1=x4=good.x 2u; x2=x3=x1+a;
+y3=y4=.5(cap_height-a); y1=y2=y3+a;
+draw z1--z2--z3--z4--cycle;
+labels(1,2,3,4); endchar;
+
+% Stolen from font cmsy10, file symbol.mf
+cmchar "Open bullet";
+beginchar(oct"025",9u#,v_center(7u#));
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
+circle_points; draw_circle; % circle
+labels(1,2,3,4,5,6,7,8); endchar;
+
+% Stolen from the font cmr10, file accent.mf
+cmchar "Umlaut (double dot) accent";
+numeric dot_diam#,dot_diam;
+dot_diam#=max(dot_size#,cap_curve#);
+beginchar(oct"026",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
+dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
+italcorr h#*slant+.5dot_diam#-2.25u#;
+adjust_fit(0,0);
+pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
+x1=x2=2.75u; top y2r=h+1;
+if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
+y1=.5[y2l,y2r]; dot(1,2); % left dot
+pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
+dot(3,4); % right dot
+penlabels(1,2,3,4); endchar;
+
+% Stolen from the font cmr10.mf, file accent.mf
+cmchar "Cedilla accent";
+beginchar(oct"027",8u#,0,.875desc_depth#);
+adjust_fit(0,0);
+x1=.5w+.5u;
+if serifs: pickup crisp.nib; pos1(stem,0); pos2(stem,0);
+ pos3(vair,90); pos4(stem,0); pos5(vair,-90);
+ x1=x2; z3l=z2l; x4=x2+1.5u; x5=x3-1.5u;
+ bot y1=-o; bot y2=-vround 2/7d-o; y4=.5[y3,y5]; bot y5=-d-o;
+ filldraw stroke z1e--z2e; % stem
+ filldraw stroke z3e{right}...z4e{down}...{left}z5e; % hook
+else: pickup fine.nib; pos1(vair,0); top y1=-o-2;
+ pos2(.5[vair,stem],0); bot y2=-d-o; x2=x1-1.25u;
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2,3,4,5); endchar;
+
+% My own creation, a zero width period. Used for dots in pic(1).
+cmchar "Dot for pic boxes";
+numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
+define_whole_blacker_pixels(dot_diam);
+beginchar(oct"030",0,dot_diam#,0);
+period_width#:=5u#; define_pixels(period_width);
+pickup fine.nib;
+pos1(dot_diam,0); pos2(dot_diam,90);
+lft x1l=hround(.5period_width-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
+penlabels(1,2); endchar;
+
+% My own creation. The fractions look like hell.
+cmchar "1/4 symbol";
+beginchar(oct"021", 12u#, body_height#, paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+x3=x4=1/4w; y3=38/40h; y4=23/40h;
+draw z3--z4; % number 1
+x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
+draw z5--z6--z7--z8;
+endchar;
+
+% My own creation
+cmchar "1/2 symbol";
+beginchar(oct"022", 12u#, body_height#, paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+x3=x4=1/4w; y3=38/40h; y4=23/40h;
+draw z3--z4; % number 1
+x5=x9=.65w; x10=x7=.85w; x6=.74w;
+y9=y10=-.2d; y6=.37h; y5=.32h; y7=.30h;
+draw z5{dir 45}..z6..z7{dir -90}..{dir 225}z9; % number 2
+draw z9--z10;
+endchar;
+
+% My own creation.
+cmchar "3/4 symbol";
+beginchar(oct"023", 12u#, body_height#, paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+draw (quartercircle rotated -90 & halfcircle) scaled .1875h shifted
+(.25w,.8562h); % number 3
+draw (halfcircle rotated -180 & quartercircle) scaled .1875h shifted
+(.25w,.6687h);
+x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
+draw z5--z6--z7--z8;
+endchar;
+
+% From the font cmsy10, file sym.mf
+iff known vertical: cmchar "Vertical line";
+beginchar(vertical,5u#,body_height#,paren_depth#);
+italcorr body_height#*slant+.5rule_thickness#-2u#;
+adjust_fit(0,0); pickup rule.nib;
+x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
+draw z1--z2; % stem
+labels(1,2); endchar;
+
+% My own creation
+cmchar "Rule";
+beginchar(oct"005",12u#,x_height#,.7u#);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric below_baseline; below_baseline#:=.2u#;
+define_pixels(below_baseline);
+define_blacker_pixels(thickness);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(-below_baseline); rt x2=hround(w+6u#);
+lft x1=hround(0);
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% My own creation
+cmchar "Underscore";
+beginchar("_",12u#,x_height#,.7u#);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric below_baseline; below_baseline#:=.2u#;
+define_pixels(below_baseline);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(-below_baseline); x2=hround(w);
+x1=hround 0;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% Hyphen from cmr10, file comlig.mf
+cmchar "Hyphen";
+beginchar("-",6u#,x_height#,0);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
+pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
+top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
+if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% My own creation
+cmchar "Cent sign";
+beginchar(oct"020",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points;
+x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2];
+y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
+x13=x14=.5[x6,x2]-.3u; y13=y4+2u; y14=y8-2u;
+draw z10..z9..z11..z12; draw z13--z14;
+labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
+
+% My own creation
+cmchar "Copyright";
+beginchar(oct"016",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points; draw_circle; % circle
+x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2];
+y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
+draw z10..z9..z11..z12;
+labels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
+
+% My own creation
+cmchar "Registered";
+beginchar(oct"017",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points; draw_circle; % circle
+x9=x11=x12=.7[x6,x8]; x10=x13=.3[x4,x2];
+y12=y13=.5[y4,y6]; y9=.5[y6,y8]; y11=.5[y12,y9]; y10=.5[y11,y9];
+x14=.08[x4,x2]; y14=y9;
+path p;
+p=z9--z14{dir 0}..z10..{dir 180}z11;
+z15=point 2.6 of p;
+draw z12--z9; draw z13--z15; draw p;
+labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15); endchar;
+
+% Stolen from the font cmr10, file accent.mf (actually the acute accent)
+cmchar "Footmark";
+beginchar(oct"015",9u#,min(asc_height#,2x_height#),0);
+italcorr h#*slant-if serifs: 1.5 fi u#;
+adjust_fit(0,0);
+if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+% Stolen from the font cmsy10, file symbol.mf
+cmchar "Dagger mark";
+beginchar(oct"014",8u#,asc_height#,desc_depth#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
+pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
+x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
+x5-.5stem=hround u; x6=w-x5;
+y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
+y5+.5stem=floor(x_height+.5stem);
+filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e; % stem
+filldraw circ_stroke z5e{right}..{right}z2'e; % left bulb
+filldraw circ_stroke z6e{left}..{left}z2'e; % right bulb
+penlabels(1,2,3,4,5,6); endchar;
+
+% Stolen from the font cmr10, file accent.mf (the Scandinavian circle accent)
+cmchar "Degree";
+beginchar(oct"013",13u#+4/3(asc_height#-x_height#)*slant,asc_height#,0);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric circ_hair,circ_vair;
+circ_hair=hround min(hair,u+.5); circ_vair=vround min(vair,(h-x_height)/6+.5);
+penpos1(circ_vair,90); penpos3(circ_vair,-90);
+penpos2(circ_hair,180); penpos4(circ_hair,0);
+x2r=hround(.5w-1.5u-.5circ_hair);
+x4r=w-x2r; x1=x3=.5w; y1r=h+apex_o; y2=y4=.5[y1,y3];
+y3r=vround(1/3[x_height,h]+apex_o);
+penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
+penlabels(1,2,3,4); endchar;
+
+% My own creation
+cmchar "Square";
+beginchar(oct"010",9u#,v_center(7u#));
+italcorr math_axis#*slant;
+adjust_fit(0,0); pickup rule.nib;
+draw unitsquare scaled 7u shifted (.5w-7u/2,math_axis-7u/2);
+endchar;
+
+% Stolen from the font cmsy10, file symbol.mf
+cmchar "Bullet";
+beginchar(oct"007",9u#,v_center(7u#));
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
+filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
+ ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle; % circle and interior
+labels(1,2,3,4,5,6,7,8); endchar;
+
+% Stolen from the font cmsy10, file sym.mf
+iff known minus: cmchar "Minus sign";
+beginarithchar(minus); pickup rule.nib;
+lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
+draw z1--z2; % bar
+labels(1,2); endchar;
+
+input romanu; % upper case (majuscules)
+input romanl; % lower case (minuscules)
+input romand; % numerals
+input romanp; % ampersand, question marks, currency sign
+input tpunct; % punctuation symbols common to roman and italic text
+if ligs>1: input tromlig; fi % letter ligatures
+if ligs>0: input tcomlig; fi % ligatures common with italic text
+if ligs<=1: input romsub; fi % substitutes for ligatures
+
+font_slant slant; font_x_height x_height#;
+if monospace: font_normal_space 9u#; % no stretching or shrinking
+ font_quad 18u#;
+ font_extra_space 9u#;
+else: font_normal_space 6u#+2letter_fit#;
+ font_normal_stretch 3u#; font_normal_shrink 2u#;
+ font_quad 18u#+4letter_fit#;
+ font_extra_space 2u#;
+ k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
+ ligtable "k": if serifs: "v": "a" kern -u#, fi\\"w": "e" kern k#,
+ "a" kern k#, "o" kern k#, "c" kern k#;
+ ligtable "P": "A" kern kk#,
+ "y": "o" kern k#, "e" kern k#, "a" kern k#, "." kern kk#, "," kern kk#;
+ ligtable "F": "V": "W": if serifs: "o" kern kk#, "e" kern kk#, "u" kern kk#,
+ "r" kern kk#, "a" kern kk#, "A" kern kkk#,
+ else: "o" kern k#, "e" kern k#, "u" kern k#,
+ "r" kern k#, "a" kern k#, "A" kern kk#, fi
+ "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
+ ligtable "T": "y" kern if serifs: k# else: kk# fi,
+ "Y": "e" kern kk#, "o" kern kk#,
+ "r" kern kk#, "a" kern kk#, "A" kern kk#, "u" kern kk#;
+ ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
+ "V" kern k#, "Y" kern k#;
+ if serifs: ligtable "h": "m": "n":
+ "t" kern k#, "u" kern k#, "b" kern k#, "y" kern k#, "v" kern k#, "w" kern k#;
+ ligtable "c": "h" kern k#, "k" kern k#; fi
+ ligtable "o": "b": "p": "e" kern -k#, "o" kern -k#, "x" kern k#,
+ "d" kern -k#, "c" kern -k#, "q" kern -k#,
+ "a": if serifs: "v" kern k#, "j" kern u#, else: "r" kern k#, fi
+ "t": "y" kern k#,
+ "u": "w" kern k#;
+ ligtable "A": if serifs: "R": fi\\ "t" kern k#,
+ "C" kern k#, "O" kern k#, "G" kern k#, "U" kern k#, "Q" kern k#,
+ "L": "T" kern kk#, "Y" kern kk#, "V" kern kkk#, "W" kern kkk#;
+ ligtable "g": "j" kern -k#; % logjam
+ ligtable "I": "I" kern -k#; fi % Richard III
+ % there are ligature/kern programs for |"f"| in the {\tt romlig} file
+ % and for |"-"|, |"`"|, and |"'"| in the {\tt comlig} file
+bye.
diff --git a/dviware/quicspool/wwfonts/tromlig.mf b/dviware/quicspool/wwfonts/tromlig.mf
new file mode 100644
index 0000000000..6f96585cae
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tromlig.mf
@@ -0,0 +1,171 @@
+% $Header: tromlig.mf,v 1.1 88/01/15 13:15:24 simpson Rel $
+% $Log: tromlig.mf,v $
+%Revision 1.1 88/01/15 13:15:24 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:43 simpson
+%beta test
+%
+% This file describes five roman ligatures that begin with `f'
+% and puts them in code positions \001-\003, \011-\012
+
+numeric itc#; % modified italic correction on `f' and `ff'
+itc#=if serifs: max(0,flare#-.25u#) else: 1.25u# fi;
+
+ligtable "f": "i"=:oct"001", "f"=:oct"003", "l"=:oct"002",
+ "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
+ligtable oct"003": "i"=:oct"011", "l"=:oct"012",
+ "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
+
+cmchar "The ligature ff";
+beginchar(oct"003",10.5u#+2letter_fit#,asc_height#,0);
+italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
+adjust_fit(0,0);
+pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
+pos11(stem',0); rt x11r=hround(w-3u+.5stem');
+pickup fine.nib; numeric bulb_diam, inner_jut;
+if serifs: bulb_diam=hround .8[stem,flare];
+ pos2(bulb_diam,0); pos12(bulb_diam,0);
+ rt x2r=hround(rt x11r-stem_corr); lft x12l=hround(w-.75u+.5);
+ y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
+ if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
+ else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
+else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 6.25u;
+ pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(w+.75u); fi
+f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
+f_stroke(11,12,d,e,f,inner_jut,1.25jut); % right stem, arc, terminal, serif
+pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
+pos3(bar,90); pos4(bar,90);
+rt x4=hround(w-1/3u);
+if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
+ pos4'(bar,90); x4'=x11; y4'=y4;
+ filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
+else: filldraw stroke z3e--z4e; fi % bar
+penlabels(1,2,3,4,11,12); endchar;
+
+cmchar "The ligature fi";
+beginchar(oct"001",10u#+2letter_fit#,asc_height#,0);
+italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
+adjust_fit(0,serif_fit#);
+pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
+pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
+pos12(stem',0); x11=x12; bot y12=0;
+pickup fine.nib; numeric bulb_diam, inner_jut;
+if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
+ pos2(bulb_diam,0); x2r=x12r;
+ y2+.5bulb_diam=.8[x_height,h+oo]; top y11=x_height+min(oo,serif_drop);
+ if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
+ else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
+else: bulb_diam=max(stem,dot_size);
+ pos2(6/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u;
+ pickup tiny.nib; pos13(bulb_diam,0); pos14(bulb_diam,90);
+ x13=x11-.5; top y14r=min(2x_height,h+1); top y11=x_height;
+ if bot y14l-x_height<tiny: y14l:=min(y14r-eps,y11+2tiny); fi
+ x13=x14; y13=.5[y14l,y14r]; dot(13,14); % dot
+fi; % this is the ligature we're drawing
+f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
+pickup tiny.nib; filldraw stroke z11e--z12e; % right stem
+pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
+pos3(bar,90); pos4(bar,90);
+if serifs: x4=x11; % bar will overlap upper right serif
+ sloped_serif.l(11,12,d,1/3,jut,min(oo,serif_drop)); % upper right serif
+ dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut); % lower right serif
+else: rt x4= hround 5.3u; fi
+pickup crisp.nib; filldraw stroke z3e--z4e; % bar
+penlabels(1,2,3,4,11,12,13,14); endchar;
+
+cmchar "The ligature fl";
+beginchar(oct"002",10u#+2letter_fit#,asc_height#,0);
+italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
+adjust_fit(0,serif_fit#);
+pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
+pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
+pos12(stem',0); x11=x12; bot y12=0; top y11=h;
+filldraw stroke z11e--z12e; % right stem
+pickup fine.nib; numeric bulb_diam, inner_jut;
+if serifs: bulb_diam=hround .8[stem,flare];
+ pos2(bulb_diam,0); x2r=x11r-stem_corr;
+ y2+.5bulb_diam=.9[x_height,h+oo];
+ sloped_serif.l(11,12,d,1/3,eps,max(serif_drop,oo)); % erase excess at top
+ if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
+ else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
+else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u; fi
+f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
+pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
+pos3(bar,90); pos4(bar,90);
+if serifs: x4=x11;
+ dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut); % lower right serif
+else: rt x4= hround 5.3u; fi
+pickup crisp.nib; filldraw stroke z3e--z4e; % bar
+penlabels(1,2,3,4,11,12); endchar;
+
+cmchar "The ligature ffi";
+beginchar(oct"011",15u#+4letter_fit#,asc_height#,0);
+italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
+adjust_fit(0,serif_fit#);
+pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
+pos11(stem',0); lft x11l=hround(.5w-.5stem');
+pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
+pos22(stem',0); x21=x22; bot y22=0;
+pickup fine.nib; numeric bulb_diam, inner_jut;
+if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
+ pos2(bulb_diam,0); x2r=x11r-stem_corr;
+ pos12(bulb_diam,0); x12r=x21r;
+ top y21=x_height+min(oo,serif_drop);
+ y2+.5bulb_diam=.8[x_height,h+oo]; y12=y2;
+ if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
+ else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
+else: bulb_diam=max(stem,dot_size);
+ pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
+ pos12(6/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u);
+ pickup tiny.nib; pos23(bulb_diam,0); pos24(bulb_diam,90);
+ x23=x21-.5; top y24r=min(2x_height,h+1); top y21=x_height;
+ if bot y24l-x_height<tiny: y24l:=min(y24r-eps,y21+2tiny); fi
+ x23=x24; y23=.5[y24l,y24r]; dot(23,24); fi % dot
+f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
+f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
+pickup tiny.nib; filldraw stroke z21e--z22e; % right stem
+pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
+pos3(bar,90); pos4(bar,90);
+if serifs: x4=x21; % bar will overlap upper right serif
+ sloped_serif.l(21,22,g,1/3,jut,min(oo,serif_drop)); % upper right serif
+ dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut); % lower right serif
+else: rt x4=hround(.5w+2.8u); fi
+pickup crisp.nib;
+if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
+ pos4'(bar,90); x4'=x11; y4'=y4;
+ filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
+else: filldraw stroke z3e--z4e; fi % bar
+penlabels(1,2,3,4,11,12,21,22,23,24); endchar;
+
+cmchar "The ligature ffl";
+beginchar(oct"012",15u#+4letter_fit#,asc_height#,0);
+italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
+adjust_fit(0,serif_fit#);
+pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
+pos11(stem',0); lft x11l=hround(.5w-.5stem');
+pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
+pos22(stem',0); x21=x22; bot y22=0; top y21=h;
+filldraw stroke z21e--z22e; % right stem
+pickup fine.nib; numeric bulb_diam, inner_jut;
+if serifs: bulb_diam=hround .8[stem,flare];
+ pos2(bulb_diam,0); x2r=x11r-stem_corr;
+ pos12(bulb_diam,0); x12r=x21r-stem_corr;
+ y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
+ sloped_serif.l(21,22,g,1/3,eps,max(serif_drop,oo)); % erase excess at top
+ if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
+ else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
+else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
+ pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u); fi
+f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
+f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
+pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
+pos3(bar,90); pos4(bar,90);
+if serifs: dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut); % lower right serif
+ pickup crisp.nib; x4=x21;
+else: rt x4=hround(.5w+2.8u); fi
+if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
+ pos4'(bar,90); x4'=x11; y4'=y4;
+ filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
+else: filldraw stroke z3e--z4e; fi % bar
+penlabels(1,2,3,4,11,12,21,22); endchar;
diff --git a/dviware/quicspool/wwfonts/tromms.mf b/dviware/quicspool/wwfonts/tromms.mf
new file mode 100644
index 0000000000..75cc7c5b9d
--- /dev/null
+++ b/dviware/quicspool/wwfonts/tromms.mf
@@ -0,0 +1,42 @@
+% $Header: tromms.mf,v 1.1 88/01/15 13:15:27 simpson Rel $
+% $Log: tromms.mf,v $
+%Revision 1.1 88/01/15 13:15:27 simpson
+%initial release
+%
+%Revision 0.1 87/12/11 19:01:45 simpson
+%beta test
+%
+% This file contains special characters of ``math italic'' fonts
+% that actually are not supposed to be slanted.
+
+% The italic corrections are zero in all of these characters.
+
+cmchar "Less than sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar("<",14u#,v_center(spread#+rule_thickness#));
+italcorr h#*slant-u#;
+adjust_fit(0,0); pickup rule.nib;
+lft x2=hround 1.5u-eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]=math_axis;
+draw z1--z2--z3; % diagonals
+labels(1,2,3); endchar;
+
+cmchar "Virgule (slash)";
+beginchar(oct"016",9u#,body_height#,paren_depth#); % non-ASCII position
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+penlabels(1,2); endchar;
+
+cmchar "Greater than sign";
+compute_spread(5/4x_height#,3/2x_height#);
+beginchar(">",14u#,v_center(spread#+rule_thickness#));
+italcorr math_axis#*slant-u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x2=hround(w-1.5u)+eps; x1=x3=w-x2;
+y1-y3=spread; y2=.5[y1,y3]=math_axis;
+draw z1--z2--z3; % diagonals
+labels(1,2,3); endchar;
+
diff --git a/dviware/quicspool/wwfonts/ttextit.mf b/dviware/quicspool/wwfonts/ttextit.mf
new file mode 100644
index 0000000000..ffbad2f774
--- /dev/null
+++ b/dviware/quicspool/wwfonts/ttextit.mf
@@ -0,0 +1,336 @@
+% $Header: ttextit.mf,v 1.1 88/01/15 13:15:30 simpson Rel $
+% $Log: ttextit.mf,v $
+% Revision 1.1 88/01/15 13:15:30 simpson
+% initial release
+%
+% Revision 0.2 88/01/14 10:12:30 simpson
+% fixed Rule and Underscore
+%
+% Revision 0.1 88/01/07 08:15:20 simpson
+% beta test
+%
+% The Computer Modern Text Italic family (by D. E. Knuth, 1979--1985)
+
+mode_setup; font_setup;
+
+input itall; % lower case (minuscules)
+if ligs>1: font_coding_scheme:="Troff text";
+ input titalig; % letter ligatures
+else: font_coding_scheme:=if ligs=0: "TeX typewriter text"
+ else: "TeX text without f-ligatures" fi;
+ spanish_shriek=oct"016"; spanish_query=oct"017"; fi
+minus=oct"004"; vertical=oct"174";
+
+font_slant slant; font_x_height x_height#;
+if monospace: font_normal_space 9u#; % no stretching or shrinking
+ font_quad 18u#;
+ font_extra_space 9u#;
+ letter_fit#:=letter_fit:=0;
+else: font_normal_space 6u#+2letter_fit#;
+ font_normal_stretch 3u#; font_normal_shrink 2u#;
+ font_quad 18u#+4letter_fit#;
+ font_extra_space 2u#; fi
+
+% We need to create space characters with no bitmap for \| and \^. I put
+% them in oct"000" and oct"177" since these characters are not normally
+% used by ditroff.
+% My own creation (...creation being a generous term), for \|, 1/6 em
+beginchar(oct"000", 16/6u#, 0, 0);
+endchar;
+
+% My own creation, for \^, 1/12 em
+beginchar(oct"177", 16/12u#, 0, 0);
+endchar;
+
+% From the font lasy10.mf, file lasy.mf
+cmchar "Box";
+beginchar(oct"024",2.1math_axis#+4u#,v_center(7u#));
+italcorr math_axis#*slant;
+adjust_fit(0,0); pickup rule.nib;
+numeric a; a=round(2.1math_axis);
+x1=x4=good.x 2u; x2=x3=x1+a;
+y3=y4=.5(cap_height-a); y1=y2=y3+a;
+draw z1--z2--z3--z4--cycle;
+labels(1,2,3,4); endchar;
+
+% Stolen from font cmsy10, file symbol.mf
+cmchar "Open bullet";
+beginchar(oct"025",9u#,v_center(7u#));
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
+circle_points; draw_circle; % circle
+labels(1,2,3,4,5,6,7,8); endchar;
+
+% Stolen from the font cmr10, file accent.mf
+cmchar "Umlaut (double dot) accent";
+numeric dot_diam#,dot_diam;
+dot_diam#=max(dot_size#,cap_curve#);
+beginchar(oct"026",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
+dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
+italcorr h#*slant+.5dot_diam#-2.25u#;
+adjust_fit(0,0);
+pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
+x1=x2=2.75u; top y2r=h+1;
+if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
+y1=.5[y2l,y2r]; dot(1,2); % left dot
+pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
+dot(3,4); % right dot
+penlabels(1,2,3,4); endchar;
+
+% Stolen from the font cmr10.mf, file accent.mf
+cmchar "Cedilla accent";
+beginchar(oct"027",8u#,0,.875desc_depth#);
+adjust_fit(0,0);
+x1=.5w+.5u;
+if serifs: pickup crisp.nib; pos1(stem,0); pos2(stem,0);
+ pos3(vair,90); pos4(stem,0); pos5(vair,-90);
+ x1=x2; z3l=z2l; x4=x2+1.5u; x5=x3-1.5u;
+ bot y1=-o; bot y2=-vround 2/7d-o; y4=.5[y3,y5]; bot y5=-d-o;
+ filldraw stroke z1e--z2e; % stem
+ filldraw stroke z3e{right}...z4e{down}...{left}z5e; % hook
+else: pickup fine.nib; pos1(vair,0); top y1=-o-2;
+ pos2(.5[vair,stem],0); bot y2=-d-o; x2=x1-1.25u;
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2,3,4,5); endchar;
+
+% My own creation, a zero width period. Used for dots in pic(1).
+cmchar "Dot for pic boxes";
+numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
+define_whole_blacker_pixels(dot_diam);
+beginchar(oct"030",0,dot_diam#,0);
+period_width#:=5u#; define_pixels(period_width);
+pickup fine.nib;
+pos1(dot_diam,0); pos2(dot_diam,90);
+lft x1l=hround(.5period_width-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
+penlabels(1,2); endchar;
+
+% My own creation. The fractions look like hell.
+cmchar "1/4 symbol";
+beginchar(oct"021", 12u#, body_height#, paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+x3=x4=1/4w; y3=38/40h; y4=23/40h;
+draw z3--z4; % number 1
+x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
+draw z5--z6--z7--z8;
+endchar;
+
+% My own creation
+cmchar "1/2 symbol";
+beginchar(oct"022", 12u#, body_height#, paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+x3=x4=1/4w; y3=38/40h; y4=23/40h;
+draw z3--z4; % number 1
+x5=x9=.65w; x10=x7=.85w; x6=.74w;
+y9=y10=-.2d; y6=.37h; y5=.32h; y7=.30h;
+draw z5{dir 45}..z6..z7{dir -90}..{dir 225}z9; % number 2
+draw z9--z10;
+endchar;
+
+% My own creation.
+cmchar "3/4 symbol";
+beginchar(oct"023", 12u#, body_height#, paren_depth#);
+italcorr body_height#*slant-.5u#;
+adjust_fit(0,0); pickup rule.nib;
+rt x1=hround(w-u)+eps; top y1=h+eps;
+lft x2=hround u-eps; bot y2=-d-eps;
+draw z1--z2; % diagonal
+draw (quartercircle rotated -90 & halfcircle) scaled .1875h shifted
+(.25w,.8562h); % number 3
+draw (halfcircle rotated -180 & quartercircle) scaled .1875h shifted
+(.25w,.6687h);
+x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
+draw z5--z6--z7--z8;
+endchar;
+
+% From the font cmsy10, file sym.mf
+iff known vertical: cmchar "Vertical line";
+beginchar(vertical,5u#,body_height#,paren_depth#);
+italcorr body_height#*slant+.5rule_thickness#-2u#;
+adjust_fit(0,0); pickup rule.nib;
+x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
+draw z1--z2; % stem
+labels(1,2); endchar;
+
+% My own creation
+cmchar "Rule";
+beginchar(oct"005",12u#,x_height#,.7u#);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric below_baseline; below_baseline#:=.2u#;
+define_pixels(below_baseline);
+define_blacker_pixels(thickness);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(-below_baseline); rt x2=hround(w+6u#);
+lft x1=hround(0);
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% My own creation
+cmchar "Underscore";
+beginchar("_",12u#,x_height#,.7u#);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric below_baseline; below_baseline#:=.2u#;
+define_pixels(below_baseline);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(-below_baseline); x2=hround(w);
+x1=hround 0;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% Hyphen from cmr10, file comlig.mf
+cmchar "Hyphen";
+beginchar("-",6u#,x_height#,0);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
+pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
+top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
+if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+% My own creation
+cmchar "Cent sign";
+beginchar(oct"020",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points;
+x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2];
+y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
+x13=x14=.5[x6,x2]-.3u; y13=y4+2u; y14=y8-2u;
+draw z10..z9..z11..z12; draw z13--z14;
+labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
+
+% My own creation
+cmchar "Copyright";
+beginchar(oct"016",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points; draw_circle; % circle
+x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2];
+y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
+draw z10..z9..z11..z12;
+labels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
+
+% My own creation
+cmchar "Registered";
+beginchar(oct"017",18u#,asc_height#,desc_depth#); autorounded;
+adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
+lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
+circle_points; draw_circle; % circle
+x9=x11=x12=.7[x6,x8]; x10=x13=.3[x4,x2];
+y12=y13=.5[y4,y6]; y9=.5[y6,y8]; y11=.5[y12,y9]; y10=.5[y11,y9];
+x14=.08[x4,x2]; y14=y9;
+path p;
+p=z9--z14{dir 0}..z10..{dir 180}z11;
+z15=point 2.6 of p;
+draw z12--z9; draw z13--z15; draw p;
+labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15); endchar;
+
+% Stolen from the font cmr10, file accent.mf (actually the acute accent)
+cmchar "Footmark";
+beginchar(oct"015",9u#,min(asc_height#,2x_height#),0);
+italcorr h#*slant-if serifs: 1.5 fi u#;
+adjust_fit(0,0);
+if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+% Stolen from the font cmsy10, file symbol.mf
+cmchar "Dagger mark";
+beginchar(oct"014",8u#,asc_height#,desc_depth#);
+adjust_fit(0,0); pickup fine.nib;
+pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
+pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
+x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
+x5-.5stem=hround u; x6=w-x5;
+y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
+y5+.5stem=floor(x_height+.5stem);
+filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e; % stem
+filldraw circ_stroke z5e{right}..{right}z2'e; % left bulb
+filldraw circ_stroke z6e{left}..{left}z2'e; % right bulb
+penlabels(1,2,3,4,5,6); endchar;
+
+% Stolen from the font cmr10, file accent.mf (the Scandinavian circle accent)
+cmchar "Degree";
+beginchar(oct"013",13u#+4/3(asc_height#-x_height#)*slant,asc_height#,0);
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+numeric circ_hair,circ_vair;
+circ_hair=hround min(hair,u+.5); circ_vair=vround min(vair,(h-x_height)/6+.5);
+penpos1(circ_vair,90); penpos3(circ_vair,-90);
+penpos2(circ_hair,180); penpos4(circ_hair,0);
+x2r=hround(.5w-1.5u-.5circ_hair);
+x4r=w-x2r; x1=x3=.5w; y1r=h+apex_o; y2=y4=.5[y1,y3];
+y3r=vround(1/3[x_height,h]+apex_o);
+penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
+penlabels(1,2,3,4); endchar;
+
+% My own creation
+cmchar "Square";
+beginchar(oct"010",9u#,v_center(7u#));
+italcorr math_axis#*slant;
+adjust_fit(0,0); pickup rule.nib;
+draw unitsquare scaled 7u shifted (.5w-7u/2,math_axis-7u/2);
+endchar;
+
+% Stolen from the font cmsy10, file symbol.mf
+cmchar "Bullet";
+beginchar(oct"007",9u#,v_center(7u#));
+adjust_fit(0,0); pickup rule.nib; autorounded;
+lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
+filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
+ ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle; % circle and interior
+labels(1,2,3,4,5,6,7,8); endchar;
+
+% Stolen from the font cmsy10, file sym.mf
+iff known minus: cmchar "Minus sign";
+beginarithchar(minus); pickup rule.nib;
+lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
+draw z1--z2; % bar
+labels(1,2); endchar;
+
+input romanu; % upper case (majuscules)
+input itald; % numerals
+input titalp; % ampersand, question marks, currency sign
+input tpunct; % punctuation symbols common to roman and italic text
+if ligs>0: input tcomlig; fi % ligatures common with roman text
+if ligs<=1: input romsub; fi % substitutes for ligatures
+
+if not monospace:
+ k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
+ ligtable "d": "w": "l": "l" kern +u#;
+ ligtable "F": "V": "o" kern kk#, "e" kern kk#,
+ "u" kern kk#, "r" kern kk#, "a" kern kk#, "A" kern kkk#,
+ "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
+ ligtable "T": "y" kern kk#,
+ "Y": "e" kern kk#, "o" kern kk#, "r" kern kk#, "a" kern kk#, "u" kern kk#,
+ "P": "W": "A" kern kk#;
+ ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
+ "V" kern k#, "Y" kern k#;
+ ligtable "A": "R": "n" kern k#, "l" kern k#, "r" kern k#, "u" kern k#,
+ "m" kern k#, "t" kern k#, "i" kern k#, "C" kern k#, "O" kern k#, "G" kern k#,
+ "h" kern k#, "b" kern k#, "U" kern k#, "k" kern k#, "v" kern k#, "w" kern k#,
+ "Q" kern k#, "L": "T" kern kk#, "Y" kern kk#, "V" kern kkk#, "W" kern kkk#,
+ "b": "c": "e": "o": "p": "r": "e" kern -u#, "a" kern -u#, "o" kern -u#,
+ "d" kern -u#, "c" kern -u#, "g" kern -u#, "q" kern -u#;
+ fi
+% there are ligature/kern programs for |"f"| in the {\tt romlig} file
+% and for |"-"|, |"`"|, and |"'"| in the {\tt comlig} file
+bye.