1 files changed, 691 insertions, 0 deletions

diff --git a/Master/texmf-dist/fonts/source/public/montex/mcyitall.mf b/Master/texmf-dist/fonts/source/public/montex/mcyitall.mf
new file mode 100644
index 00000000000..a181475fd3c
--- /dev/null
+++ b/Master/texmf-dist/fonts/source/public/montex/mcyitall.mf
@@ -0,0 +1,691 @@
+%        File: mcyitall.mf
+%    Based on: cyitall.mf
+% Modified by: Oliver Corff
+%        Date: October 1997, Ulaanbaatar
+%
+% Computer Modern Cyrillic Italic lower case:
+
+cmchar "Cyrillic italic letter a";
+beginchar(cyra,9u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
+pos4(stem,0); x4=x0; y4+.5stem=vround .98h;
+x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
+rt x4r=hround(w-2.5u+.5stem);
+top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
+filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
+ & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
+x5=x4; x7=w; hook_out(5,6,7);  % closing hook
+filldraw circ_stroke z4e--z5e;  % stem
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6,7); endchar;
+
+cmchar "Cyrillic italic letter be";
+beginchar(cyrb,9u#,asc_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
+x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
+top y1r=x_height+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
+filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
+pos2'(hair,180); z2'r=z2r; pos5(vstem,90); pos5'(vstem,-90); z5'=z5;
+pos6(hair,0); rt x6r=hround(w-u); top y6=h; top y5r=vround .9h; x5=x1;
+filldraw stroke pulled_arc.e(6,5'); filldraw stroke pulled_arc.e(5,2');
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
+
+cmchar "Cyrillic italic letter ve";
+beginchar(cyrv,9u#,x_height#,0);
+italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric heavy_hair; heavy_hair=hround .2[hair,stem];
+pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
+pos3(curve,180); pos4(vair,270); pos5(curve,0); pos6(vair,180);
+x0=rt x3l; rt x1r=hround(w-2.5u+.5heavy_hair); x2=x4=.5w;
+lft x3r=hround(1.5u-.5curve); x5r=good.x(w-u-eps); x6=x2;
+y0=y3=y6-.1u=bar_height; y1=.5[y0,y2];
+top y2r=h+oo; bot y4r=-oo; y5=vround .5bar_height;
+filldraw stroke z0e{right}...z1e{up}
+ ...pulled_arc.e(2,3) & pulled_arc.e(3,4) &
+ {{surerness:=hein_super; pulled_arc.e(4,5) & pulled_arc.e(5,6)}};
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Cyrillic italic letter ghe";
+beginchar(cyrg,8u#,x_height#,0);
+italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos2(hair,140); pos3(vair,90); pos4(curve,0);
+pos5(vair,-90); pos5'(vair,90); pos6(curve,180);
+pos7(vair,270); pos8(hair,320);
+x7=w-x3=.5(w+u); x5=.52w; y5=.52h; z5'=z5;
+lft x6r=w-rt x4r-.5u=hround(1.5u-.5curve); x8r=w-x2=good.x(w-eps);
+x9=x8; x1=x2; top y3=h+oo; y4=.5[y5,y3]; bot y7r=-oo; y6=.5[y5,y7];
+top y8l=h-bot y2l=vround .5bar_height; y9=h-y1=bar_height;
+path p[]; p1=z3{left}..z2..z1; p2=z7{right}..z8..z9;
+filldraw stroke pulled_arc.e(5,4)
+ & pulled_arc.e(4,3)...{direction 1 of p1}z2e;
+filldraw stroke pulled_arc.e(5',6)
+ & pulled_arc.e(6,7)...{direction 1 of p2}z8e;  % arc
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Cyrillic italic letter de";
+beginchar(cyrd,9u#,asc_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,150); pos2(vair,90); pos3(curve,0);
+pos4(vair,270); pos5(curve,180); pos6(vair,90);
+x1=x5l; x2=.5w-u; y1=h-.25u; top y2r=h+o; y3=.5[y2,y4];
+x6=x4=.5w; lft x5r=w-rt x3r=hround(1.5u-.5curve);
+top y6r=x_height+oo; y5=.5[y6,y4]; bot y4r=-oo;
+path p; p=pulled_super_arc.l(3,4)(superpull);
+numeric t; t=xpart(p intersectiontimes((x4,y5)--(x3r,y5)));
+pos7(thin_join,0); z7l=point t of p;
+filldraw stroke z1e...pulled_super_arc.e(2,3)(superpull)
+ & {{interim superness:=more_super; pulled_super_arc.e(3,4)(superpull)}}
+ & {{less_tense; pulled_super_arc.e(4,5)(superpull)}}
+ & pulled_super_arc.e(5,6)(superpull)
+ & z6e{right}...{direction t of p}z7e; % arc and bowl
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(1,2,3,4,5,6,7); endchar;
+
+cmchar "Cyrillic italic letter ie";
+beginchar(cyre,8u#,x_height#,0);
+italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric heavy_hair; heavy_hair=hround .2[hair,stem];
+pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
+pos3(curve,180); pos4(vair,270); pos5(hair,320);
+x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
+lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
+y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
+top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
+filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
+ & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Cyrillic italic letter ye";
+numeric dot_diam#,dot_diam;
+beginchar(cyryo,8u#,1.4x_height#,0);
+dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
+italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
+adjust_fit(0,0); pickup fine.nib;
+numeric heavy_hair,letter_h; letter_h=x_height; heavy_hair=hround .2[hair,stem];
+pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
+pos3(curve,180); pos4(vair,270); pos5(hair,320);
+x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
+lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
+y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=letter_h+oo; bot y4r=-oo;
+top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
+filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
+ & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+pos7(dot_diam,0); pos8(dot_diam,90);
+x7=x8=2.5u; top y8r=h+1;
+if bot y8l<letter_h+o+slab: y8l:=min(y8r-eps,letter_h+o+slab+.5tiny); fi
+y7=.5[y8l,y8r]; dot(7,8);  % left dot
+pos9(dot_diam,0); penpos10(y8r-y8l,90); y9=y10=y7; x9=x10=w-x7;
+dot(9,10);  % right dot
+penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
+
+
+cmchar "Cyrillic italic letter zhe";
+beginchar(cyrzh,17u#,x_height#,0);
+italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
+adjust_fit(0,0); pickup fine.nib;
+numeric arc_width; arc_width=7u;
+pos0(flare,180); pos1(hair,180); pos2(vair,-90);
+pos3(curve,0); pos4(vair,90); pos5(hair,140);
+pos7(flare,0); pos8(hair,0); pos9(vair,90);
+pos10(curve,180); pos11(vair,270); pos12(hair,320);
+x2=x4=w-x9=.5(arc_width-u); x11=x9;
+lft x1r=w-rt x8r=min(lft x2,hround u)-eps;
+rt x3r=w-lft x10r=hround(arc_width-1.5u+.5curve);
+x5r=w-x12r=good.x(eps); x6=x5; x13=x12;
+y8=h-y1=.5[bar_height,h]; bot y2r=-oo; top y9r=h+oo;
+top y4r=h+oo; bot y11r=-oo; y3=h-y10=.5[y2,y4];
+bot y5l=h-top y12l=vround h-.5bar_height; y13=h-y6=bar_height;
+path p[]; p1=z4{left}..z5..z6; p2=z11{right}..z12..z13;
+filldraw stroke pulled_arc.e(2,3)
+ & pulled_arc.e(3,4)...{direction 1 of p1}z5e;  % left arc
+filldraw stroke pulled_arc.e(9,10)
+ & pulled_arc.e(10,11)...{direction 1 of p2}z12e;  % right arc
+bulb(2,1,0); bulb(9,8,7);  % left and right bulb
+pos14(stem,0); pos15(stem,0); x14=x15=.5w; top y14=h; bot y15=0;
+filldraw stroke z14e--z15e;   % stem
+penpos3'(bar,90); penpos10'(bar,90); z3'=z3; z10'=z10;
+fill stroke z3'e--z10'e;  % bar
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15); endchar;
+
+cmchar "Cyrillic italic letter ze";
+beginchar(cyrz,8u#,x_height#,0);
+italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos1(hair,140); pos2(cap_band,90); pos4(vair,-90);
+x1r=good.x(eps); x0=x1; top y2r=h+o;
+bot y1l=vround h-.5bar_height; y0=h-bar_height;
+pos3(max(fine.breadth,curve-stem_corr),0);
+pos7(vair,-90); pos8(vair,-90); pos9(vair,90);
+x2=.45[2u,x10]; rt x3r=hround(w-u); x4=.45[x1,x10];
+pos10(curve,0); rt x10r=hround(w-.5u); lft x8=.5w-u;
+y3=.35[top y7l,bot y2l]; top y8l=vround(.54h+.5vair); z8r=z9l;
+x7=1/3[x8,x3l]; z7=z8+whatever*(150u,h);
+pos5'(hair,-180); pos5(flare,-180);
+bot y4r=0; rt x5l=hround 2u; z5r=z5'r;
+y10=.45[bot y8r,top y4l]; y5=max(good.y .95(h-y1),y4l+eps);
+(x2l',y2l)=whatever[z2r,z1l]; x2l:=max(x2l',x2l-.5u);
+(x4l',y4l)=whatever[z4r,z5l]; x4l:=max(x4l',x4l-.5u);
+path p; p=z0..z1..{right}z2;
+filldraw stroke z1e{direction 1 of p}
+  ...pulled_arc.e(2,3)
+ & z3e{down}...z7e---z8e;  % upper bowl
+filldraw stroke z9e---pulled_arc.e(9,10)
+ & pulled_super_arc.e(10,4)(.5superpull);  % lower bowl
+bulb(4,5',5);   %bulb
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,7,8,9,10,11,12,13); endchar;
+
+cmchar "Cyrillic italic letter i";
+beginchar(cyri,9.5u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e;  % right stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Cyrillic italic letter short i";
+beginchar(cyrishrt,9.5u#,x_height#+3.5u#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57x_height; y6+.5stem=x_height;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e;  % right stem
+penpos10(hair-fine,-90); penpos11(hair-fine,-180); penpos12(.5flare,-180);
+penpos13(hair-fine,-90); penpos14(hair-fine,0);  penpos15(.5flare,0);
+x10=.5[x11,x14]; x11=.5w-2u; x14=w-x11;
+y10=y13=x_height+u; y11=y14=h-.5u; z13=z10;
+bulb(10,11,12); bulb(13,14,15);  % bulbs
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
+
+cmchar "Cyrillic italic letter ka";
+beginchar(cyrk,9.5u#,x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
+hook_in(0,a,1);  % opening hook
+filldraw circ_stroke z2e--z1e;  % left stem
+pos3(vair,90); x3=x1; y3=bar_height;
+pos4(vair,90); x4=w-2u; top y4r=x_height+oo;
+filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
+pos5(hair,0); pos6(flare,0);
+rt x5r=hround(w-.5u); y5+.5flare=vround(bot y4l-.03x_height);
+bulb(4,5,6);  % bulb
+pos7(stem,0); pos8(vair,90); pos9(hair,180);
+x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
+lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
+filldraw stroke z3e{right}...z7e{down}
+ ...z8e{right}...{up}z9e;  % lower diagonal
+math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Cyrillic italic letter el";
+beginchar(cyrl,9u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib;
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x6=x7; x9=w; hook_out(7,8,9);  % closing hook
+top y6=top y0=h; x0=lft x6r;
+filldraw stroke z6e--z7e;  % right stem
+pickup tiny.nib; pos0(hair,-90); pos1(hair,0); pos2(hair,0);
+y1=.5h; rt x1r=hround(w-5.25u); x2=x1; y2=.21h;
+pos3(vair,-90); pos4(hair,-180); pos5(flare,-180);
+bot y3r=0; x3=.5[x4,x2]; y5=.25h; rt x5l=hround 2u; z5r=z4r;
+filldraw stroke pulled_arc.e(0,1) & z1e--z2e & super_arc.e(2,3);  % arc
+bulb(3,4,5);  % bulb
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Cyrillic italic letter em";
+beginchar(cyrm,12u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib;
+numeric stem[]; % thicknesses of the four strokes
+stem1=hround(fudged.stem-4stem_corr);
+stem2=hround(fudged.hair-stem_corr);
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem); top y6=h;
+x6=x7; x9=w; hook_out(7,8,9);  % closing hook
+filldraw stroke z6e--z7e;  % right stem
+pickup tiny.nib; pos1(hair,0); pos2(hair,0);
+top y1=h; rt x1r=hround(w-8.25u); x2=x1; y2=.21h;
+pos3(vair,-90); pos4(hair,-180); pos5(flare,-180);
+bot y3r=0; x3=.5[x4,x2]; y5=.25h; rt x5l=hround 2u; z5r=z4r;
+filldraw stroke z1e--z2e & super_arc.e(2,3);  % left stem and arc
+bulb(3,4,5);  % bulb
+penpos10(stem1,0); penpos11(stem1,0); penpos12(stem2,0); penpos13(stem2,0);
+x10l=x1; x11l=x12l; x13=lft x6l; x11-x10=x13-x12; y10=y13=h; y11=y12;
+y11=0; z0=whatever[z10r,z11r]=whatever[z12l,z13l];
+fill z10l..{z11-z10}diag_in(10l,11l,1,11r)
+ ..diag_out(12l,1,12r,13r){z13-z12}
+ ..z13r--diag_out(13r,1,13l,12l){z12-z13}..{z12-z13}z0{z10-z11}
+ ..{z10-z11}diag_in(11r,10r,1,10l)--cycle;   % diagonals
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
+
+cmchar "Cyrillic italic letter en";
+beginchar(cyrn,9.5u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
+hook_in(0,a,1);  % opening hook
+filldraw circ_stroke z2e--z1e;  % left stem
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem); y6+.5stem=h;
+x6=x7; x9=w; hook_out(7,8,9);  % closing hook
+filldraw circ_stroke z6e--z7e;  % right stem
+penpos10(bar,90); penpos11(bar,90); x10=x1; x11=x6; y10=y11=.5h;
+fill stroke z10e--z11e;  % bar
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
+
+cmchar "Cyrillic italic letter o";
+beginchar(cyro,9u#,x_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
+x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
+top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
+filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
+ & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
+
+cmchar "Cyrillic italic letter pe";
+beginchar(cyrp,10u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
+hook_in(0,a,1);  % opening hook
+filldraw circ_stroke z2e--z1e;  % left stem
+x4+.5stem=hround(w-2.5u+.5stem); x5=x4-.25u; ital_arch(2,3,4);  % arch
+x7=w; hook_out(5,6,7)(skewed);  % closing hook
+filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,a,1,2,3,4,5,6,7); endchar;
+
+cmchar "Cyrillic italic letter er";
+beginchar(cyrr,9u#,x_height#,desc_depth#);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);  % opening hook
+pos4(hair,-180); pos5(vair,-90); pos6(curve,0); pos7(vair,90);
+x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
+bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
+filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
+ & pulled_arc.e(6,7) & super_arc.e(7,4);  % bowl
+pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
+z2=z2'; x3=x2; bot y3=-d; filldraw stroke z2'e--z3e;  % stem
+dish_serif(3,2',a,1/3,.75jut,b,1/3,jut);  % serif
+math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
+ 2u#-.5stem#-desc_depth#*slant),ic#);
+penlabels(0,1,2,3,4,5,6,7); endchar;
+
+cmchar "Cyrillic italic letter es";
+beginchar(cyrs,8u#,x_height#,0);
+italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(curve,180); pos4(vair,270); pos5(hair,320);
+x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
+lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
+y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
+bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
+path p; p=z4{right}..z5..z6;
+filldraw stroke pulled_arc.e(2,3)
+ & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Cyrillic italic letter te";
+beginchar(cyrt,15u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
+numeric shaved_stem; shaved_stem=mfudged.stem;
+save stem; stem=shaved_stem;
+pos2(stem,0); x1=x2;
+if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
+else: x0=0; lft x2l=hround(2.5u-.5stem);
+ hook_in(0,a,1); fi  % opening hook
+y2-.5stem=-oo; filldraw circ_stroke z2e--z1e;  % left stem
+x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
+pos5(stem,0); y5=y2; x5=x4;
+filldraw circ_stroke z5e--z4e;  % middle stem
+x7+.5stem=hround(w-2.5u+.5stem);
+x8=x7-.25u; ital_arch(5,6,7);  % right arch
+if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
+ pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
+else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
+filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Cyrillic italic letter ef";
+beginchar(cyrf,12u#,asc_height#,desc_depth#);
+italcorr asc_height#*slant+.75u#;
+adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
+numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
+pos0(flare,0); pos1(hair,0); pos2(vair,90);
+pos3(.5[hair,stem],180); pos4(stem,theta+90);
+pos5(stem,theta-90); pos6(.5[hair,stem],0);
+pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
+rt x1r=hround(w-2u); lft x8r=hround 2u; x2=.6[x1,x4]; x7=.6[x8,x5];
+y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
+y4=.15[x_height,h]; y5=.4[-d,y4];
+z4=whatever[z88,z89]; z5=whatever[z88,z89];
+x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
+bulb(2,1,0); bulb(7,8,9);  % bulbs
+filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
+filldraw z4r--z5l--z5r--z4l--cycle;  % stem
+filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
+penpos10(hair,180); penpos11(vair,90); penpos12(curve,0);
+penpos13(vair,-90); penpos14(hair,0); penpos15(vair,90);
+penpos16(curve,180); penpos17(vair,270);
+x10=x14=.5w; y11r=y15r=x_height+o; y12=y16=.5[y11l,y13l]; y13r=y17r=-o;
+y10=y14=.5x_height; x11r=x13r=w-x15r=w-x17r=.5w+1.75u;
+x12r=w-x16r=hround(w-.5u);
+fill stroke super_arc.e(10,11) & pulled_arc.e(11,12)
+ & pulled_arc.e(12,13) & super_arc.e(13,10);
+fill stroke super_arc.e(14,15) & pulled_arc.e(15,16)
+ & pulled_arc.e(16,17) & super_arc.e(17,14);
+math_fit(desc_depth#*slant+u#,x_height#*slant);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,88,89); endchar;
+
+cmchar "Cyrillic italic letter u";
+beginchar(cyru,8.5u#,x_height#,desc_depth#);
+italcorr x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-1.5u+.5stem);
+pos7(stem,0); pos8(vair,-90);
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
+y7=0; bot y8r=-d-oo; x5=x6=x7; x8=.5w;
+pos9(hair,-180); pos10(flare,-180); y9=-.5d;
+lft x9r=hround(2.75u-.5flare); bulb(8,9,10);  % bulb
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e---z7e...{left}z8e;  % right stem and link
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
+penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
+
+cmchar "Cyrillic italic letter xa";
+beginchar(cyrh,6.5u#+max(1.5u#,flare#),x_height#,0);
+italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant+.25u#);
+adjust_fit(0,0); pickup fine.nib;
+pos0(hair,180); pos1(vair,90); pos2(stem,0);
+pos3(stem,-180); pos4(vair,-90); pos5(hair,0);
+y0=y2=2/3h; y3=y5=1/3h; top y1r=h+oo; bot y4r=-oo;
+rt x2r=hround(.5w+.5stem-eps); x2=x3;
+x0-.5hair=hround-.5hair; x5+.5hair=hround(w+.5hair-eps);
+x1=.5[x0,x2]; x4=.5[x3,x5];
+filldraw stroke z0e{up}...pulled_arc.e(1,2); % opening hook
+filldraw z2l--z3r--z3l--z2r--cycle;  % stem
+filldraw stroke pulled_arc.e(3,4)...{up}z5e;  % closing hook
+pos3'(hair,180); pos6(hair,180); pos7(vair,90);
+pos8(hair,0); pos9(flare,0);
+x3'l=x6l=x3l; y3'=y3; y6=3/4h; x7=.5[x8,x2]; top y7r=h+oo;
+rt x8r=hround(w-.25u); y8+.5flare=vround(bot y7l-.03x_height);
+filldraw stroke z3'e---z6e...{right}z7e; bulb(7,8,9);  % upper link and bulb
+pos2'(hair,0); pos16(hair,0); pos17(vair,-90);
+pos18(hair,-180); pos19(flare,-180);
+x2'l=x16l=x2l; y2'=y2; y16=1/4h; x17=.5[x18,x3]; bot y17r=-oo;
+lft x18r=hround.25u; y18-.5flare=vround(top y17l+.03x_height);
+filldraw stroke z2'e---z16e...{left}z17e; bulb(17,18,19); % lower link and bulb
+math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,16,17,18,19); endchar;
+
+cmchar "Cyrillic italic letter tse";
+beginchar(cyrc,9.5u#,x_height#,desc_depth#-u#);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=w;
+pos7(stem,0); pos8(vair,90);
+x9:=hround(x9+.5hair-eps)-.5hair; pos9(hair,180);
+y7=1/4x_height; bot y8l=-oo; y9=1/3x_height; x8=x7+1.5u;
+path p,p.l,p.r;
+forsuffixes $=r,l: p.$=z7${down}...z8${right}
+  ...{x9-(x7+2.5u),x_height}z9$; endfor;
+p=p.r--reverse p.l--cycle;
+filldraw p;  %   closing hook;
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e;  % right stem
+pos10(stem,-140); pos11(stem,-150);
+x11r=x10; x10r=.9[x7,x8]; x12=x8;
+y11=.5[y12,y10]; y10=-.25d; bot y12=-d;
+filldraw stroke (subpath (1.5,3.5) of p)..z10e..z11e..z12;
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12); endchar;
+
+cmchar "Cyrillic italic letter che";
+beginchar(cyrch,9.5u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.2u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
+y3=.7[y4,y5]; bot y4r=.325h; y5=.7h; y6+.5stem=h;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e;  % right stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Cyrillic italic letter sha";
+beginchar(cyrsh,14.5u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); pos6(stem,-180); pos7(stem,-180);
+pos8(vair,-90); pos9(hair,0); pos10(stem,0);
+x4=.5[x3,x5]; x6=.5w; x8=.5[x5,x9]; rt x10r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=x10=x11; x13=w; hook_out(11,12,13);  % closing hook
+y3=.7[y4,y5]; bot y4r=bot y8r=-oo; y5=y9=.57h; y7=y11;
+y6+.5stem=h; y10=y6;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e
+ ...super_arc.e(7,8)...{up}z9e; % middle stem and arc
+filldraw circ_stroke z10e--z11e;  % right stem
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
+
+cmchar "Cyrillic italic letter shcha";
+beginchar(cyrshch,14.5u#,x_height#,desc_depth#-u#);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed);  % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); pos6(stem,-180); pos7(stem,-180);
+pos8(vair,-90); pos9(hair,0); pos10(stem,0);
+x4=.5[x3,x5]; x6=.5w; x8=.5[x5,x9]; rt x10r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=x10=x11; x13=w;
+pos11(stem,0); pos12(vair,90);
+x13:=hround(x13+.5hair-eps)-.5hair; pos13(hair,180);
+y11=1/4x_height; bot y12l=-oo; y13=1/3x_height; x12=x11+1.5u;
+path p,p.l,p.r;
+forsuffixes $=r,l: p.$=z11${down}...z12${right}
+  ...{x13-(x11+2.5u),x_height}z13$; endfor;
+p=p.r--reverse p.l--cycle;
+filldraw p;  %   closing hook;
+y3=.7[y4,y5]; bot y4r=bot y8r=-oo; y5=y9=.57h; y7=y11;
+y6+.5stem=h; y10=y6;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e
+ ...super_arc.e(7,8)...{up}z9e; % middle stem and arc
+filldraw circ_stroke z10e--z11e;  % right stem
+pos14(stem,-140); pos15(stem,-150);
+x15r=x14; x14r=.9[x11,x12]; x16=x12;
+y15=.5[y16,y14]; y14=-.25d; bot y16=-d;
+filldraw stroke (subpath (1.5,3.5) of p)..z14e..z15e..z16;
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16); endchar;
+
+cmchar "Cyrillic italic letter soft_sign";
+beginchar(cyrsftsn,8u#,x_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup tiny.nib;
+numeric x_bowl; x_bowl=2/3h;
+pos1(stem,0); pos2(stem,0); x1=x2;
+lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_bowl;
+filldraw stroke z1e--z2e;  % stem
+sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
+pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
+pos4(curve,0); pos5(vair,90); pos0(hair,180);
+z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(8u-1.5u+.5curve);
+bot y3r=-oo; top y5r=x_bowl+oo; y4=y2;
+filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
+ & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5); endchar;
+
+cmchar "Cyrillic italic letter hard_sign";
+beginchar(cyrhrdsn,12u#,x_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup tiny.nib;
+numeric x_bowl; x_bowl=.52h;
+pos1(vair,0); pos2(stem,0); x1=x2;
+lft x1l=hround(5.5u-.5stem); top y1=h+oo; y2=.5x_bowl;
+filldraw stroke z1e--z2e;  % stem
+pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
+pos4(curve,0); pos5(vair,90); pos0(hair,180);
+z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
+bot y3r=-oo; top y5r=x_bowl+oo; y4=y2;
+filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
+ & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
+pos1'(vair,0); pos6(vstem,-90); pos6'(vstem,90); pos7(vair,180);
+z1'=z1; x6=.5[x7,x1]; top y6l=h+oo; z6'=z6; lft x7r=0; y7=h-1.75u;
+filldraw stroke pulled_arc.e(1',6);
+filldraw stroke pulled_arc.e(6',7);
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6,7); endchar;
+
+cmchar "Cyrillic italic letter yeru";
+beginchar(cyrery,12u#,x_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup tiny.nib;
+numeric x_bowl; x_bowl=2/3h;
+pos1(stem,0); pos2(stem,0); x1=x2;
+lft x1l=hround(1.5u-.5stem); top y1r=h+oo; y2=.5x_bowl;
+filldraw stroke z1e--z2e;  % stem
+sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
+pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
+pos4(curve,0); pos5(vair,90); pos0(hair,180);
+z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(8u-1.5u+.5curve);
+bot y3r=-oo; top y5r=x_bowl+oo; y4=y2;
+filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
+ & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
+pickup fine.nib; x7-.5stem=hround(9.5u-.5stem); x9=w;
+hook_out(7,8,9);  % closing hook
+pickup tiny.nib; pos6(stem,0); pos7'(stem,0); z7'=z7;
+top y6=h; x6=x7; filldraw stroke z6e--z7e;  % stem
+sloped_serif.l(6,7,b,1/3,jut,serif_drop);  % serif
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+cmchar "Cyrillic italic letter e";
+beginchar(cyrerev,8u#,x_height#,0);
+italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
+adjust_fit(0,0); pickup fine.nib;
+pos0(flare,180); pos1(hair,180); pos2(vair,-90);
+pos3(curve,0); pos4(vair,90); pos5(hair,140);
+x2=x4=.5(w-u); lft x1r=.25u;
+rt x3r=hround(w-1.5u+.5curve); x5r=good.x(eps); x6=x5;
+y1=.52[0,h-bar_height]; bot y2r=-oo; bulb(2,1,0);  % bulb
+top y4r=h+oo; y3=.5[y2,y4]; bot y5l=vround h-.5bar_height; y6=h-bar_height;
+path p; p=z4{left}..z5..z6;
+filldraw stroke pulled_arc.e(2,3)
+ & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
+penpos7(bar,90); penpos8(bar,90);
+x7=x3; y7=.52h; y8=y7; x8=.5w-hround(u);
+fill stroke z7e--z8e;  % bar
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Cyrillic italic letter yu";
+beginchar(cyryu,13u#,x_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
+hook_in(0,a,1);  % opening hook
+filldraw circ_stroke z2e--z1e;  % left stem
+pos3(vair,90); pos4(curve,180); pos5(vair,270); pos6(curve,360);
+x3=x5=w-4.5u; rt x6r=hround(w-1.5u+.5curve); x4=w-(x6-4u);
+top y3r=h+oo; y4=y6=.5[y3,y5]; bot y5r=-oo;
+filldraw stroke pulled_arc.e(3,4) & pulled_arc.e(4,5)
+ & pulled_arc.e(5,6) & pulled_arc.e(6,3); % bowl
+penpos4'(bar,90); penpos7(bar,90); z4'=z4; x7=x1; y7=y4';
+fill stroke z4'e--z7e;  % bar
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
+penlabels(1,2,3,4,4',5,6,7); endchar;
+
+cmchar "Cyrillic italic letter ya";
+beginchar(cyrya,8u#+.5max(2u#,curve#),x_height#,0);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0);
+pickup tiny.nib; pos1(stem',0); pos2(stem',0);
+rt x1r=rt x2r=w-hround(2.5u-.5stem'); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+penpos3(cap_band,90); penpos4(cap_band,90);
+penpos5(curve if hefty:-3stem_corr fi,180);
+penpos6(vair,-90); penpos7(vair,-90);
+z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
+x7=x2; y7=.5h; x4=x6;
+if serifs: x4=.5w+.5u; x5r=hround(1.5u);
+else: x4=.5w-.5u; x5l=hround(.75u); fi
+x4l:=x6l:=x4+.125curve;
+fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e;  % lobe
+pos6'(vair,-90); pos0(stem,0);
+pos8(curve,0); pos9(vair,-90); pos10(hair,180);
+z6'=z6; rt x0r=rt x8r=hround(x5+2/3u+.5curve);
+y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
+bot y9l=0; lft x10r=hround(.05u); y10=1/4[y2,y7];
+filldraw stroke z6'e{left}..z0e---z8e....z9e{left}..z10e{up};  % tail
+nodish_serif(1,2,a,1/3,.5jut,b,1/3,jut);  % upper serif
+dish_serif(2,1,c,1/3,jut,d,1/3,jut);  % lower serif
+math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
+ 2u#-.5stem#-desc_depth#*slant),ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
+