summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/source/latex/stex/xsl/LaTeXML/LaTeXML-structure-xhtml.xsl
blob: e3665da7a2579e7dbf9c8f19b15bd80138488f7b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
<?xml version="1.0" encoding="utf-8"?>
<!--
/=====================================================================\ 
|  LaTeXML-structure-xhtml.xsl                                        |
|  Converting documents structure to xhtml                            |
|=====================================================================|
| Part of LaTeXML:                                                    |
|  Public domain software, produced as part of work done by the       |
|  United States Government & not subject to copyright in the US.     |
|=====================================================================|
| Bruce Miller <bruce.miller@nist.gov>                        #_#     |
| http://dlmf.nist.gov/LaTeXML/                              (o o)    |
\=========================================================ooo==U==ooo=/
-->
<xsl:stylesheet
    version     = "1.0"
    xmlns:xsl   = "http://www.w3.org/1999/XSL/Transform"
    xmlns:ltx   = "http://dlmf.nist.gov/LaTeXML"
    xmlns       = "http://www.w3.org/1999/xhtml"
    xmlns:f     = "http://dlmf.nist.gov/LaTeXML/functions"
    extension-element-prefixes="f"
    exclude-result-prefixes = "ltx f">

  <!-- ======================================================================
       Document Structure
       ====================================================================== -->

  <xsl:template match="ltx:document  | ltx:part | ltx:chapter
		       | ltx:section | ltx:subsection | ltx:subsubsection
		       | ltx:paragraph | ltx:subparagraph | ltx:slide
		       | ltx:bibliography | ltx:appendix | ltx:index" xml:space="preserve">
    <div class="{f:classes(.)}"><xsl:call-template name="add_id"/>
    <xsl:apply-templates/>
    </div>
  </xsl:template>

  <xsl:template match="ltx:creator[@role='author']" xml:space="preserve">
    <div class="{concat(f:classes(.),' ',@role)}"><xsl:call-template name="add_id"/><xsl:apply-templates/></div>
  </xsl:template>

  <xsl:template match="ltx:personname" xml:space="preserve">
    <div class="{f:classes(.)}"><xsl:call-template name="add_id"/><xsl:apply-templates/></div>
  </xsl:template>

  <xsl:template match="ltx:contact[@role='address']" xml:space="preserve">
    <div class="{concat(f:classes(.),' ',@role)}"><xsl:call-template name="add_id"/><xsl:apply-templates/></div>
  </xsl:template>

  <xsl:template match="ltx:contact[@role='email']" xml:space="preserve">
    <div class="{concat(f:classes(.),' ',@role)}"><xsl:call-template name="add_id"/><a href="{concat('mailto:',text())}"><xsl:apply-templates/></a></div>
  </xsl:template>

  <xsl:template match="ltx:contact[@role='dedicatory']" xml:space="preserve">
    <div class="{concat(f:classes(.),' ',@role)}"><xsl:call-template name="add_id"/><xsl:apply-templates/></div>
  </xsl:template>

  <!-- put in footer -->
  <xsl:template match="ltx:date"/>

  <xsl:template match="ltx:abstract" xml:space="preserve">
    <div class='{f:classes(.)}'>
      <xsl:call-template name="add_id"/>
      <xsl:if test="@name"><h6><xsl:apply-templates select="@name"/><xsl:text>.</xsl:text></h6></xsl:if>
      <xsl:apply-templates/>
    </div>
  </xsl:template>

  <xsl:template match="ltx:acknowledgements">
    <div class='{f:classes(.)}'>
      <xsl:call-template name="add_id"/>
      <xsl:if test="@name"><h6><xsl:apply-templates select="@name"/><xsl:text>.</xsl:text></h6></xsl:if>
      <xsl:apply-templates/>
    </div>
  </xsl:template>

  <xsl:template match="ltx:keywords[not(string(.))]" xml:space="preserve">
    <div class="RDFa"><xsl:copy-of select="@*"/></div>
  </xsl:template>


  <xsl:template match="ltx:keywords" xml:space="preserve">
    <div class='{f:classes(.)}'>
      <xsl:call-template name="add_id"/>
      <xsl:if test="@name"><h6><xsl:apply-templates select="@name"/><xsl:text>:</xsl:text></h6></xsl:if>
      <xsl:apply-templates/>
    </div>
  </xsl:template>

  <xsl:template match="ltx:classification">
    <xsl:text>
    </xsl:text>
    <div class='{f:classes(.)}'>
      <xsl:call-template name="add_id"/>
      <i><xsl:choose>
	<xsl:when test='@scheme'><xsl:value-of select='@scheme'/></xsl:when>
	<xsl:when test='@name'><xsl:value-of select='@name'/></xsl:when>
      </xsl:choose>: </i>
    <xsl:apply-templates/></div>
  </xsl:template>

  <!--  ======================================================================
       Titles.
       ====================================================================== -->
  <!-- Hack to determine the `levels' of various sectioning.
       Given that the nesting could consist of any of
       document/part/chapter/section or appendix/subsection/subsubsection
       /paragraph/subparagraph
       We'd like to assign h1,h2,... sensibly.
       Or should the DTD be more specific? -->

  <xsl:param name="title_level">6</xsl:param>

  <xsl:param name="document_level">
    <xsl:value-of select="1"/>
  </xsl:param>

  <xsl:template match="ltx:document/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$document_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:param name="part_level">
    <xsl:value-of select="$document_level+number(boolean(ltx:document))"/>
  </xsl:param>

  <xsl:template match="ltx:part/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$part_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:param name="chapter_level">
    <xsl:value-of select="$part_level+number(boolean(//ltx:part))"/>
  </xsl:param>

  <xsl:template match="ltx:chapter/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$chapter_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:param name="section_level">
    <xsl:value-of select="$chapter_level+number(boolean(//ltx:chapter))"/>
  </xsl:param>

  <xsl:template match="ltx:section/ltx:title | ltx:bibliography/ltx:title
		       | ltx:index/ltx:title | ltx:appendix/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$section_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:param name="subsection_level">
    <xsl:value-of select="$section_level+number(boolean(//ltx:section | //ltx:appendix
			                                | //ltx:index | //ltx:bibliography))"/>
  </xsl:param>

  <xsl:template match="ltx:subsection/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$subsection_level"/>
    </xsl:call-template>
  </xsl:template>


  <xsl:param name="subsubsection_level">
    <xsl:value-of select="$subsection_level+number(boolean(//ltx:subsection))"/>
  </xsl:param>

  <xsl:template match="ltx:subsubsection/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$subsubsection_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:param name="paragraph_level">
    <xsl:value-of select="$subsubsection_level+number(boolean(//ltx:subsubsection))"/>
  </xsl:param>

  <xsl:template match="ltx:paragraph/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$paragraph_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:param name="subparagraph_level">
    <xsl:value-of select="$paragraph_level+number(boolean(//ltx:paragraph))"/>
  </xsl:param>

  <xsl:template match="ltx:subparagraph/ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="$subparagraph_level"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template match="ltx:title">
    <xsl:call-template name="maketitle">
      <xsl:with-param name="title_level" select="6"/>
    </xsl:call-template>
  </xsl:template>

  <!-- Convert a title to an <h#>, with appropriate classes and content.
       The parameter $title_level should specify the level 1-6,
       determined by the container and its context in the document.
       A title always appears as a child of a Labelled element. -->
  <xsl:template name="maketitle">
    <xsl:param name="title_level">6</xsl:param>
    <xsl:param name="use_level">
      <xsl:choose>
	<xsl:when test="$title_level &gt; 6">6</xsl:when>
	<xsl:otherwise><xsl:value-of select="$title_level"/></xsl:otherwise>
      </xsl:choose>
    </xsl:param>
    <xsl:element name="{concat('h',$use_level)}">
      <xsl:call-template name="add_id"/>
      <xsl:attribute name="class">
	<xsl:value-of select="concat(f:classes(.),
			      ' ',concat(local-name(..),'-title'),
			      f:if(@font,concat(' ',@font),''),
			      f:if(@size,concat(' ',@size),''))"/>
      </xsl:attribute>
      <xsl:if test="@color">
	<xsl:attribute name="style">
	  <xsl:value-of select="concat('color:',@color)"/>
	</xsl:attribute>
      </xsl:if>
      <xsl:apply-templates/>
    </xsl:element>
  </xsl:template>

  <xsl:template match="ltx:toctitle"/>

<!-- NOTE: Probably should support font, punct, etc, right? -->
  <xsl:template match="ltx:subtitle">
    <div class="{f:classes(.)}"><xsl:call-template name="add_id"/><xsl:apply-templates/></div>
  </xsl:template>

  <!-- ======================================================================
       Indices
       ====================================================================== -->

  <xsl:template match="ltx:indexlist">
    <ul class="{f:classes(.)}">
      <xsl:call-template name="add_id"/>
      <xsl:apply-templates/>
    </ul>
  </xsl:template>

  <xsl:template match="ltx:indexentry">
    <li class="{f:classes(.)}"><xsl:call-template name="add_id"/>
    <xsl:apply-templates select="ltx:indexphrase"/>
    <xsl:apply-templates select="ltx:indexrefs"/>
    <xsl:apply-templates select="ltx:indexlist"/>
    </li>
  </xsl:template>

  <xsl:template match="ltx:indexrefs">
    <span class="{f:classes(.)}"><xsl:call-template name="add_id"/><xsl:apply-templates/></span>
  </xsl:template>

</xsl:stylesheet>