summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/public/pl/pl_sym.mf
blob: 0605aa4aff927afdc77f9e88544a9a479879ca31 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
% ---------------------------------------------------------------------------
% This is PL_SYM.MF (polskie symbole matematyczne, i.e., extra
% Polish math symbols) in text format. Characters |xleq| and |xgeq| are
% generated when their codes are known.
% The program is a modification of the SYM.MF file.
% ---------------------------------------------------------------------------
% PL VERSION 1.09a, 30th March 2020 (see README.ENG)
% ---------------------------------------------------------------------------
% AUTHORS OF MODIFICATION: Bogusław Jackowski and Marek Ryćko
% ---------------------------------------------------------------------------
% This file belongs to the public domain under conditions similar to
% those of D. E. Knuth specified for the Computer Modern family of fonts.
%
% For details see either the file MEXINFO.POL or MEXINFO.ENG.
% ---------------------------------------------------------------------------
iff known xleq: cmchar "Extra less than or equal to sign";
compute_spread(.45x_height#,.55x_height#);
spread#':=spread#; spread':=spread; % the spread of `$=$'
compute_spread(5/4x_height#,3/2x_height#);
beginchar(xleq,14u#,v_center(spread#'+spread#+rule_thickness#));
 italcorr h#*slant-u#;
 adjust_fit(0,0); pickup rule.nib;
 lft x2=hround 1.5u-eps; x1=x3=w-x2;
 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
 draw z1--z2--z3; % diagonals
 x8=x1; x9=x2; y2-y9=y3-y8=floor(spread'); draw z8--z9;  % skew bar
 labels(1,2,3,8,9);
endchar;

iff known xgeq: cmchar "Extra greater than or equal to sign";
compute_spread(.45x_height#,.55x_height#);
spread#':=spread#; spread':=spread; % the spread of `$=$'
compute_spread(5/4x_height#,3/2x_height#);
beginchar(xgeq,14u#,v_center(spread#'+spread#+rule_thickness#));
 italcorr h#*slant-u#;
 adjust_fit(0,0); pickup rule.nib;
 lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
 draw z1--z2--z3;  % diagonals
 x8=x1; x9=x2; y2-y9=y3-y8=floor(spread'); draw z8--z9; % skew bar
 labels(1,2,3,8,9);
endchar;

endinput

%%\end