blob: c9ae25772a4dfcdd44c75c9745eac7025db4b7f4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
dnl Process this file with autoconf to produce a configure script.
dnl
dnl Copyright (C) 2009-2013 Peter Breitenlohner <tex-live@tug.org>
dnl
dnl This file is free software; the copyright holder
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl
m4_include([version.ac])[] dnl define icu_version
AC_INIT([icu for TeX Live], icu_version, [tex-k@tug.org])
AC_PREREQ([2.65])
AC_CONFIG_SRCDIR([icu-]icu_version[/common/unicode/utypes.h])
AC_CONFIG_AUX_DIR([../../build-aux])
AC_CONFIG_MACRO_DIR([../../m4])
KPSE_BASIC([icu])
KPSE_CANONICAL_HOST
AM_CONDITIONAL([build], [test "x$enable_build" != xno])
AM_CONDITIONAL([cross], [test "x$cross_compiling" = xyes])
AC_PROG_LN_S
ICU_TREE=[icu-]icu_version
AC_SUBST([ICU_TREE])
# Prepare configure arguments for ICU.
# Can not share the cache file for various reasons.
icu_config="'\${abs_srcdir}'/$ICU_TREE/configure --enable-static --disable-shared"
icu_config="$icu_config --disable-extras --disable-samples --disable-tests"
if test "x$cache_file" != x/dev/null; then
icu_config="$icu_config -C"
fi
# Add '--disable-strict': required for MinGW32, otherwise reduce warnings.
# Add '--disable-dyload': neither XeTeX nor BibTeXU use plugins, new in ICU 4.4.
icu_config="$icu_config --disable-strict --disable-dyload --disable-layout"
AC_SUBST([icu_config])
if test "x$cross_compiling" = xyes; then
icu_native_args="--build=$build_alias --host=$build_alias --disable-icuio"
icu_build_args="--build=$build_alias --host=$host_alias --with-cross-build='\${abs_builddir}'/icu-native"
else
icu_build_args="--build=$kpse_build_alias"
icu_native_args=
fi
eval "set x $ac_configure_args"
shift
for icu_arg
do
case $icu_arg in
BUILD*=*) icu_arg=`echo "$icu_arg" | sed 's/^BUILD//'`; icu_list=native ;;
*) icu_list=build ;;
esac
case $icu_arg in
CC=* | CFLAGS=* | CPPFLAGS=* | CXX=* | CXXFLAGS=* | LDFLAGS=*) ;;
*) continue ;;
esac
case $icu_arg in
*\'*) icu_arg=`echo "$icu_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
esac
eval icu_${icu_list}_args="\"\$icu_${icu_list}_args '\$icu_arg'\""
done
AC_SUBST([icu_build_args])
AC_SUBST([icu_native_args])
AC_CONFIG_FILES([Makefile include/Makefile include/unicode/Makefile include/layout/Makefile])
AC_OUTPUT
|
