path: root/Master/tlpkg/installer/install-menu-wizard.pl

#!/usr/bin/env perl
# $Id$
#
# Copyright 2009 Norbert Preining
# This file is licensed under the GNU General Public License version 2
# or any later version.
#
# HOW TO ADD A SCREEN:
# 1) create a sub called something like
#     ask_yourscreen
# 2) in the beginning of the sub call
#     $current_screen = "yourscreen";
# 3) set the screen_subs hash
#     $screen_subs{"yourscreen"} = \&ask_yourscreen;
# 4) call at the end of the screen
#     unpack_buttons();
#     pack_buttons("cancel", "prev", "next");  # if you are in the middle
#   if you want to change something on the $prv, $nxt, $can buttons 
#   please do it *between* the two calls, then call 
#     pack_buttons("-no-config", "cancel", "prev", "next");
#   Normally the text of $nxt button is set according to the existence of
#   a following screen to either Next or Install, and in the latter case
#   the -command is changed to \&wizard_installation_window
#   Calling with "-no-config" as first argument does inhibit that.
#
# The list of screens can be set using the run_menu(@screens), and
# install_tl does transfer a call to
#     install-tl -gui "wizard:welcome,path,scheme,integration,install"
# to 
#     run_menu("welcome", "path", "scheme", "integration", "install");
# which in turn will only show these screens.

use strict;
$^W = 1;

my $svnrev = '$Revision: 11925 $';
$svnrev =~ m/: ([0-9]+) /;
$::menurevision = $1;


our %vars;
our $tlpdb;
our $texlive_release;
our @collections_std;
our @collections_lang;
our @collections_lang_doc;

our $MENU_INSTALL = 0;
our $MENU_ABORT   = 1;
our $MENU_QUIT    = 2;
our $MENU_ALREADYDONE = 3;


my $return = $MENU_INSTALL;

my $custom = 0;

require Tk;
require Tk::Dialog;
require Tk::DialogBox;
require Tk::PNG;
require Tk::ROText;
require Tk::ProgressBar;

use utf8;
no utf8;

#
# LAYOUT of the wizard
#
# /---------------------------------------------------\
# |                                                   |
# |  /------------ Frame $ftitle -----------------\   |
# |  |          Lab $tit                          |   |
# |  \--------------------------------------------/   |
# |                                                   |
# |  /------------ Frame $fmain ------------------\   |
# |  |                                            |   |
# |  \--------------------------------------------/   |
# |                                                   |
# |  /------------ Frame $fbuttons ---------------\   |
# |  | But $can  <$spi> But $prv <$spii> But $nxt |   |
# |  \--------------------------------------------/   |
# |                                                   |
# \---------------------------------------------------/
#
my $ftitle;
my $tit;

my $fmain;

my $fbuttons;
my $can;
my $spi;
my $prv;
my $spii;
my $nxt;

my $img;

if (defined($::opt_lang)) {
  $::lang = $::opt_lang;
  if ($::lang eq "zh") {
    # set language to simplified chinese
    $::lang = "zh-cn";
  }
} else {
  if ($^O =~ /^MSWin(32|64)$/i) {
    # trying to deduce automatically the country code
    my $foo =  TeXLive::TLWinGoo::reg_country();
    if ($foo) {
      $::lang = $foo;
    } else {
      debug("Didn't get any usuful code from reg_country: $foo...\n");
    }
  } else {
    # we load POSIX and locale stuff
    require POSIX;
    import POSIX qw/locale_h/;
    # now we try to deduce $::lang
    my $loc = setlocale(&POSIX::LC_MESSAGES);
    my ($lang,$area,$codeset);
    if ($loc =~ m/^([^_.]*)(_([^.]*))?(\.([^@]*))?(@.*)?$/) {
      $lang = defined($1)?$1:"";
      $area = defined($3)?$3:"";
      if ($lang eq "zh") {
        if ($area =~ m/^(TW|HK)$/i) {
          $lang = "zh-tw";
        } else {
          # fallback to zh-cn for anything else, that is
          # zh-cn, zh-sg, zh, and maybe something else
          $lang = "zh-cn";
        }
      }
    }
    $::lang = $lang if ($lang);
  }
}

my $dest = $vars{'TEXDIR'};

my $mw;

my $current_screen;

my @screens = qw/welcome path install/;

my %screen_subs;
$screen_subs{"welcome"} = \&reset_start;
$screen_subs{"path"}    = \&ask_path;
$screen_subs{"systems"} = \&ask_systems;
$screen_subs{"scheme"}  = \&ask_scheme;
$screen_subs{"stdcoll"} = \&ask_stdcoll;
$screen_subs{"langcoll"} = \&ask_langcoll;
$screen_subs{"install"} = \&ask_go;

sub next_screen {
  # returns the name of the next screen
  for my $i (0..$#screens) {
    if ($screens[$i] eq $current_screen) {
      return ( $i == $#screens ? undef : $screens[$i+1]);
    }
  }
}
sub prev_screen {
  # returns the name of the prev screen
  for my $i (0..$#screens) {
    if ($screens[$i] eq $current_screen) {
      return ($i ? $screens[$i-1] : undef);
    }
  }
}
sub run_screen {
  my $what = shift;
  debug("current screen = $current_screen\nwhat = $what\n");
  if (defined($screen_subs{$what})) {
    &{$screen_subs{$what}}();
  } else {
    tlwarn("Undefined screen: $what\n");
  }
}

######################################################################

push @::info_hook,
  sub {
    return unless defined($mw);
    wizard_update_status(join(" ",@_));
    $mw->update;
  };
push @::warn_hook,
  sub {
    return unless defined($mw);
    wizard_update_status(join(" ",@_));
    $mw->update;
  };
push @::install_packages_hook, \&wizard_update_progressbar;
push @::install_packages_hook,
  sub { $mw->update; $::sww->update; };

sub wizard_update_status {
  my ($p) = @_;
  $::progressw->insert("end", "$p");
  $::progressw->see("end");
}
sub wizard_update_progressbar {
  my ($n,$total) = @_;
  if (defined($n) && defined($total)) {
    $::progress->value(int($n*100/$total));
  }
}

my %text = ( title      => 'TeX Live 2008 Installation',
             basicinfo  => 'Basic Information',
             custom     => 'Further Customization',
             dirsetup   => "Directory setup",
             options    => 'Options',
             sysint     => 'System Integration',
             change     => 'Change',
             toggle     => 'Toggle',
             install    => 'Install TeX Live',
             finbut     => 'Finish',
             quit       => 'Quit',
             ok         => 'Ok',
             cancel     => 'Cancel',
             status     => 'Status output',
             changevar  => 'Change variable value',
             enterpath  => 'Enter path for',
             hinthome   => '(use ~ for %%%)',
             selectscheme => 'Select a scheme',
             selectstdcol => 'Select the collections to be installed',
             selectall  => 'Select All',
             selectnone => 'Deselect All',
             selectlang => 'Select language support',
             selectdoc  => 'Select language-specific documentation',
             createsym  => 'create symlinks in standard directories',
             binto      => 'binaries to',
             manto      => 'manpages to',
             infoto     => 'info to',
             selectsys  => 'Select arch-os',
             outof      => 'out of',
             collof     => 'collections out of',
             diskreq    => 'disk space required',
             yes        => 'Yes',
             no         => 'No',
             notwritable => '(default not writable - please change!)',
             changetexdir => '(please change TEXDIR first!)',
             nolangcol  => '(no language collection selected!)',
             finished   => 'See TEXDIR/index.html for links to documentation.\nThe TeX Live web site (http://tug.org/texlive/) contains any updates and corrections. TeX Live is a joint project of the TeX user groups around the world; please consider supporting it by joining the group best for you. The list of groups is available on the web at http://tug.org/usergroups.html.',
             finishedpath => 'Add TEXDIR/texmf/doc/man to MANPATH.\nAdd TEXDIR/texmf/doc/info to INFOPATH.\nMost importantly, add TEXDIR/bin/PLATFORM\nto your PATH for current and future sessions.',
             welcome => 'Welcome to TeX Live!',
    );


my %labels = ( binsys   => 'Binary System(s)',
               scheme   => 'Selected Scheme',
               stdcoll  => 'Standard Collections',
               langcoll => 'Language Collections',
               texdir   => 'TEXDIR (the main TeX directory)',
               localdir => 'TEXMFLOCAL (directory for site-wide local files)',
               sysvardir   => 'TEXMFSYSVAR (directory for autogenerated data)',
               sysconfigdir   => 'TEXMFSYSCONFIG (directory for local config)',
               texmfhome => 'TEXMFHOME (directory for user-specific files)',
               optletter => 'Use letter size instead of A4 by default',
               optfmt   => 'Create all format files',
               optdoc   =>  'Install font/macro doc tree',
               optsrc   =>  'Install font/macro source tree',
               symlink  =>  'Create symlinks in system directories',
    );

if (($::lang ne "en") && ($::lang ne "C")) {
  if (! -r "$::installerdir/tlpkg/installer/lang/perltk-$::lang") {
    tlwarn ("\n  Sorry, no translations available for $::lang; falling back to English.
  (If you'd like to help translate the installer's messages, please see
  http://tug.org/texlive/doc.html#install-tl-xlate for information.)\n\n");
  } else {
    # merge the translated strings into the text string
    open(LANG, "<$::installerdir/tlpkg/installer/lang/perltk-$::lang");
    my %trans;
    while (<LANG>) {
      chomp;
      next if m/^\s*#/;
      next if m/^\s*$/;
      my ($a,$b) = split(/:/,$_,2);
      $b =~ s/^\s*([^\s])/$1/;
      $b =~ s/\s*$//;
      if (!utf8::decode($b)) {
        warn("decoding string to utf8 didn't work:$b\n");
      }
      $trans{"$a"} = "$b";
    }
    close(LANG);
    foreach my $k (keys %text) {
      $text{$k} = $trans{"text.$k"} if defined($trans{"text.$k"});
    }
    foreach my $k (keys %labels) {
      $labels{$k} = $trans{"label.$k"} if defined($trans{"label.$k"});
    }
  }
}

sub unpack_buttons {
  $can->packForget;
  $spi->packForget;
  $prv->packForget;
  $spii->packForget;
  $nxt->packForget;
}

sub pack_buttons {
  my ($first) = @_;
  my $skip_buttonconfig = 0;
  if (defined($first) && ($first eq "-no-config")) {
    $skip_buttonconfig = 1;
  }
  if (member("cancel", @_)) {
    $can->pack(-side => "left");
    $spi->pack(-side => "left");
  }
  if (member("next", @_)) {
    # in case we pack the next button and there is no other screen we assume
    # that this is the install screen
    if (!$skip_buttonconfig) {
      if (!defined(next_screen($current_screen))) {
        $nxt->configure(-text => "Install", 
                        -command => \&wizard_installation_window);
      } else {
        $nxt->configure(-text => "Next >", 
                        -command => sub { run_screen(next_screen()); } );
      }
    }
    $nxt->pack(-side => "right");
    $spii->pack(-side => "right");
  }
  if (member("prev", @_)) {
    $prv->pack(-side => "right");
  }
}



################# WELCOME SCREEN ######################################
sub run_menu_wizard {
  my @args = @_;

  if (@args) {
    my $allok = 1;
    for my $s (@args) {
      if (!defined($screen_subs{$s})) {
        tlwarn("screen $s not defined, switching to normal wizard mode!");
        $allok = 0;
        last;
      }
    }
    @screens = @args if $allok;
  }

  calc_depends();
  $mw = Tk::MainWindow->new;

  $ftitle = $mw->Frame;
  $tit = $ftitle->Label(-text => "TeX Live 2008 Installation");
  $tit->pack(-side => "top", -expand => 1, -fill => "both");

  $fmain = $mw->Frame(); ## DEBUG: -relief => "ridge", -borderwidth => 2);

  $fbuttons = $mw->Frame;
  $can = $fbuttons->Button(-width => 10, -relief => "ridge", -text => "Cancel",
               -command => sub { $return = $MENU_ABORT; $mw->destroy; });
  $spi = $fbuttons->Label(-width => 6);
  $nxt = $fbuttons->Button(-width => 10, -relief => "ridge", -text => "Next >",
                           -command => sub { run_screen(next_screen()); } );
  $spii= $fbuttons->Label(-width => 2);
  $prv = $fbuttons->Button(-width => 10, -relief => "ridge", -text => "< Back",
                           -command => sub { run_screen(prev_screen()); } );

  reset_start();


  $ftitle->pack(-side => "top", -expand => 1, -fill => "both", -padx => "8m", -pady => "8m");
  $fmain->pack(-side => "top", -expand => 1, -fill => "both", -padx => "8m", -pady => "8m");
  $fbuttons->pack(-side => "bottom", -expand => 1, -fill => "x", -padx => "8m", -pady => "8m");

  Tk::MainLoop();
  return($return);
}
$::run_menu = \&run_menu_wizard;

sub reset_start {
  $current_screen = "welcome";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;

  my $inf = $fmain->Label(-text => "Welcome to the installation of TeX Live 2008\nhttp://tug.org/texlive\n\nThis wizard will guide you through the installation.");
  $inf->pack(-padx => "3m", -pady => "3m");

  unpack_buttons();
  pack_buttons("cancel", "next");

  $fmain->update;
  $mw->update;
}

############### BINARY SYSTEM SCREEN ############################

sub ask_systems {
  $current_screen = "systems";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;

  my $af = $fmain->Frame;
  my $bf = $fmain->Frame;
  my $lab = $af->Label(-text => "Binary system(s):");
  $lab->pack(-side => "left");
  my $val = $af->Label(-textvar => \$vars{'n_systems_selected'});
  $val->pack(-side => "left", -padx => "3m");
  my $but = $af->Button(-text => "Change", -command => \&change_systems, -relief => "ridge", -width => 10);
  $but->pack(-side => "right");

  my $inf = $bf->Label(-text => "Selects the list of binary systems to be installed.");
  $inf->pack(-padx => "3m", -pady => "3m");

  $af->pack(-expand => 1, -fill => "both");
  $bf->pack(-expand => 1, -fill => "both");

  unpack_buttons();
  pack_buttons("cancel", "prev", "next");

  $fmain->update;
  $mw->update;
}

sub change_systems {
  our $f2r;
  our $f2;
  my $sw = $mw->Toplevel(-title => $labels{'binsys'});
  $sw->transient($mw);
  $sw->grab();
  my @diskarchs = ();
  foreach my $key (keys %vars) {
    if ($key=~/binary_(.*)/) {
      push @diskarchs, $1;
    }
  }
  $sw->Label(-text => $text{'selectsys'})->pack(-padx => "2m", -pady => "2m");
  $f2 = $sw->Frame;
  my $f2l = $f2->Frame;
  foreach my $sys (sort @diskarchs) {
    $f2l->Checkbutton(-variable => \$vars{"binary_$sys"}, -text => platform_desc($sys))->pack(-anchor => 'w');
  }
  $f2l->pack(-side => 'left');
  $f2->pack(-padx => "2m", -pady => "2m");
  my $f3 = $sw->Frame;
  my $okbutton = $f3->Button(-text => $text{'ok'},
     -command => sub { 
                      if ($vars{"binary_win32"}) {
                        $vars{"collection-wintools"} = 1;
                      } else {
                        $vars{"collection-wintools"} = 0;
                      }
                      calc_depends();
                      update_numbers();
                      $sw->destroy; 
                     })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  my $cancelbutton = $f3->Button(-text => $text{'cancel'},
     -command => sub { $sw->destroy })->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $f3->pack(-expand => 'x');
  $sw->bind('<Return>' => [ $okbutton, 'Invoke']);
  $sw->bind('<Escape>' => [ $cancelbutton, 'Invoke']);
}


############## SCHEME SCREEN #####################################

sub ask_scheme {
  $current_screen = "scheme";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;
 
  my $af = $fmain->Frame;
  my $bf = $fmain->Frame;
  my $lab = $af->Label(-text => "Currently selected scheme:");
  $lab->pack(-side => "left");
  my $val = $af->Label(-textvar => \$vars{'selected_scheme'});
  $val->pack(-side => "left", -padx => "3m");
  my $but = $af->Button(-text => "Change", -command => \&change_scheme, -relief => "ridge", -width => 10);
  $but->pack(-side => "right");

  my $inf = $bf->Label(-text => "A scheme defines what will be installed.\nThe predefined scheme-full installs all of TeX Live (recommended).");
  $inf->pack(-padx => "3m", -pady => "3m");

  $af->pack(-expand => 1, -fill => "both");
  $bf->pack(-expand => 1, -fill => "both");

  unpack_buttons();
  pack_buttons("cancel", "prev", "next");

  $fmain->update;
  $mw->update;
}

sub change_scheme {
  my $sw = $mw->Toplevel(-title => $labels{'scheme'});
  $sw->transient($mw);
  $sw->grab();
  my @schemes;
  foreach my $pkg ($tlpdb->list_packages) {
    my $tlpobj = $tlpdb->{'tlps'}{$pkg};
    if ($tlpobj->category eq "Scheme") {
      push @schemes, $pkg;
      $vars{"$pkg"}=($vars{'selected_scheme'} eq $pkg)? 1:0;
    }
  }
  @schemes=sort @schemes;
  my $selected = $vars{'selected_scheme'};
  $sw->Label(-text => $text{'selectscheme'})->pack(-padx => "2m", -pady => "2m");
  my $f2 = $sw->Frame;
  my $f2l = $f2->Frame;
  my $f2r = $f2->Frame;
  my $nrfh = $#schemes / 2;
  my $i = 0;
  foreach my $scheme (@schemes) {
    my $tlpobj = $tlpdb->get_package("$scheme");
    if ($i < $nrfh) {
      $f2l->Radiobutton(-variable => \$selected, -value => $scheme,
        -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    } else {
      $f2r->Radiobutton(-variable => \$selected, -value => $scheme,
        -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    }
    $i++;
  }
  $f2l->pack(-side => 'left', -padx => "2m", -pady => "2m");
  $f2r->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $f2->pack;
  my $f3 = $sw->Frame;
  my $okbutton = $f3->Button(-text => $text{'ok'}, -relief => "ridge",
     -command => sub { select_scheme($selected) ; $sw->destroy })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  my $cancelbutton = $f3->Button(-text => $text{'cancel'}, -relief => "ridge",
     -command => sub { $sw->destroy })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  $f3->pack(-expand => 'x');
  $sw->bind('<Return>' => [ $okbutton, 'Invoke']);
  $sw->bind('<Escape>' => [ $cancelbutton, 'Invoke']);
}


################## PATH SCREEN ################################

sub ask_path {
  $current_screen = "path";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;

  my $af = $fmain->Frame;
  my $bf = $fmain->Frame;
  my $cf = $fmain->Frame;

  my $lab = $af->Label(-text => "Destination Folder:");
  $lab->pack(-side => "left");
  my $val = $af->Label(-textvar => \$dest);
  $val->pack(-side => "left", -padx => "3m");
  my $but = $af->Button(-text => "Change", -command => \&change_path, -relief => "ridge", -width => 10);
  $but->pack(-side => "right");

  my $pa = $cf->Checkbutton(-text => "Use letter-size paper instead of A4 by default", -variable => \$vars{"option_letter"});
  my $cb = $cf->Button(-text => "Advanced customization", 
         -command => sub { $mw->destroy; 
                           #undef &run_menu;
                           @::warn_hook = ();
                           @::debug_hook = ();
                           @::info_hook = ();
                           @::install_packages_hook = ();
                           require("installer/install-menu-perltk.pl");
                           $return = &{$::run_menu}();
                         });
  $pa->pack(-anchor => "w");
  $cb->pack(-anchor => "w");

  calc_depends();
  my $inf = $bf->Label(-text => "Total size needed: $vars{'total_size'} MB\n\nThe destination folder will contain the installation.\nIt is recommended to keep the year as last component.");
  $inf->pack(-padx => "3m", -pady => "3m");

  $af->pack(-expand => 1, -fill => "both");
  $cf->pack(-expand => 1, -fill => "both");
  $bf->pack(-expand => 1, -fill => "both");

  unpack_buttons();
  pack_buttons("cancel", "prev", "next");

  $fmain->update;
  $mw->update;
}

sub change_path {
  my $val = $dest;
  my $sw = $mw->Toplevel(-title => "Changing TEXDIR");
  $sw->transient($mw);
  $sw->grab();
  $sw->Label(-text => $text{'enterpath'} . " TEXDIR: ")->pack(-padx => "2m", -pady => "2m");
  my $entry = $sw->Entry(-textvariable => $val, -width => 60);
  $entry->pack(-padx => "2m", -pady => "2m");
  my $f = $sw->Frame;
  my $okbutton = $f->Button(-text => $text{'ok'}, -relief => "ridge",
     -command => sub { $val = $entry->get; callback_change_texdir($val) ; $sw->destroy })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  my $cancelbutton = $f->Button(-text => $text{'cancel'}, -relief => "ridge",
     -command => sub { $sw->destroy })->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $f->pack(-expand => 'x');
  # bindings
  $sw->bind('<Return>' => [ $okbutton, 'Invoke']);
  $sw->bind('<Escape>' => [ $cancelbutton, 'Invoke']);
}

sub callback_change_texdir {
  my ($val) = @_;
  my $home = getenv('HOME');
  if (win32()) {
    $home = getenv('USERPROFILE');
    $home =~ s!\\!/!g;
  }
  $home ||= '~';
  $val =~ s!\\!/!g;
  $vars{'TEXDIR'} = $val;
  $vars{'TEXDIR'} =~ s/^~/$home/;
  $vars{'TEXMFLOCAL'} =~ s/^~/$home/;
  $vars{'TEXMFSYSVAR'} =~ s/^~/$home/;
  $vars{'TEXMFSYSCONFIG'} =~ s/^~/$home/;
  # only if we set TEXDIR we set the others in parallel
  if ($vars{'TEXDIR'}=~/^(.*)\/$texlive_release$/) {
    $vars{'TEXMFLOCAL'}="$1/texmf-local";
    $vars{'TEXMFSYSVAR'}="$1/$texlive_release/texmf-var";
    $vars{'TEXMFSYSCONFIG'}="$1/$texlive_release/texmf-config";
  } elsif ($vars{'TEXDIR'}=~/^(.*)$/) {
    $vars{'TEXMFLOCAL'}="$1/texmf-local";
    $vars{'TEXMFSYSVAR'}="$1/texmf-var";
    $vars{'TEXMFSYSCONFIG'}="$1/texmf-config";
  }
  $vars{'TEXDIRW'}=$vars{'TEXDIR'};
  $dest = $vars{'TEXDIR'};
}

################## STD COLLECTIONS SCREEN ####################

sub ask_stdcoll {
  $current_screen = "stdcoll";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;
 
  my $af = $fmain->Frame;
  my $bf = $fmain->Frame;
  my $lab = $af->Label(-text => "Standard collections:");
  $lab->pack(-side => "left");
  my $but = $af->Button(-text => "Change", -command => \&change_stdcoll, -relief => "ridge", -width => 10);
  $but->pack(-side => "right");

  my $inf = $bf->Label(-text => "Select the from all available collections.");
  $inf->pack(-padx => "3m", -pady => "3m");

  $af->pack(-expand => 1, -fill => "both");
  $bf->pack(-expand => 1, -fill => "both");

  unpack_buttons();
  pack_buttons("cancel", "prev", "next");

  $fmain->update;
  $mw->update;
}

sub change_stdcoll {
  my $sw = $mw->Toplevel(-title => $labels{'stdcoll'});
  $sw->transient($mw);
  $sw->grab();
  my $fb = $sw->Frame;
  my $fc = $sw->Frame;
  my $fd = $sw->Frame;
  my $f1 = $fb->Frame;
  my $f2 = $fb->Frame;
  my %lvars = %vars;
  $sw->Label(-text => $text{'selectstdcol'})->pack(-padx => "2m", -pady => "2m");
  my $halfcol = $#collections_std / 2;
  my $i = 0;
  foreach my $coll (sort @collections_std) {
    my $tlpobj = $tlpdb->get_package("$coll");
    if ($i < $halfcol) {
      $f1->Checkbutton(-variable => \$lvars{$coll}, -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    } else {
      $f2->Checkbutton(-variable => \$lvars{$coll}, -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    }
    $i++;
  }
  $f1->pack(-side => 'left', -padx => "2m", -pady => "2m");
  $f2->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $fb->pack(-padx => "2m", -pady => "2m");
  $fd->pack();
  $fd->Button(-text => $text{'selectall'},
    -command => sub { select_collections(\%lvars, @collections_std) })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  $fd->Button(-text => $text{'selectnone'},
    -command => sub { deselect_collections(\%lvars, @collections_std) })->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $fc->pack(-expand => 'x', -padx => "2m", -pady => "2m");
  my $okbutton = $fc->Button(-text => $text{'ok'},
     -command => sub { %vars = %lvars; wizard_callback_select_collection() ; $sw->destroy })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  my $cancelbutton = $fc->Button(-text => $text{'cancel'},
     -command => sub { $sw->destroy })->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $sw->bind('<Return>' => [ $okbutton, 'Invoke']);
  $sw->bind('<Escape>' => [ $cancelbutton, 'Invoke']);
}

sub wizard_callback_select_collection {
  calc_depends();
  update_numbers();
}

#################  LANGUAGE COLLECTIONS #######################

sub ask_langcoll {
  $current_screen = "langcoll";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;
 
  my $af = $fmain->Frame;
  my $bf = $fmain->Frame;
  my $lab = $af->Label(-text => "Language collections:");
  $lab->pack(-side => "left");
  my $but = $af->Button(-text => "Change", -command => \&change_langcoll, -relief => "ridge", -width => 10);
  $but->pack(-side => "right");

  my $inf = $bf->Label(-text => "Select language support and documentation.");
  $inf->pack(-padx => "3m", -pady => "3m");

  $af->pack(-expand => 1, -fill => "both");
  $bf->pack(-expand => 1, -fill => "both");

  unpack_buttons();
  pack_buttons("cancel", "prev", "next");

  $fmain->update;
  $mw->update;
}

sub change_langcoll {
  my $sw = $mw->Toplevel(-title => $labels{'langcoll'});
  $sw->transient($mw);
  $sw->grab();
  my $f1 = $sw->Frame;
  $f1->pack;
  my $f1lang = $f1->Labelframe(-text => $text{'selectlang'});
  my $f1doc  = $f1->Labelframe(-text => $text{'selectdoc'});
  $f1lang->pack(-side => 'left', -padx => "2m", -pady => "2m", -ipadx => "2m", -ipady => "2m");
  $f1doc->pack(-side => 'right', -padx => "2m", -pady => "2m", -ipadx => "2m", -ipady => "2m", -expand => 1, -fill => "y");
  my $f1langT = $f1lang->Frame; $f1langT->pack;
  my $f1langL = $f1lang->Frame; $f1langL->pack;
  my $f1langLa = $f1langL->Frame; $f1langLa->pack(-side => 'left');
  my $f1langLb = $f1langL->Frame; $f1langLb->pack(-side => 'right');
  my $langh = $#collections_lang / 2;
  my $i = 0;
  my %lvars = %vars;
  foreach my $coll (sort @collections_lang) {
    my $tlpobj = $tlpdb->get_package("$coll");
    if ($i < $langh) {
      $f1langLa->Checkbutton(-variable => \$lvars{$coll}, -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    } else {
      $f1langLb->Checkbutton(-variable => \$lvars{$coll}, -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    }
    $i++;
  }
  my $f1langB = $f1lang->Frame;
  $f1langB->pack(-expand => 'x');
  $f1langB->Button(-text => $text{'selectall'},
    -command => sub { select_collections(\%lvars, @collections_lang) })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  $f1langB->Button(-text => $text{'selectnone'},
    -command => sub { deselect_collections(\%lvars, @collections_lang) })->pack(-side => 'right', -padx => "2m", -pady => "2m");

  my $f1docT = $f1doc->Frame; $f1docT->pack;
  my $f1docL = $f1doc->Frame; $f1docL->pack;
  my $f1docLa = $f1docL->Frame; $f1docLa->pack(-side => 'left');
  my $f1docLb = $f1docL->Frame; $f1docLb->pack(-side => 'right');
  my $doch = $#collections_lang_doc / 2;
  $i = 0;
  foreach my $coll (sort @collections_lang_doc) {
    my $tlpobj = $tlpdb->get_package("$coll");
    if ($i < $doch) {
      $f1docLa->Checkbutton(-variable => \$lvars{$coll}, -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    } else {
      $f1docLb->Checkbutton(-variable => \$lvars{$coll}, -text => $tlpobj->shortdesc)->pack(-anchor => 'w');
    }
    $i++;
  }
  my $f1docB = $f1doc->Frame;
  $f1docB->pack(-expand => 1, -side => "bottom");
  $f1docB->Button(-text => $text{'selectall'},
    -command => sub { select_collections(\%lvars, @collections_lang_doc) })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  $f1docB->Button(-text => $text{'selectnone'},
    -command => sub { deselect_collections(\%lvars, @collections_lang_doc) })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  my $f2 = $sw->Frame; $f2->pack(-expand => 'x');
  my $okbutton = $f2->Button(-text => $text{'ok'},
     -command => sub { %vars = %lvars; wizard_callback_select_collection() ; $sw->destroy })->pack(-side => 'left', -padx => "2m", -pady => "2m");
  my $cancelbutton = $f2->Button(-text => $text{'cancel'},
     -command => sub { $sw->destroy })->pack(-side => 'right', -padx => "2m", -pady => "2m");
  $sw->bind('<Return>' => [ $okbutton, 'Invoke']);
  $sw->bind('<Escape>' => [ $cancelbutton, 'Invoke']);
}


################## INSTALL SCREEN #############################

sub ask_go {
  $current_screen = "install";
  for ($fmain->children) {
    $_->destroy;
  }
  $fmain->update;
  $mw->update;

  my $inf = $fmain->Label(-justify => "left", -text => "We are ready to install TeX Live 2008.\nThe following settings will be used.\nIf you want to change something please go back,\notherwise press the \"Install\" button.\n\nDestination folder:   $dest\nSelected scheme:   $vars{'selected_scheme'}");
  $inf->pack(-padx => "3m");
  
  unpack_buttons();
  pack_buttons("cancel", "prev", "next");

  $fmain->update;
  $mw->update;
}

sub wizard_installation_window {
# create a progress bar window
  $::sww = $mw->Toplevel(-title => "installation process",
                        -width => 400);
  $::sww->transient($mw);
  $::sww->grab();
  $::sww->Label(-text => "Installation process")->pack;
  $::progressw = $::sww->Scrolled("ROText", -scrollbars => "e", -height => 16);
  $::progressw->pack(-expand => 1, -fill => "both");
  my $percent_done = 0;
  $::progress = $::sww->ProgressBar(-variable => \$percent_done,
      -width => 20, -length => 400, -from => 0, -to => 100, -blocks => 10,
      -colors => [ 0, '#0078b8' ]);
  $::progress->pack(-fill => "x");
  my $f = $::sww->Frame;
  my $b = $f->Button(-text => $text{'cancel'}, -relief => "ridge",
                  -command => sub { $::sww->destroy; $mw->destroy;
                        do_cleanup(); exit(1); }
            )->pack(-pady => "2m");
  $f->pack;
# set the vars
  calc_depends();
  $mw->Busy(-recurse => 1);
  do_installation();
  $mw->Unbusy;
  $::sww->destroy;
  $return = $MENU_ALREADYDONE;
  my $t = $text{'finished'};
  if (!win32()) {
    $t .= "\n\n$text{'finishedpath'}";
  }
  $t .= "\n\n$text{'welcome'}";
  $t =~ s/TEXDIR/$::vars{'TEXDIR'}/g;
  $t =~ s/PLATFORM/$::vars{'this_platform'}/g;
  $t =~ s/\\n/\n/g;
  for ($fmain->children) {
    $_->destroy;
  }
  $can->packForget;
  $prv->packForget;
  my $lab = $fmain->ROText(-height => 16, -relief => "flat", -wrap => "word");
  my $linechar = $lab->index("end");
  $lab->markSet("finaltext", $linechar);
  $lab->markGravity("finaltext", "left");
  $lab->insert("end", "\n$t");
  $lab->see("end");
  $lab->tagAdd("centered", $linechar, "end");
  $lab->tagConfigure("centered", -justify => "center");
  $lab->pack;
  $nxt->configure(-text => $text{'finbut'},
                -command => sub { $mw->destroy; });
}

################### END OF MODULE RETURN 1 FOR REQUIRE ###########

1;

__END__

### Local Variables:
### perl-indent-level: 2
### tab-width: 2
### indent-tabs-mode: nil
### End:
# vim:set tabstop=2 expandtab: #