move svnchangelog.sed to libexec, now that we have it

git-svn-id: svn://tug.org/texlive/trunk@12325 c570f23f-e606-0410-a88d-b1316a301751

1 files changed, 43 insertions, 0 deletions

diff --git a/Master/tlpkg/libexec/svnchangelog.sed b/Master/tlpkg/libexec/svnchangelog.sed
new file mode 100755
index 00000000000..699cacce1f9
--- /dev/null
+++ b/Master/tlpkg/libexec/svnchangelog.sed
@@ -0,0 +1,43 @@
+#! /bin/sed -nf
+# $Id$
+# Written by Werner Lemberg, 25may06.  Public domain.
+# svn log outputs the paths first, then the log message.  This sed
+# script reverses that.
+
+:main
+/------------------------------------------------------------------------/ {
+  p
+  n
+  /r[0-9][0-9]* / {
+    p
+    n
+    /^Changed paths:$/ {
+      h
+      n
+
+      :loop1
+      /^$/! {
+        H
+        n
+        bloop1
+      }
+
+      :loop2
+      /------------------------------------------------------------------------/! {
+        p
+        n
+        bloop2
+      }
+
+      i\
+
+      x
+      p
+      g
+      bmain
+    }
+  }
+  bmain
+}
+
+p