blob: 77ad19b7763be4e12d03fc57ce1e6bc6fe785201 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
package CPAN::Plugin;
use strict;
use warnings;
our $VERSION = '0.96';
require CPAN;
######################################################################
sub new { # ;
my ($class, %params) = @_;
my $self = +{
(ref $class ? (%$class) : ()),
%params,
};
$self = bless $self, ref $class ? ref $class : $class;
unless (ref $class) {
local $_;
no warnings 'once';
$CPAN::META->use_inst ($_) for $self->plugin_requires;
}
$self;
}
######################################################################
sub plugin_requires { # ;
}
######################################################################
sub distribution_object { # ;
my ($self) = @_;
$self->{distribution_object};
}
######################################################################
sub distribution { # ;
my ($self) = @_;
my $distribution = $self->distribution_object->id;
CPAN::Shell->expand("Distribution",$distribution)
or $self->frontend->mydie("Unknowns distribution '$distribution'\n");
}
######################################################################
sub distribution_info { # ;
my ($self) = @_;
CPAN::DistnameInfo->new ($self->distribution->id);
}
######################################################################
sub build_dir { # ;
my ($self) = @_;
my $build_dir = $self->distribution->{build_dir}
or $self->frontend->mydie("Distribution has not been built yet, cannot proceed");
}
######################################################################
sub is_xs { #
my ($self) = @_;
my @xs = glob File::Spec->catfile ($self->build_dir, '*.xs'); # quick try
unless (@xs) {
require ExtUtils::Manifest;
my $manifest_file = File::Spec->catfile ($self->build_dir, "MANIFEST");
my $manifest = ExtUtils::Manifest::maniread($manifest_file);
@xs = grep /\.xs$/, keys %$manifest;
}
scalar @xs;
}
######################################################################
package CPAN::Plugin;
1;
__END__
=pod
=head1 NAME
CPAN::Plugin - Base class for CPAN shell extensions
=head1 SYNOPSIS
package CPAN::Plugin::Flurb;
use parent 'CPAN::Plugin';
sub post_test {
my ($self, $distribution_object) = @_;
$self = $self->new (distribution_object => $distribution_object);
...;
}
=head1 DESCRIPTION
=head2 Alpha Status
The plugin system in the CPAN shell was introduced in version 2.07 and
is still considered experimental.
=head2 How Plugins work?
See L<CPAN/"Plugin support">.
=head1 METHODS
=head2 plugin_requires
returns list of packages given plugin requires for functionality.
This list is evaluated using C<CPAN->use_inst> method.
=head2 distribution_object
Get current distribution object.
=head2 distribution
=head2 distribution_info
=head2 build_dir
Simple delegatees for misc parameters derived from distribution
=head2 is_xs
Predicate to detect whether package contains XS.
=head1 AUTHOR
Branislav Zahradnik <barney@cpan.org>
=cut
|
