summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/bibtex/bst/din1505/unsrtdin.bst
blob: 5505961b707fe92cf681c46b4d1cee587c639b93 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
%%  UNSRTDIN.BST        Ausgabe [8.2]      2006-01-02
%%       mit doi-, urn-, url-Funktionen
%%       ersetzt UNSRTDIN.BST       Ausgabe [8.1b3]  22.2.2005
%%       ersetzt UNSRTDIN.BST       Ausgabe [7]  16/6/99
%%
%%   K.F.Lorenzen  (Copyright 1994-2006)  email:  lorenzen.marxen@t-online.de
%%  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
%%  UNSRTDIN.BST wurde entwickelt aus BibTeX standard bibliography style
%% `unsrt'.Mit UNSRTDIN.BST werden Literaturverzeichnisse gemaess der deutschen
%%  Zitiernorm DIN 1505 Teil 2 formatiert.
%%  Analog zu den 4 US standard styles wird ein vollstaendiger Satz von
%%  4 DIN-gerechten bst-style Dateien veroeffentlicht (alphadin.bst,
%%  plaindin.bst, unsrtdin.bst, abbrvdin.bst). Die gueltige Version
%%  ist am schnellsten aus dem WWW ueber folgende URL zu beziehen
%%            http://www.haw-hamburg.de/pers/Lorenzen/bibtex/
%%            Stand: 2006-01-02
%%  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
%%  WAS IST UNSRTDIN.BST ?
%%  Dieser style produziert Literaturzitate in Literaturverzeichnissen
%%  gemaess der deutschen Norm DIN 1505, Teil 2 vom Jan. 1984.
%%  Die Reihenfolge der Zitate im Text bestimmt die Reihenfolge im
%%  Literaturverzeichnis, das somit unsortiert ist. Form und Gestaltung
%%  entsprechen der von plaindin.bst. Die label im Literaturverzeichnis sowie
%%  im Text sind Nummern in eckigen Klammern. Die vorliegenden DIN-styles
%%  gehen ueber die bibliographischen Beschraenkungen der Originalstyles hinaus.
%
%%  Es werden nun auch Elektronische Online / Offline Ressourcen wie Internet-
%%  quellen, CD-ROM usw. verarbeitet. Dazu kommen besondere Publikationsformen
%%  wie Patente, Normen, Karten, Fernsehaufzeichnungen, Gesetzesstellen, Spiele.
%
%%  Zur Gewaehrleistung der Allgemeingueltigkeit von bib-files gelten in den
%%  DIN-styles die in der Tex-Literatur veroeffentlichten originalen
%%  Definitionen und Regeln fuer die Publikationstypen (entry-types) und die
%%  bibliographischen Felder (fields).
%%  Treten kleinere "Schoenheitsfehler" im fertig gesetzten output auf,
%%  lassen sich diese so gut wie immer durch eine veraenderte
%%  Erfassung im bib-inputfile beseitigen. Oren Patashnik empfiehlt, die
%%  Definition der Felder weit auszulegen. Last but not least koennen
%%  Sie im output-file < *.bbl > noch letzte Hand zur Korrektur ansetzen.
%
%%  WARN- UND FEHLERMELDUNGEN
%%  Ursache von Warnmeldungen sind meistens ausgelassene Felder oder
%%  Erfassungs-"Fehler". Letztere haengen teilweise mit den gegenueber US-
%%  Gepflogenheiten andersartigen bibliographischen Regeln nach DIN 1505
%%  zusammen. Sie sind also in Wahrheit keine "Fehler" und duerfen fast immer
%%  ignoriert werden. Dennoch pruefen Sie diese Warnungen, um heraus zu finden,
%%  ob Publikationstyp (=entry-type) und "fields" eventuell unzulaessig
%%  kombiniert worden sind.
%%  Echte Fehler ("errors") treten nur noch in Verbindung mit falscher
%%  Erfassung auf (nach meinen Tests!). Pruefen Sie die Syntax, den entry-type
%%  und die fields.
%%  Zu guter letzt: Qualitaetsmasstab ist einzig der DIN-konforme output!
%%
%%  DANKSAGUNG
%%  Hartmut Lueddecke, HAW Hamburg, hat viele Verbesserungsvorschlaege
%%  in die frueheren Versionen eingebracht. Ihm danke ich herzlich.
%%  Patrick W. Daly, dem Entwickler des Natbib-Stils, verdanke ich viele
%%  Anregungen und den steten Ansporn, die DIN-Stile zu verbessern.
%%  Viele an dieser Stelle ungenannt bleibende Anwender haben mich in
%%  den vergangenen Jahren auf Fehler oder Verbesserungsmoeglichkeiten
%%  aufmerksam gemacht und so diesen Stil mitentwickelt. Ihnen gilt mein
%%  besonderer Dank. Ihr Feedback ist immer willkommen und eine Ermunterung.
%%
%%  Klaus F. Lorenzen
%%
%%
%%
%%  HINWEIS: Neben den vier bibliographischen DIN 1505 Standard-Stilen
%%           nach den Original-styles von Oren Patashnik
%%           gibt es zusaetzlich vier DIN 1505 Modifikationen der style
%%           Emulationen des NATBIB-Pakets von Patrick W.Daly.
%%           In den NATBIB-Modifikationen werden jetzt alle von P.W. Daly
%%           implementierten Zitierweisen des Autor-Jahr-Stils unterstuetzt.
%%           Damit erhaelt der Anwender eine weit ueber die urspruenglichen
%%           Standardstyles hinausreichende Flexibilitaet beim Zitieren.
%%           Naeheres unter URL http://www.haw-hamburg.de/pers/Lorenzen/bibtex/
%%
%%
%%  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
%       version 0.99c for BibTeX versions 0.99c or later, LaTeX2e
%       Copyright (C) 1985, all rights reserved.
%       Copying of this file is authorized only if either
%       (1) you make absolutely no changes to your copy, including name, or
%       (2) if you do make changes, you name it something other than
%       plaindin.bst, unsrtdin.bst, alphadin.bst, and abbrvdin.bst.
%       This restriction helps ensure that all standard styles are identical.
%       The file btxbst.doc has the original documentation for style 'alpha'.
%%
%%  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
%%
%%  NEUE FELDER
%%  Zur Erfassung der neuen digitalen Online-Medien z.B. Internetquellen, E-journals, E-books,
%%  E-mail u.a. gibt es die zusaetzlichen Felder: doi, url, urn, lastchecked
%%  Internetquellen werden vorzugsweise mit dem BOOKLET-Typ erfasst.
%%  Normen, Patente, Schutzrechte sind mit dem MISC-Typ zu erfassen.
%
%
ENTRY
  { address      %%  Verlagsort
    author       %%  persoenlicher Urheber eines Werkes
    booktitle    %%  a) Gesamttitel eines mehrbaendigen Werkes
%                %%  b) Titel des Sammelwerks, das einzelne selbstaendige
%                %%     Beitraege mit eigenem Titel enthaelt (->incollection)
    chapter      %%  Kapitel in einem Buch (Monographie)
    doi          %%% Digital Object Identifier
    edition      %%  Auflagevermerk; bei selbst. elektron. Dok. == Version
    editor       %%  Persoenl.Herausgeber oder Koerperschaftlicher Herausgeber
    howpublished %%  beliebiger Verlegervermerk: von wem, wo
    institution  %%  Institution, die e.Verlagsfreie Veroeffentlichung betreibt
    isbn         %%  Standardnr fuer Buecher
    issn         %%  - " -    :      Zeitschriften u. Serien
    journal      %%  Titel einer Zeitschrift
    key          %%  Zusaetzlich vergebener Sortierschluessel, mitunter notwend.
    lastchecked  %%  Online Abruf einer Internetquelle ( GRAY ); 22.1.2004
    month        %%  naehere Bestimmung des Erscheinungsjahres (-> macro 's)
    note         %%  freies Eingabefeld fuer zusaetzliche Informationen
    number       %%  Mehrfachbedeutung in Abhaengigkeit vom Eingabetyp
    organization %%  a) Name der Organisation/des Organisators e. Tagung,Konferenz
%                %%  b) Name einer Firma/Gesellschaft, die ein ->manual herausgab
    pages        %%  Umfangsangaben, meist Seitenzahlen
    publisher    %%  Verlag
    school       %%  Hochschule/Universitaet, die eine Dipl.-Arb./Dissertation veroeff.
    series       %%  Titel e.Reihe, in der ein best. Buchtitel erschienen ist
    title        %%  Titel einer (namentlich gekennzeichneten) Veroeffentlichung
    type         %%  Zusatzfeld z.Kennzeichnung e.besonderen Publikationstyps
    url          %%%  Internet-Adresse URL ( Uniform Resource Locator )
    urn          %%   Persistent Identifier URN ( Uniform Resource Name )
    volume       %%  a) Zaehlung bei einem mehrbaendigen Werk (-> book)
%                %%  b) Jahrgang einer Zeitschrift (-> article
    year         %%  Erscheinungsjahr
  }
  {}
  { label }

%% Variablen-Vereinbarungen

INTEGERS { output.state before.all mid.sentence after.sentence after.block }

INTEGERS { colon.after  period.dash }

INTEGERS { after.firstblock }

%% fuer die Namensbehandlung

INTEGERS { zahl  lang }

INTEGERS { nameptr namesleft numnames }

INTEGERS { ptr collation collrest }

%% fuer die Sortierung bei der label-Produktion
INTEGERS { len }

INTEGERS { number.label longest.label.width }
%%----------------------------------------------------------------------

STRINGS { h s t u v w }

%% bei der Behandlung der Namen-Funktionsbezeichnung (Hrsg., Redakt., usw)
STRINGS { fkt }

%% fuer die label-Produktion
STRINGS { longest.label }

%%%----------------------------------------------------------------------------
%  Einige Standardvorgaben, die vom Benutzer veraendert werden koennen.
%%%----------------------------------------------------------------------------

%  Abkuerzung ("... und andere") bei Mehrverfasserquellen:

FUNCTION { ua.etal } { " u.\,a." } %% evtl. auch in eckigen Klammern " [u.\,a.]"

%%  oder lateinisch:  FUNCTION { ua.etal } { " et~al." }

FUNCTION { und } { " u. " }

%%  oder ausgeschrieben:  FUNCTION { und } { " und " }
%
% Einige elektronische Medien erhalten nach DIN 1505 eine "Ergaenzende Angabe"
% zusaetzlich zum materiellen Typ, z.B. CD ROM oder DVD u.a.:

FUNCTION { eress } { "Elektronische Ressource" }

%%%-----------------------------------------------------------------------------------


FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.sentence :=
  #3 'after.block :=
  #4 'colon.after :=
  #5 'period.dash :=
  #6 'after.firstblock :=
}

FUNCTION {output.nonnull}
{ 's :=
  output.state after.block =
      { add.period$  write$
        newline$
        "\newblock " write$
      }
      { output.state before.all =
          { write$ }
          {  output.state colon.after =
               { ": " * write$
                 newline$
                 "\newblock " write$
               }
               { output.state period.dash =
                   { ". -- " *  write$
                     newline$
                     "\newblock " write$
                   }
                   { output.state mid.sentence =
                       { ", " * write$ }
                       { output.state after.sentence =
                           { " " * write$ }
                           { output.state after.firstblock =
                               { add.period$  write$
                                 newline$
                                 "\newblock " write$
                               }
                               { write$
                                 newline$
                                 "\newblock " write$
                               }
                             if$
                            }
                          if$
                       }
                     if$
                   }
                 if$
               }
             if$
           }
         if$
       after.block 'output.state :=
      }
    if$
    s
 }

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { after.block 'output.state := }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}


FUNCTION {output.bibitem}
{ newline$
  "\bibitem[" write$
  label write$%
  "]{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {fin.entry}
{ write$
  newline$
}

FUNCTION {set.period.dash}    %% Wenn ein ". - " die Satzteile trennen soll.!
{ output.state before.all =
    'skip$
    { period.dash  'output.state := }
  if$
}

FUNCTION {set.period.dash.check}
{ empty$
    'skip$
    'set.period.dash
  if$
}

FUNCTION {set.colon.after}   %%$$$ Wenn ein ": " d. Satzteile trennen soll!
{ output.state before.all =
    'skip$
    { colon.after 'output.state  := }
  if$
}

%%                                 Wenn ein " " die Satzteile trennen soll.!
FUNCTION {new.sentence}
{ output.state before.all =
     'skip$
     { after.sentence 'output.state := }
  if$
}

%%                                 Wenn ein ", " die Satzteile trennen soll.!
FUNCTION { part.of.sentence }
{ output.state before.all =
     'skip$
     { mid.sentence 'output.state := }
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "\emph{" swap$ * "}" * }
  if$
}

FUNCTION { capitalize }
 { duplicate$ empty$
    { pop$ "" }
    { "\textsc{" swap$ * "}" * }
  if$
}

FUNCTION {article.in.journal}
{ duplicate$ empty$
    { pop$ "" }
    { author missing$ title missing$ and
            { emphasize }
            { emphasize "{In: }" swap$ * }
          if$
     }
  if$
}

FUNCTION {format.doi}
{ doi empty$
    { "" }
    { new.block "\url{http://dx.doi.org/" doi * "}" *
     %%      { new.block "\url{http://dx.medra.org/" doi * "}" *
    }
  if$
}

FUNCTION {format.url}
{ urn missing$
     { doi missing$
          { url empty$
             { "" }
             { type empty$ NOT
                 { type #-1 #4 substring$ "mail" =
                   type #1 #4 substring$ "Mail" =
                   OR
                      { type$ "incollection" =
                          { "" }
                          { "\,Absenderadresse: \url{" url * "}" * }
                        if$
                      }
                      { "\url{" url * "}" * }%%   evtl. "URL" oder "<...>"
                    if$
                  }
                  { "\url{" url * "}" * }   %%   evtl. "URL" oder "<...>"
                if$
             }
           if$
          }
          { format.doi }
        if$
      }
      { "\url{http://nbn-resolving.de/urn/resolver.pl?urn=" urn * "}" *
      }
    if$
}

FUNCTION {format.maillist.url}
  { url empty$
       { "" }
       { type empty$
             { "" }
             { type #-1 #4 substring$ "mail" =
               type #1 #4 substring$ "Mail" =
               OR
                  { "\url{" url * "}" * }
                  { "" }
                if$
              }
           if$
        }
      if$
   }



%% Adelspraedikate beim Sortieren nach den(m) Vornamen auffuehren
%% Abweichend v. DIN !!!
FUNCTION {format.names}
{ 's :=
  "" 'u  :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    {
       s nameptr "{ll}" format.name$ 't :=
       t capitalize 't :=
       s nameptr "{ jj}" format.name$ 'w :=
       s nameptr "{, ff}{ vv}{ jj}" format.name$ 'u :=
       u  text.length$  'lang :=
       #1 'zahl :=
       "" 'v :=
         {  zahl  lang  <  }
         {  u  zahl  #1  substring$  "~"  =
               {  v  ""  =
                     {  u  #1  zahl  #1  -  substring$  'v :=  }
                     'skip$
                  if$
                  v  u  zahl  #2  substring$ * "." *  w * 'v :=
                }
               'skip$
            if$
            zahl  #1  +  'zahl :=  }
      while$
      v  ""  =
         {  u  'v :=  }
         'skip$
      if$
      t  v  *  fkt  *  't :=
      nameptr #1 >
         { namesleft #1 >
             { " ; " * t * }
             { numnames #2 >
                  { " " * }
                  'skip$
               if$
               t "\textsc{others}" = t "\textsc{others} (Hrsg.)" = or
                  { ua.etal * }
                  { " ; " * t * }
               if$
               }
            if$  %% Ende der namesleft-Pruefung
          }
            't
           if$  %%  Ende der nameptr-Pruefung

      nameptr #1 + 'nameptr :=
      namesleft #1 -  'namesleft :=
    }
  while$  %%  Ende von { namesleft #0 > } ganz oben
  "" 'fkt :=  %% fkt wird zurueckgesetzt
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
   { author empty$
       { "empty author and editor in " cite$ * warning$ "" }
       'skip$
     if$
   }
   { author empty$
        { " (Hrsg.)" 'fkt :=
          editor format.names
        }
        { " (Hrsg.)" 'fkt :=
          " ; " * editor format.names *
        }
      if$
   }
 if$
 }

FUNCTION { format.authors.organization }
{ type$ "misc" =
        { organization empty$
            { author empty$
               { "" }
               { author format.names " (Erfinder)" * }
             if$
            }
            { author empty$
               { organization  }
               { author format.names " (Erfinder); " *
                 organization * " (Anmelder)" *
               }
             if$
            }
          if$
        }
        { type$ "manual" =
           { organization empty$
               { format.authors }
               { author empty$
                   { organization capitalize " (Hrsg.)" * }
                   { author format.names }
                 if$
               }
             if$
           }
           'skip$
         if$
        }
      if$
}



FUNCTION { format.editors.organization }
{ organization empty$
    'skip$
    { type$ "misc" =
        { organization }
        { * " ; " * organization " (Veranst.)" *}
      if$
    }
  if$
}

FUNCTION { format.tr.institution }
{ institution empty$
    'skip$
   { institution capitalize }
 if$
}

FUNCTION {format.ed.incoll}
{ editor empty$
     { "" }
     { " (Hrsg.)" 'fkt :=
       editor format.names
     }
  if$
}


FUNCTION {format.title}
{ title empty$
    { "" }
    { title }  %% Text so wie er dasteht im Feld title
  if$
}

FUNCTION {format.number}
{ number empty$
    { "" }
    { number " " * }  %% Text so wie er im Feld number steht plus " "
  if$
}


FUNCTION {format.type}
{ type empty$
    { "" }
    { type " " * }  %% Text wie er dasteht; Schutzrecht, Norm etc.
  if$
}

FUNCTION {format.digital.type}
{ type empty$
    { "" }
    { type #-1 #4 substring$ "mail" =
      type #1 #4 substring$ "Mail" =
      OR
        { "" }
        { type }  %% Typ einer digitalen Ressource in Form einer
              %% "Ergaenzenden Angabe", so wie er dasteht;
              %% Alternativ kann dieser Text auch in NOTE erfasst werden.
      if$
    }
 if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
        { t #1 #2 substring$ "--" = not
            { "--" *
              t #2 global.max$ substring$ 't :=
            }
            {   { t #1 #1 substring$ "-" = }
                { "-" *
                  t #2 global.max$ substring$ 't :=
                }
              while$
            }
          if$
        }
        { t #1 #1 substring$ *
          t #2 global.max$ substring$ 't :=
        }
      if$
    }
  while$
}

%%  Auflagenvermerke gibt man komplett, einschliesslich Abkuerzungen in
%%  das Feld edition ein: ---> EDITION= { 3., erw. und verb. Aufl. }
%%  oder fremdsprachlich:      EDITION= { 2nd edition }

FUNCTION {format.edition}
{ edition empty$
    { "" }
    { edition }
  if$
}

FUNCTION {format.date}
{ year duplicate$ empty$
    { "empty year in " cite$ * warning$
       pop$ "" }
     'skip$
  if$
  month empty$
     'skip$
    { type$ "book" =
      type$ "inbook" =
       OR
         'skip$
         { month " " * swap$ * }
      if$
     }
   if$
}

FUNCTION {format.edition.or.date}
{ edition empty$ year empty$ and
    { "" }
    { edition empty$
        { type empty$ NOT
            { type #-1 #4 substring$ "mail" =
              type #1 #4 substring$ "Mail" =
              OR
                { " gesendet: " "-- " type * swap$ *
                  format.date *
                }
                { "\,Version:\,"
                  format.date *
                }
              if$
             }
             { "\,Version:\,"
               format.date *
             }
           if$
        }
        { year empty$
            { "\,Version:\," edition * }
            { "\,Version:\," edition * ", " *
              format.date *
            }
          if$
        }
      if$
    }
  if$
}

FUNCTION {format.version.url}
{ url empty$ doi empty$ urn empty$ and and
   { type$ "techreport" =
       { format.edition }
       { "" }
     if$
   }
   { format.edition.or.date output format.url }
 if$
}

FUNCTION {format.edition.or.version}
{ url empty$ doi empty$ urn empty$ and and
   { format.edition }
   { format.edition.or.date }
 if$
}

FUNCTION {format.address.publisher.year}
{  publisher empty$
      { address empty$
          { year empty$
              { "" }
              { year }
            if$
          }
          { "there's an address but no publisher in " cite$ * warning$
              address ", " * format.date *
          }
        if$
      }
      { address empty$
          { year empty$
              { "neither address nor publication date in " cite$ * warning$
                 publisher
              }
              { publisher ", " * format.date * }
            if$
          }
          { year empty$
              { address " : " * publisher * }
              { address " : " * publisher * ", " * format.date * }
            if$
          }
        if$
       }
     if$
}


FUNCTION {format.address.publisher.year.alt}
{  publisher empty$
      { address empty$
          { year empty$
              { "" }
              { url empty$
                   { year }
                   { "" }
                 if$
              }
            if$
          }
          { "there's an address but no publisher in " cite$ * warning$
              address ", " * format.date *
          }
        if$
      }
      {  url empty$%%%%  wenn es URL gibt wird nur die service-provider Adresse
%%%                      ausgegeben, die im publisher-Feld steht
          { address empty$
               { year empty$
                   { "neither address nor publication date in " cite$ * warning$
                      publisher
                   }
                   { publisher ", " * format.date * }
                 if$
               }
               { year empty$
                   { address " : " * publisher * }
                   { address " : " * publisher * ", " * format.date * }
                 if$
               }
             if$
          }
          { publisher }
        if$
      }
    if$
}

FUNCTION {format.howpublished}
{ url missing$ urn missing$ doi missing$ AND AND
    { howpublished empty$
        { address empty$
            { type empty$
              { "" }
              { type #-1 #4 substring$ "mail" =
                  { "(gesendet: " new.sentence
                    format.date * ")" *
                  }
                  { "" }
                if$
               }
             if$
             format.date *
            }
            { address ", " * format.date * }
          if$
        }
        { address empty$
            { howpublished ", " * format.date * }
            { address " : " * howpublished * ", " * format.date * }
          if$
        }
      if$
    }
    { howpublished empty$
        { "" }
        { howpublished }
      if$
    }
  if$
}

FUNCTION {format.lastchecked.or.type}
{  lastchecked empty$
      { url empty$ doi empty$ urn empty$ and and
          { type empty$
             { skip$ }
             { type set.period.dash.check
               type output
             }
           if$
          }
          { type empty$
              { skip$ }
              { type #-1 #4 substring$ "mail" =
                type #1 #4 substring$ "Mail" =
                OR
                  { skip$ }
                  { type set.period.dash.check
                         type output }
                     if$
                   }
                 if$
               }
             if$
           }
       { url empty$ doi empty$ urn empty$ and and
          { "there's a lastchecked date but no url, urn or doi in "
             cite$ * warning$
          }
          { type empty$
               { "there's a URL and a lastchecked date but no type in "
                  cite$ * warning$
               }
               { type set.period.dash.check
                 type output
                 part.of.sentence
                 lastchecked "Abruf: " swap$ * output
               }
             if$
          }
        if$
       }
    if$
}


FUNCTION {format.btitle}
{ title emphasize
}

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {format.btitle.vol}
{ number empty$
   { series empty$
     { volume empty$
        { title emphasize }
        { title emphasize ". Bd." * volume tie.or.space.connect }
       if$
     }
     { volume empty$
        { title emphasize }%% ein Buch, das zusaetzl. SERIES=Reihentitel besitzt
    %% jetzt kommt d. Fall des mehrbaendigen Werkes mit Gesamttitel=SERIES
    %% Zaehlung=VOLUME und Bandtitel=TITLE;
        { series emphasize ". Bd." * volume tie.or.space.connect
                                 ": " * "{\emph{" * title * "}}" * }
       if$
     }
     if$%% series-test
   }
   { title emphasize }%% wenn number ex., dann immer title-Feld
  if$%% Ende number-test
}

FUNCTION {format.series.number.din}
{ volume empty$
    { number empty$
          { series empty$
               { "" }
               { "(" series * ")" * } %% d. Seriennr koennte auch gleich hier
                                      %% im SERIES-Feld miterfasst werden
            if$
          }
          { series empty$
               { "(" number * ")" *
                 "there's a number but no series in " cite$ * warning$
               }
               { "(" series * number tie.or.space.connect ")" * }
            if$
          }
       if$
     }
     { series empty$
          { "" }
          { type$ "proceedings" =  %% Sonderfall, es darf VOLUME und NUMBER ex. !
            type$ "inproceedings" = OR
                { number empty$
                    { "(" series * ")" * }
                    { "(" series * number tie.or.space.connect ")" * }
                  if$
                }
                { "" }%%   Ausstieg mit Nullstring, s. Kommentar
            if$
          }%% bei gezaehlten Reihen MUSS die Reihennr. im Feld NUMBER stehen!
       if$ %% wenn also d. Feld VOLUME nicht leer ist, dann liegt ausser bei
           %% Typ PROCEEDINGS falsche
      }     %% Erfassung vor und es erfolgt d. Ausstieg mit d. Nullstring!
  if$
}

FUNCTION {format.tr.series.or.number}
{    number empty$
       { series empty$
           { "" }
           { "(" series * ")" * }
         if$
       }
       { series empty$
         { "(" number * ")" * }
         { "(" series * number tie.or.space.connect ")" * }
       if$
       }
     if$
 }

FUNCTION {format.misc.series}
{ series empty$
    { "" }
    { "(" series * ")" * }
  if$
}

FUNCTION { format.doi.urn }
{ urn empty$
     { doi empty$
          { "" }
          { "DOI" doi n.dashify tie.or.space.connect }
       if$
     }
     { "URN" urn n.dashify tie.or.space.connect }
  if$
}

FUNCTION { format.isbn.issn }
{ isbn empty$
     { issn empty$
          { "" }
          { "ISSN" issn n.dashify tie.or.space.connect }
       if$
     }
     { "ISBN" isbn n.dashify tie.or.space.connect }
  if$
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { url empty$
        { "S." pages n.dashify  tie.or.space.connect }
        { pages }
      if$
    }
  if$
}

FUNCTION {format.pages.book}
{ pages empty$
    { "" }
    { note empty$ isbn empty$ AND
         { "" pages n.dashify tie.or.space.connect " S" *
           add.period$ }
         { "" pages n.dashify tie.or.space.connect " S" * }
       if$
     }
  if$
}

FUNCTION {format.pages.bkcollation}
{ pages empty$
    { "" }
    { "" pages n.dashify tie.or.space.connect }
  if$
}

FUNCTION {format.bkpages.collat.check}
{ 's :=
  #1 'ptr :=
  s text.length$ 'collation :=
   collation #1 =
    { format.pages.book }
    {
      collation 'collrest :=
       { collrest #0 > }
       { s ptr #2 substring$ 't :=
         t "S." =
           { format.pages.bkcollation
             #0 'collrest := }
           { ptr #1 + 'ptr :=
             collrest #1 - 'collrest :=
             #1 collrest =
               { format.pages.book }
               { skip$ }
             if$
           }
         if$
       }
       while$
    }
  if$
}

FUNCTION {format.vol.year.num.pages}
{ volume field.or.null
    year empty$
      { "there's no year in " cite$ * warning$ }
      { " (" year * ")" * * }
    if$
    month empty$
      'skip$
      { ", " month * * }
    if$
    number empty$
      'skip$
      { ", Nr. " number * * }
    if$
    pages empty$
        'skip$
        { duplicate$ empty$
          { pop$ "" }
          { title missing$
              { ", " pages format.bkpages.collat.check * *}
              { ", " format.pages * *}
            if$
          }
        if$
        }
     if$
}

FUNCTION {format.chapter.inbook}
{ duplicate$  empty$
    { pop$ "empty chapter in " cite$ * warning$ }
    { type empty$
         { "\emph{Kapitel\/} " swap$ tie.or.space.connect }
         { type " " * swap$ * }%%  wenn keine bes. Abschnittsform gen. werden soll,
                 %%  koennte e. kl. Zwischenraum gewaehlt werden, z.B. " \, "
       if$
     }
  if$
 }

FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.pages
    { type empty$
        { "Kapitel " }
        { url empty$
           { type }
           { "Kapitel " }
         if$
        }
      if$
      chapter tie.or.space.connect
      pages empty$
        'skip$
        { ", " * format.pages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.booktitle.din}
{ booktitle empty$
    { "" }
    { editor empty$
        { volume empty$
            { "{In: }" booktitle emphasize * }
            { "{In: }" booktitle emphasize *
              " Bd." volume tie.or.space.connect *
            }
          if$
        }
        { volume empty$
            { "{In: }" format.ed.incoll * ": " * booktitle emphasize * }
            { "{In: }" format.ed.incoll * ": " * booktitle emphasize *
              " Bd." volume tie.or.space.connect *
            }
          if$
        }
      if$
    }
  if$
}

FUNCTION {format.thesis.tr.type}
{ type empty$
    'skip$
   { pop$
     type
   }
 if$
}

FUNCTION {format.online.lastcheck}
{ lastchecked empty$
      { url empty$ doi empty$ urn empty$ and and
          { skip$ }
          { "" output }
        if$
      }
      { url empty$ doi empty$ urn empty$ and and
          { "there's a lastchecked date but no url, urn or doi in "
             cite$ * warning$
          }
          { part.of.sentence
            lastchecked "Abruf: " swap$ * output
          }
        if$
      }
    if$
}

FUNCTION {format.maillist.lastcheck}
   { type empty$ NOT
       { type #-1 #4 substring$ "mail" =
         type #1 #4 substring$ "Mail" =
         OR
           { format.online.lastcheck }
           'skip$
         if$
       }
       'skip$
     if$
   }

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
        { "need key or journal for " cite$ * " to crossref " * crossref *
          warning$
          ""
        }
        { "{In: }{\emph " journal * "}" * }
      if$
    }
    { "{In: }" key * }
  if$
  "\cite{" * crossref * "}" * ", " * format.pages *
}

FUNCTION {format.crossref.editor}
 { editor #1 "{ll}" format.name$ " (Hrsg.)" *
   editor num.names$ duplicate$
   #2 >
    { pop$ ua.etal * }%% --->u. a.
    { #2 <
        'skip$
        { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
            { ua.etal }

            { " ; " * editor #2 "{vv~}{ll}" format.name$ * " (Hrsg.)" * }
          if$
        }
      if$
    }
  if$
}

FUNCTION {format.inbk.vol.title}
{ volume empty$
     { " In: " }
     { title empty$
        { " In: Bd." volume tie.or.space.connect
                " von " *
        }
        { "In: Bd." volume tie.or.space.connect ": " * title emphasize *
                     " (" * year * ") in " *
        }
      if$
     }
   if$
 }


FUNCTION {format.book.crossref}
{ type$ "inbook" =
   { format.inbk.vol.title }
   { volume empty$
       { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
         " "
       }
       { ". -- Bd." volume tie.or.space.connect
          " von " *
       }
     if$
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
        { series empty$
            { "need editor, key, or series for " cite$ * " to crossref " *
              crossref * warning$
              "" *
            }
            { "" * }
          if$
        }
        { key * }
      if$
    }
    { "" * }
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
    editor field.or.null author field.or.null =
    or
     { key empty$
        { booktitle empty$
            { "need editor, key, or booktitle for " cite$ * " to crossref " *
              crossref * warning$
              ""
            }
            { "{In: }{\emph " booktitle * "}" * }%%
          if$
        }
        { "{In: }" }
      if$
     }
    { "{In: }" }
  if$
  "\cite{" * crossref * "}" * %% ", " * format.pages *    5.12.2005
}

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  set.colon.after
  format.title "title" output.check
  crossref missing$
    { journal article.in.journal output.nonnull
      new.sentence
      format.vol.year.num.pages output
      format.url output
    }
    { format.article.crossref output.nonnull }
  if$
  format.online.lastcheck
  doi set.period.dash.check
  urn set.period.dash.check
  format.doi.urn output
  issn set.period.dash.check
  format.isbn.issn output
  note set.period.dash.check
  note output
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors format.editors output.nonnull }
  if$
  set.colon.after
  crossref missing$
    { format.btitle.vol "title" output.check }
    { format.btitle "title" output.check }
  if$
  format.edition output
  format.address.publisher.year "publisher" output.check
  new.sentence
  crossref missing$
    { format.series.number.din output }
    { format.book.crossref output.nonnull }
  if$
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
  format.doi output
  format.url output
  new.block
  isbn set.period.dash.check
  format.isbn.issn output
  note set.period.dash.check
  note output
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors format.editors output.nonnull }
  if$
  set.colon.after
  format.btitle "title" output.check
  format.edition.or.version output
  format.url output
  format.online.lastcheck
  format.howpublished output
  series new.sentence.checka
  format.series.number.din output
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
  type set.period.dash.check
  format.digital.type output
  doi set.period.dash.check
  urn set.period.dash.check
  format.doi.urn output
  note set.period.dash.check
  note output
  format.isbn.issn output
  fin.entry
}


FUNCTION {inbook}
{ output.bibitem
    chapter format.chapter.inbook output.nonnull
      crossref missing$
      { author empty$
          { format.editors "\,{In:\,}" swap$ * "author and editor" output.check }
          { format.authors "\,{In:\,}" swap$ * output.nonnull }
        if$
        author empty$ editor empty$ AND
           { before.all 'output.state := }
           { set.colon.after }
         if$
      format.btitle.vol "title" output.check
      format.edition output
      format.address.publisher.year "publisher" output.check
      new.sentence
      format.series.number.din output
      isbn set.period.dash.check
      format.isbn.issn output
    }
    { format.book.crossref output.nonnull }
  if$
    part.of.sentence
    format.pages output
    note set.period.dash.check
    note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "author" output.check
  set.colon.after
  format.title "title" output.check
  format.version.url output
  type empty$ NOT
      { type #-1 #4 substring$ "mail" =
        type #1 #4 substring$ "Mail" =
        OR
           'skip$
           { format.online.lastcheck }
        if$
      }
      { format.online.lastcheck }
   if$
  crossref missing$
    { format.in.ed.booktitle.din "booktitle" output.check
      format.edition output
      format.address.publisher.year "publisher" output.check
      format.maillist.url output
      format.maillist.lastcheck
      new.sentence
      format.series.number.din output
      doi set.period.dash.check
      urn set.period.dash.check
      format.doi.urn output
      isbn set.period.dash.check
      issn set.period.dash.check
      format.isbn.issn output
    }
    { format.incoll.inproc.crossref output.nonnull }
  if$
  part.of.sentence
  format.chapter.pages "pages" output.check
  note set.period.dash.check
  note output
  fin.entry
}


FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check
  set.colon.after
  format.title "title" output.check
  crossref missing$
    { format.in.ed.booktitle.din "booktitle" output.check
      address empty$
        { organization new.sentence.checka
          organization output
          part.of.sentence
          format.address.publisher.year output
        }
        { format.address.publisher.year "publisher" output.check }
      if$
      new.sentence
      series empty$
        'skip$
        { format.series.number.din output }
      if$
      isbn set.period.dash.check
      issn set.period.dash.check
      format.isbn.issn output
    }
    { format.incoll.inproc.crossref output.nonnull }
  if$
  part.of.sentence
  format.pages "pages" output.check
  note set.period.dash.check
  note output
  fin.entry
}


FUNCTION {conference} { inproceedings }%% nach Patashnik, wg US-Kompatibilitaet

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
        { title empty$
            'skip$
            {format.btitle "title" output.check }
          if$
        }
        'skip$
      if$
    }
    'skip$
  if$
  format.authors.organization output.nonnull
  set.colon.after
  format.btitle "title" output.check
  format.edition "edition" output.check
  author empty$ organization empty$ AND
    {   address "address" output.check
        part.of.sentence
    }
    { organization empty$
        { address "address" output.check
          part.of.sentence
        }
        { address ": " * organization * output
          part.of.sentence
        }
      if$
    }
  if$
  format.date output
  number empty$
    'skip$
   { "(" number * ") " * output }
  if$
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
  format.doi output
  format.url output
  format.online.lastcheck
  note set.period.dash.check
  note output
  fin.entry
}

%%  Standard ist "Diplomarbeit", anderes mit TYPE="anderer Typ" erfassen!
%%  z.B. TYPE={Hausarbeit}, TYPE={Diss.}, TYPE={Habil.}, TYPE={Magisterarb.}
FUNCTION {mastersthesis}
{ output.bibitem
  format.authors "author" output.check
  set.colon.after
  format.btitle "title" output.check
  address output
  part.of.sentence
  school "school" output.check
  part.of.sentence
  "Diplomarbeit" format.thesis.tr.type output.nonnull
  part.of.sentence
  format.date "year" output.check
  format.url output
  format.online.lastcheck
%%  format.digital.resource.type
  doi set.period.dash.check
  urn set.period.dash.check
  format.doi.urn output
%%  pages set.period.dash.check
%%  format.pages.book output
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
  note set.period.dash.check
  note output
  fin.entry
}

FUNCTION {phdthesis} %%  {mastersthesis}% ist identisch bis auf Standardwert, s.o.
{ output.bibitem
  format.authors "author" output.check
  set.colon.after
  format.btitle "title" output.check
  address output
  part.of.sentence
  school "school" output.check
  part.of.sentence
  "Diss." format.thesis.tr.type output.nonnull % koennte auch `Dissertation' sein
  part.of.sentence
  format.date "year" output.check
  format.url output
  format.online.lastcheck
%%  format.digital.resource.type
  doi set.period.dash.check
  urn set.period.dash.check
  format.doi.urn output
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
%%  pages set.period.dash.check
%%  format.pages.book output
  note set.period.dash.check
  note output
  fin.entry
}


%% Normen, Vornormen, Schutzrechte (Patente) werden hiermit erfasst;
%% (z.Zt. auch noch Internetressourcen)
%% das type-Feld uebernimmt eine wichtige Steuerfunktion:
FUNCTION {misc}
{ output.bibitem
   type missing$ not
       { type duplicate$ #1 #4 substring$ "Norm" =
           type #1 #4 substring$ "Vorn" = OR
           { " " *
             format.number * output
             new.sentence
             format.date output
             title empty$
               { skip$ }
               { add.period$ new.sentence }
             if$
             format.btitle "title" output.check
             note set.period.dash.check
             note output
           }
           { duplicate$ #1 #6 substring$ "Schutz" =
                { " " * format.number * output
                  new.sentence
                  "(" * format.date ")" * output
                  add.period$ new.sentence
                  format.authors.organization add.period$ output
                  note output
                }
            %%  wenn irgendein anderer Typ eingetragen ist
                { pop$ pop$ ""
                  title empty$
                     { note empty$
                         { url empty$
                             { "there's no relevant field in " cite$ warning$
                                pop$ ""
                             }
                             { format.url output }%%%
                           if$
                         }
                         { note " " * output.nonnull }
                       if$
                     }
                     { author empty$
                          { editor empty$
                               { organization empty$
                                   { skip$ }
                                   { format.editors.organization output.nonnull
                                     set.colon.after
                                   }
                                 if$
                               }
                               { format.editors format.editors.organization
                                 output.nonnull set.colon.after
                               }
                             if$
                          }
                          { format.authors format.editors output.nonnull
                            set.colon.after
                          }
                        if$
                 format.btitle output.nonnull
                 url empty$
                   { format.edition output
                     format.howpublished output}
                   { format.howpublished output
                     format.edition.or.date output
                     format.url output
                   }
                 if$
                 format.online.lastcheck
%%                 format.lastchecked.or.type
                 new.sentence
                 format.misc.series output
%%                 note set.period.dash.check
                 note output
                }
              if$
            }
         if$
          }
        if$
       }
       %% wenn es keinen type gibt
       { title empty$
             { note empty$
                 { url empty$
                     { "there's no relevant field in " cite$ warning$
                       pop$ ""
                     }
                     { format.url output }%%%  das waere e. reine URL
                   if$
                 }
                 { note " " * output.nonnull
                 %%  format.url format.date output
                 }
               if$
             }
             { author empty$
                   { editor empty$
                        { organization empty$
                             { skip$ }
                             { format.editors.organization output.nonnull
                               set.colon.after
                             }
                           if$
                        }
                        { format.editors format.editors.organization
                          output.nonnull set.colon.after
                        }
                      if$
                   }
                   { format.authors format.editors output.nonnull
                     set.colon.after
                   }
                 if$
              format.btitle output.nonnull
              url empty$
                { format.edition output
                  format.howpublished output}
                { format.howpublished output
                  format.url output
                  format.edition.or.date output
                  format.online.lastcheck
%%                  format.lastchecked.or.type
                }
              if$
              new.sentence
              format.misc.series output
              note set.period.dash.check
              note output
          }
        if$
      }
    if$
 fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
    editor empty$
      { organization empty$
           { "empty organization and editor in " cite$ * warning$ }
           { organization " (Veranst.)" * output }
        if$
      }
      { format.editors format.editors.organization output.nonnull }
    if$
  set.colon.after
  format.btitle "title" output.check
  volume empty$
    { skip$ }
    { "{\textnormal{Bd.}}" volume tie.or.space.connect emphasize "volume" output.check }
  if$
  format.address.publisher.year "publisher" output.check
  new.sentence
  format.series.number.din output.nonnull
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
  isbn set.period.dash.check
  issn set.period.dash.check
  format.isbn.issn output
  note set.period.dash.check
  note output
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check
      format.tr.institution output.nonnull }
    { format.authors  format.editors output.nonnull }
  if$
  set.colon.after
  format.title "title" output.check
  institution empty$
     'skip$
    { author empty$ editor empty$ AND
          'skip$
        { institution new.sentence.checka
          "/ " institution *  output.nonnull
        }
      if$
    }
  if$
  format.version.url output
  format.online.lastcheck
  format.address.publisher.year output
  number new.sentence.checka
  format.tr.series.or.number "number" output.check
  "Forschungsbericht" format.thesis.tr.type set.period.dash.check
  "Forschungsbericht" format.thesis.tr.type output
%%  format.digital.resource.type
  pages empty$
    { skip$ }
    { pages set.period.dash.check
      pages format.bkpages.collat.check output
    }
  if$
  isbn set.period.dash.check
  issn set.period.dash.check
  format.isbn.issn output
  note set.period.dash.check
  note "note" output.check
  fin.entry
}

FUNCTION {unpublished} {misc}%%       AUTHOR, TITLE, NOTE muessen sein!
%%                                    andere Felder sind optional

FUNCTION {default.type} { misc }


MACRO {jan} {"Januar"}

MACRO {feb} {"Februar"}

MACRO {mar} {"M{\^^b a}rz"}

MACRO {apr} {"April"}

MACRO {mai} {"Mai"}

MACRO {may} {"Mai"}

MACRO {jun} {"Juni"}

MACRO {jul} {"Juli"}

MACRO {aug} {"August"}

MACRO {sep} {"September"}

MACRO {okt} {"Oktober"}

MACRO {oct} {"Oktober"}

MACRO {nov} {"November"}

MACRO {dez} {"Dezember"}

MACRO {dec} {"Dezember"}

%%$$$  stillgelegte Beispiele fuer den Gebrauch von Kuerzeln (hier Zs-Titel).

%%MACRO {acmcs} {"ACM Computing Surveys"}

%%MACRO {acta} {"Acta Informatica"}

READ

FUNCTION {initialize.longest.label}%% nicht identisch mit der Fkt.im ALPHA-Stil
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
     { label  'longest.label :=
       label width$ 'longest.label.width :=
     }
       'skip$
  if$
}

EXECUTE { initialize.longest.label }

ITERATE { longest.label.pass }

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{" number.label int.to.str$ * "}" *
  write$ newline$ newline$
  "% this bibliography is generated by unsrtdin.bst [8.2] from 2005-12-21"
  write$ newline$ newline$
  "\providecommand{\url}[1]{\texttt{#1}}"
  write$ newline$
  "\expandafter\ifx\csname urlstyle\endcsname\relax"
  write$ newline$
  "  \providecommand{\doi}[1]{doi: #1}\else"
  write$ newline$
  "  \providecommand{\doi}{doi: \begingroup \urlstyle{rm}\Url}\fi"
  write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}