blob: 5f6bcc8ae16cfc8af3869a681613002b1b3c6af7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
package if;
$VERSION = '0.05';
sub work {
my $method = shift() ? 'import' : 'unimport';
die "Too few arguments to `use if' (some code returning an empty list in list context?)"
unless @_ >= 2;
return unless shift; # CONDITION
my $p = $_[0]; # PACKAGE
(my $file = "$p.pm") =~ s!::!/!g;
require $file; # Works even if $_[0] is a keyword (like open)
my $m = $p->can($method);
goto &$m if $m;
}
sub import { shift; unshift @_, 1; goto &work }
sub unimport { shift; unshift @_, 0; goto &work }
1;
__END__
=head1 NAME
if - C<use> a Perl module if a condition holds
=head1 SYNOPSIS
use if CONDITION, MODULE => ARGUMENTS;
=head1 DESCRIPTION
The construct
use if CONDITION, MODULE => ARGUMENTS;
has no effect unless C<CONDITION> is true. In this case the effect is
the same as of
use MODULE ARGUMENTS;
Above C<< => >> provides necessary quoting of C<MODULE>. If not used (e.g.,
no ARGUMENTS to give), you'd better quote C<MODULE> yourselves.
=head1 BUGS
The current implementation does not allow specification of the
required version of the module.
=head1 AUTHOR
Ilya Zakharevich L<mailto:perl-module-if@ilyaz.org>.
=cut
|
