summaryrefslogtreecommitdiff
path: root/fonts/icelandic/MF/icomlig.mf
diff options
context:
space:
mode:
authorNorbert Preining <norbert@preining.info>2019-09-02 13:46:59 +0900
committerNorbert Preining <norbert@preining.info>2019-09-02 13:46:59 +0900
commite0c6872cf40896c7be36b11dcc744620f10adf1d (patch)
tree60335e10d2f4354b0674ec22d7b53f0f8abee672 /fonts/icelandic/MF/icomlig.mf
Initial commit
Diffstat (limited to 'fonts/icelandic/MF/icomlig.mf')
-rw-r--r--fonts/icelandic/MF/icomlig.mf67
1 files changed, 67 insertions, 0 deletions
diff --git a/fonts/icelandic/MF/icomlig.mf b/fonts/icelandic/MF/icomlig.mf
new file mode 100644
index 0000000000..37bcb185da
--- /dev/null
+++ b/fonts/icelandic/MF/icomlig.mf
@@ -0,0 +1,67 @@
+% This is COMLIG.MF in text format, as of May 5, 1986.
+% This file defines characters common to roman and italic text fonts
+% that appear only when |ligs>0|.
+
+% Character codes \0042, \0055, \0134, \0173, and \0174 are generated.
+% **********************************************************************
+% Öslenskun 7. jan 1988 (ICOMLIG.MF)
+% Tilvitnunarmerkjum (g‘sal”ppum) er breytt til samr‘mis viÐ ¡slenska
+% venju
+% **********************************************************************
+ligtable "-": "-"=:oct"173";
+ligtable oct"173": "-"=:oct"174";
+
+cmchar "Opening Icelandic quotes";
+beginchar(oct"042",7u#+max(2u#,dot_size#),asc_height#,0);
+italcorr asc_height#*slant+dot_size#-4.1u#;
+adjust_fit(0,0);
+%Breyta b‘Œi x og y-gildum
+x2+.5dot_size=hround(w-.6u);
+x2-x1=hround(1.5u+max(2u,dot_size));
+y2-.5dot_size=0;
+y2=y1;
+comma(1,a,dot_size,.25u,comma_depth); % left dot and tail
+comma(2,b,dot_size,.25u,comma_depth); % right dot and tail
+penlabels(1,2); endchar;
+
+cmchar "Hyphen";
+beginchar("-",6u#,x_height#,0);
+italcorr .5x_height#*slant-.5u#;
+adjust_fit(0,0);
+numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
+pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
+top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
+if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+cmchar "Closing Icelandic quotes";
+beginchar(oct"134",7u#+max(2u#,dot_size#),asc_height#,0);
+italcorr asc_height#*slant-.1u#;
+adjust_fit(0,0);
+%aŒeins breytt x-gildum
+x1-.5dot_size=hround .6u;
+x2-x1=hround(1.5u+max(2u,dot_size));
+y1+.5dot_size=h-comma_depth;
+y2=y1;
+ammoc(1,a,dot_size,.25u,comma_depth); % left dot and tail
+ammoc(2,b,dot_size,.25u,comma_depth); % right dot and tail
+penlabels(1,2); endchar;
+
+cmchar "En dash";
+beginchar(oct"173",9u#,x_height#,0);
+italcorr .61803x_height#*slant+.5u#;
+adjust_fit(0,0);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;
+
+cmchar "Em dash";
+beginchar(oct"174",18u#,x_height#,0);
+italcorr .61803x_height#*slant+.5u#;
+adjust_fit(letter_fit#,letter_fit#);
+pickup crisp.nib; pos1(vair,90); pos2(vair,90);
+top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
+filldraw stroke z1e--z2e; % bar
+penlabels(1,2); endchar;