more autoconf updates

git-svn-id: svn://tug.org/texlive/trunk@6488 c570f23f-e606-0410-a88d-b1316a301751

10 files changed, 114 insertions, 33 deletions

diff --git a/Build/source/texk/ChangeLog b/Build/source/texk/ChangeLog
index 900a423f42c..68b63bfe88d 100644
--- a/Build/source/texk/ChangeLog
+++ b/Build/source/texk/ChangeLog
@@ -1,3 +1,16 @@
+2008-02-02  Peter Breitenlohner  <peb@mppmu.mpg.de>
+
+	Convert from autoconf-2.13 to autoconf-2.59+:
+	* configure.in: Use KPSE_CONFIG_SUBDIRS.
+	* Makefile.in: Add @configure_input@ line.
+	* aclocal.m4 (new): Generated (aclocal -I m4).
+	* configure: Regenerated (autoconf).
+
+2008-02-01  Peter Breitenlohner  <peb@mppmu.mpg.de>
+
+	* configure.in: Removed configure kludge for dvipos.
+	* configure: Regenerated (autoconf2.13).
+
 2008-01-13  Karl Berry  <karl@tug.org>
 
 	* withenable.ac (afm2pl, dtl): more --without options.
diff --git a/Build/source/texk/Makefile.in b/Build/source/texk/Makefile.in
index 3f46fcc9407..876d6be80a3 100644
--- a/Build/source/texk/Makefile.in
+++ b/Build/source/texk/Makefile.in
@@ -1,3 +1,4 @@
+# @configure_input@
 # Top-level Makefile for kpathsea-using programs.
 
 # Package subdirectories, the library, and all subdirectories.
diff --git a/Build/source/texk/cjkutils/ChangeLog b/Build/source/texk/cjkutils/ChangeLog
index 776b81e96b2..0bcbc04b011 100644
--- a/Build/source/texk/cjkutils/ChangeLog
+++ b/Build/source/texk/cjkutils/ChangeLog
@@ -1,3 +1,9 @@
+2008-01-31  Peter Breitenlohner  <peb@mppmu.mpg.de>
+
+	* configure.in: Use AC_CONFIG_FILES([Makefile]) instead of
+	KPSE_CONFIG_FILES.
+	* configure: Regenerated.
+
 2008-01-30  Peter Breitenlohner  <peb@mppmu.mpg.de>
 
 	Convert from autoconf-2.13 to autoconf-2.59+:
diff --git a/Build/source/texk/cjkutils/configure.in b/Build/source/texk/cjkutils/configure.in
index d58f4628474..9e190434224 100644
--- a/Build/source/texk/cjkutils/configure.in
+++ b/Build/source/texk/cjkutils/configure.in
@@ -52,6 +52,7 @@ AC_PROG_INSTALL
 
 sinclude(../kpathsea/withenable.ac)
 
-KPSE_CONFIG_FILES([Makefile conv/Makefile hbf2gf/Makefile scripts/Makefile])
+AC_CONFIG_FILES([Makefile])
+KPSE_CONFIG_FILES([conv/Makefile hbf2gf/Makefile scripts/Makefile])
 AC_OUTPUT
 date >stamp-auto
diff --git a/Build/source/texk/configure.in b/Build/source/texk/configure.in
index 4a29b8147ac..ad060defe49 100644
--- a/Build/source/texk/configure.in
+++ b/Build/source/texk/configure.in
@@ -15,7 +15,7 @@ dnl
 AC_INIT(kpathsea/kpathsea.texi)
 
 dnl These configure scripts won't work with anything else.
-AC_PREREQ(2.13)
+AC_PREREQ(2.59)
 
 AC_PROG_MAKE_SET
 
@@ -47,7 +47,9 @@ if test "x$with_x" = xno; then
   with_xdvik=no
 fi
 
-PKGS='
+AC_CONFIG_SUBDIRS([kpathsea web2c])
+
+KPSE_CONFIG_SUBDIRS([
  afm2pl
  bibtex8
  cjkutils
@@ -76,33 +78,7 @@ PKGS='
  xdv2pdf
  xdvik
  xdvipdfmx
-'
-
-ESUBDIRS=
-for pkg in $PKGS; do
-  if eval "test \"x`echo '$with_'${pkg}`\" != xno"; then
-    ESUBDIRS="$ESUBDIRS $pkg"
-
-    if test "$pkg" = dvipos; then
-      # attempt to discover if srcdir = builddir.
-      dir_src=`cd $srcdir/dvipos && /bin/pwd`
-      dir_work=`/bin/pwd`/dvipos  # may not exist, so don't cd
-      echo "testing configure kludge for dvipos..."
-      if test "$dir_src" != "$dir_work"; then
-        # this is a terrible kludge, but dvipos has no real configure
-        # and it is claimed crucial for context.
-        # So copy the entire sam2p srcdir into objdir.
-        rm -rf $dir_work
-        mkdir $dir_work
-        cp -pr $dir_src/* $dir_work/  # omit .svn
-        echo "  copied dvipos dir_src ($dir_src) dir_work ($dir_work)"
-      fi
-    fi
-  fi
-done
-AC_SUBST(ESUBDIRS)
-
-AC_CONFIG_SUBDIRS(kpathsea web2c $ESUBDIRS)
+])
 
 KPSE_CONFIG_FILES([Makefile])
 AC_OUTPUT
diff --git a/Build/source/texk/m4/ChangeLog b/Build/source/texk/m4/ChangeLog
index c2f9c8c4c75..d5e2a58e8e6 100644
--- a/Build/source/texk/m4/ChangeLog
+++ b/Build/source/texk/m4/ChangeLog
@@ -1,3 +1,9 @@
+2008-02-02  Peter Breitenlohner  <peb@mppmu.mpg.de>
+
+	* kpse_subdirs.m4 (new): Define KPSE_CONFIG_SUBDIRS, used in
+	../configure.in and ../../configure.in in order to avoid shell
+	variables as arguments of AC_CONFIG_SUBDIRS.
+
 2008-01-29  Peter Breitenlohner  <peb@mppmu.mpg.de>
 
 	Support for autoconf-2.59+:
diff --git a/Build/source/texk/m4/kpse_subdirs.m4 b/Build/source/texk/m4/kpse_subdirs.m4
new file mode 100644
index 00000000000..70afe18fdac
--- /dev/null
+++ b/Build/source/texk/m4/kpse_subdirs.m4
@@ -0,0 +1,73 @@
+# Private macros for the kpathsea library.
+# by Peter Breitenlohner <peb@mppmu.mpg.de>
+# Copyright (C) 2008
+# Free Software Foundation, Inc.
+#
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# serial 1
+
+# KPSE_CONFIG_SUBDIRS(PKGLIST, [DIR])
+# -----------------------------------
+# Specify optional subdirectories to be configured.
+# First the shell variable ESUBDIRS initialize (to empty).  Then for
+# each PKG in PKGLIST, test if PKG (or optionally DIR/PKG) exists as
+# subdirectory of $srcdir and the value of the shell variable with_PKG
+# differs from "no"; if so append this subdirectoryi to the list of
+# subdirectories to be configured and to the shell variable ESUBDIRS.
+# Finally ESUBDIRS is AC_SUBSTed.
+#
+# Examples: KPSE_CONFIG_SUBDIRS([dialog lcdf-typetools], [utils]) is
+# roughly equivalent to the shell code
+#	ESUBDIRS=
+#	  test -d utils || mkdir utils
+#	  for pkg in $PKGS; do
+#	    if test -d $srcdir/utils/$pkg; then
+#	      if eval "test \"`echo '$with_'${pkg}|sed 's/-/_/g'`\" != no"; then
+#	        ESUBDIRS="$ESUBDIRS utils/$pkg"
+#	        AC_CONFIG_SUBDIRS([utils/$pkg])
+#	      fi
+#	    fi
+#	  done
+#	AC_SUBST(ESUBDIRS)
+# whereas KPSE_CONFIG_SUBDIRS([afm2pl bibtex8]) corresponds to
+#	ESUBDIRS=
+#	for pkg in $PKGS; do
+#	  if test -d $srcdir/utils/$pkg; then
+#	    if eval "test \"x`echo '$with_'${pkg}`\" != xno"; then
+#	      ESUBDIRS="$ESUBDIRS $pkg"
+#	      AC_CONFIG_SUBDIRS([$pkg])
+#	    fi
+#	  fi
+#	done
+#	AC_SUBST(ESUBDIRS)
+#
+# The main difference is that these macros replace the shell loop by
+# an M4 loop and therefore M4 variables (i.e., shell literals) are
+# passed as arguments to AC_CONFIG_SUBDIRS, as required by modern
+# versions of Autoconf and Automake.
+
+AC_DEFUN([KPSE_CONFIG_SUBDIRS],
+[ESUBDIRS=
+m4_ifval([$2], [test -d $2 || mkdir $2])
+AC_FOREACH([AC_Pkg], [$1],
+  [_KPSE_CONFIG_SUBDIR(m4_ifval([$2], [$2/])AC_Pkg,
+     [with_]m4_bpatsubst(AC_Pkg, [-], [_]))])
+AC_SUBST(ESUBDIRS)dnl
+])
+
+# _KPSE_CONFIG_SUBDIR(DIR, WITH_VAR)
+# ----------------------------------
+# See above; test if $srcdir/DIR exists and $WITH_VAR != no; if so
+# append DIR to the list of subdirectories to be configured.
+m4_define([_KPSE_CONFIG_SUBDIR],
+[if test -d $srcdir/$1; then
+  if test "x$[]$2" != xno; then
+    ESUBDIRS="$ESUBDIRS $1"
+    AC_CONFIG_SUBDIRS([$1])dnl
+  fi
+fi
+])
+
diff --git a/Build/source/texk/make/ChangeLog b/Build/source/texk/make/ChangeLog
index 491b7f5e37e..7fb81d13b00 100644
--- a/Build/source/texk/make/ChangeLog
+++ b/Build/source/texk/make/ChangeLog
@@ -1,3 +1,7 @@
+2008-02-02  Peter Breitenlohner  <peb@mppmu.mpg.de>
+
+	* paths.mk: Add datarootdir for Autoconf 2.60+.
+
 2007-07-29  Karl Berry  <karl@tug.org>
 
 	* rdepend.mk: replace all texk/kpathsea, not just first.
diff --git a/Build/source/texk/make/README b/Build/source/texk/make/README
index 9481d74b7d5..88a1364ba82 100644
--- a/Build/source/texk/make/README
+++ b/Build/source/texk/make/README
@@ -10,9 +10,9 @@ kb@mail.tug.org
 With the long overdue transition from autoconf-2.13 to autoconf-2.59+
 this is handled as follows:
 
-Every 'ac_include' in Makefile.in are replaced by 'kpse_include' and the
-command 'AC_CONFIG_FILES([Makefile])' in configure.in (or configure.ac)
-is replaced by 'KPSE_CONFIG_FILES([Makefile])'.
+Each 'ac_include' in Makefile.in is replaced by 'kpse_include' and the
+command 'AC_CONFIG_FILES([Makefile])' in configure.in or configure.ac is
+replaced by 'KPSE_CONFIG_FILES([Makefile])'.
 
 The macro KPSE_CONFIG_FILES (defined in kpse_inc.m4) uses standard
 autoconf mechanisms to achieve the desired substitutions.
diff --git a/Build/source/texk/make/paths.mk b/Build/source/texk/make/paths.mk
index 7a18924ad0f..d0aee38aa68 100644
--- a/Build/source/texk/make/paths.mk
+++ b/Build/source/texk/make/paths.mk
@@ -22,6 +22,7 @@ scriptdir = $(bindir)
 libdir = @libdir@
 
 # Architecture-independent files.
+datarootdir = @datarootdir@
 datadir = @datadir@
 
 # Header files.