summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/doc/latex/texmate/skak/mf/skakinf.mf
blob: 224a774018134ec2904c3fe4350e97c0bcc51dbe (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739

% First, the markers (cross and circle) are defined for usage
% in the normal text.

beginchar("x", d#, .8d#, .2d#);
  "x: Cross marker";

  pickup pencircle scaled thick;
  define_whole_pixels(d);

  % lower left point
  z1=(.2d,0);
  % upper left point
  z2=(.2d,.6d);
  % lower right point
  z3=(.8d,0);
  % upper right point
  z4=(.8d,.6d);

  draw z1..z4;
  draw z2..z3;
endchar;

beginchar("y", d#, .8d#, .2d#);
  "y: Circle marker";

  pickup pencircle scaled thick;
  define_whole_pixels(d);

  draw fullcircle scaled .6d shifted (.5d,.3d);
endchar;

% Additionally, a "plus" and "minus" sign and the
% ``capture'' symbol are provided

beginchar("+", .7d#, d#, 0);
  "+: Plus";

  pickup pencircle scaled middle;
  define_whole_pixels(d);

  % Plus sign
  z1=(.1d,.25d);
  z2=(.6d,.25d);
  z3=(.35d,.5d);
  z4=(.35d,0);

  draw z1--z2;
  draw z3--z4;
endchar;

beginchar("-", .4d#, d#, 0);
  "-: Minus";

  pickup pencircle scaled middle;
  define_whole_pixels(d);

  % Minus sign
  z1=(.1d,.3d);
  z2=(.3d,.3d);

  draw z1--z2;
endchar;

beginchar("X", .6d#, d#, 0);
  "X: Capture symbol";

  pickup pencircle scaled middle;
  define_whole_pixels(d);

  % lower left point
  z1=(.1d,.5middle);
  % upper left point
  z2=(.1d,.4d+.5middle);
  % lower right point
  z3=(.5d,.5middle);
  % upper right point
  z4=(.5d,.4d+.5middle);

  draw z1..z4;
  draw z2..z3;
endchar;

% Here, the definitions of the informator symbols start

beginchar("a", d#, d#, 0);
  "a: Informator symbol ``pair of bishops''";
  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Points for lower square
  z1=(.1d,.5d);
  z2=(.1d,0);
  z3=(.6d,.5d);
  z4=(.6d,0);

  % Points for upper square
  z5=(.4d,.8d);
  z6=(.4d,.3d);
  z7=(.9d,.8d);
  z8=(.9d,.3d);

  draw z1--z2--z4--z3--z1;
  draw z5--z6--z8--z7--z5;
endchar;

beginchar("b", 1.2d#, d#, 0);
  "b: Informator symbol ``better is''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Points for vertical line
  z1=(.1d,0);
  z2=(1.1d,0);

  draw z1..z2;
  draw halfcircle scaled d shifted (.6d,0);
endchar;

beginchar("c", .7d#, d#, 0);
  "c: Informator symbol ``white has the upper hand''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Minus sign
  z1=(.1d,.2d);
  z2=(.6d,.2d);
  % Plus sign
  z3=(.1d,.55d);
  z4=(.6d,.55d);
  z5=(.35d,.8d);
  z6=(.35d,.3d);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6;
endchar;

beginchar("d", .9d#, d#, 0);
  "d: Informator symbol ``double pawns''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  draw fullcircle scaled .35d shifted (.45d,.125d);
  draw fullcircle scaled .35d shifted (.45d,.625d);
endchar;

beginchar("e", .7d#, d#, 0);
  "e: Informator symbol ``black has the upper hand''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Minus sign
  z1=(.1d,.6d);
  z2=(.6d,.6d);
  % Plus sign
  z3=(.1d,.25d);
  z4=(.6d,.25d);
  z5=(.35d,.5d);
  z6=(.35d,0);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6;
endchar;

beginchar("f", .7d#, d#, 0);
  "f: Informator symbol ``white stands slightly better''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Equal sign
  z1=(.1d,.2d);
  z2=(.6d,.2d);
  z3=(.1d,.1d);
  z4=(.6d,.1d);
  % Plus sign
  z5=(.1d,.55d);
  z6=(.6d,.55d);
  z7=(.35d,.8d);
  z8=(.35d,.3d);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6;
  draw z7--z8;
endchar;

beginchar("g", .7d#, d#, 0);
  "g: Informator symbol ``black stands slightly better''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Equal sign
  z1=(.1d,.6d);
  z2=(.6d,.6d);
  z3=(.1d,.7d);
  z4=(.6d,.7d);
  % Plus sign
  z5=(.1d,.25d);
  z6=(.6d,.25d);
  z7=(.35d,.5d);
  z8=(.35d,0);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6;
  draw z7--z8;
endchar;

beginchar("h", 1.3d#, d#, 0);
  "h: Informator symbol ``white has a decisive advantage''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Plus sign
  z1=(.1d,.25d);
  z2=(.6d,.25d);
  z3=(.35d,.5d);
  z4=(.35d,0);
  % Minus sign
  z5=(.7d,.25d);
  z6=(1.2d,.25d);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6;
endchar;

beginchar("i", 1.3d#, d#, 0);
  "i: Informator symbol ``black has a decisive advantage''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Minus sign
  z1=(.1d,.25d);
  z2=(.6d,.25d);
  % Plus sign
  z3=(.7d,.25d);
  z4=(1.2d,.25d);
  z5=(.95d,.5d);
  z6=(.95d,0);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6;
endchar;

beginchar("j", .7d#, d#, 0);
  "j: Informator symbol ``even''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.4d);
  z2=(.6d,.4d);
  z3=(.1d,.3d);
  z4=(.6d,.3d);
  draw z1--z2;
  draw z3--z4;
endchar;

beginchar("k", .7d#, d#, 0);
  "k: Informator symbol ``unclear''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.35d);
  z2=(.2d,.475d);
  z3=(.35d,.35d);
  z4=(.5d,.225d);
  z5=(.6d,.35d);
  z6=(.5d,.475d);
  z7=(.2d,.225d);

  draw z1..z2..z3..z4..z5..z6..z3..z7..cycle;
endchar;

beginchar("l", d#, d#, 0);
  "l: Informator symbol ``see''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.35d);
  z2=(.9d,.35d);
  draw z1--z2;
endchar;

beginchar("m", .9d#, d#, 0);
  "m: Informator symbol ``mate''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Points for vertical lines
  z1=(.1d,.5d);
  z2=(.1d,.2d);
  z3=(.8d,.5d);
  z4=(.8d,.2d);

  % Points for horizontal lines
  z5=(.3d,.7d);
  z6=(.6d,.7d);
  z7=(.3d,0);
  z8=(.6d,0);

  draw z1..z3;
  draw z2..z4;
  draw z5..z7;
  draw z6..z8;
endchar;

beginchar("n", .7d#, d#, 0);
  "n: Informator symbol ``with compensation for the material''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Infinity symbol
  z1=(.1d,.25d);
  z2=(.2d,.375d);
  z3=(.35d,.25d);
  z4=(.5d,.125d);
  z5=(.6d,.25d);
  z6=(.5d,.375d);
  z7=(.2d,.125d);
  % Equal sign
  z8=(.1d,.575d);
  z9=(.6d,.575d);
  z10=(.1d,.475d);
  z11=(.6d,.475d);

  draw z1..z2..z3..z4..z5..z6..z3..z7..cycle;
  draw z8--z9;
  draw z10--z11;
endchar;

beginchar("o", d#, d#, 0);
  "o: Informator symbol ``bishops of opposite color''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Points for lower square
  z1=(.1d,.5d);
  z2=(.1d,0);
  z3=(.6d,.5d);
  z4=(.6d,0);

  % Points for upper square
  z5=(.4d,.8d);
  z6=(.4d,.3d);
  z7=(.9d,.8d);
  z8=(.9d,.3d);

  draw z1--z2--z4--z3--z1;
  fill z5--z6--z8--z7--cycle;
endchar;

beginchar("q", 1.25d#, d#, 0);
  "q: Informator symbol ``separated pawns''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  draw fullcircle scaled .35d shifted (.275d,.4d);
  fill fullcircle scaled .1d shifted (.55d,.4d);
  fill fullcircle scaled .1d shifted (.7d,.4d);
  draw fullcircle scaled .35d shifted (.975d,.4d);
endchar;

beginchar("r", d#, d#, 0);
  "r: Informator symbol ``passed pawn''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.5d,.7d);
  z2=(.5d,.4d);
  draw fullcircle scaled .4d shifted (.5d,.2d);
  draw z1--z2;
  draw quartercircle rotated 270 scaled .2d shifted (.4d,.7d);
  draw quartercircle rotated 180 scaled .2d shifted (.6d,.7d);
endchar;

beginchar("s", d#, d#, 0);
  "s: Informator symbol ``bishops of the same color''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Points for lower square
  z1=(.1d,.5d);
  z2=(.1d,0);
  z3=(.6d,.5d);
  z4=(.6d,0);

  % Points for upper square
  z5=(.4d,.8d);
  z6=(.4d,.3d);
  z7=(.9d,.8d);
  z8=(.9d,.3d);

  fill z1--z2--z4--z3--cycle;
  fill z5--z6--z8--z7--cycle;
endchar;

beginchar("t", d#, d#, 0);
  "t: Informator symbol ``development advantage''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Arcus
  z1=(.8d,.65d);
  z2=(.5d,.8d);
  z3=(.1d,.4d);
  z4=(.5d,0);
  z5=(.9d,.4d);
  z6=(.85d,.55d);
  % Arrow
  z7=(.65d,.65d);
  z8=(.8d,.8d);

  draw z1..z2..z3..z4..z5..z6;
  draw z7--z1;
  draw z8--z1;
endchar;

beginchar("u", d#, d#, 0);
  "u: Informator symbol ``united pawns''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  draw fullcircle scaled .35d shifted (.275d,.4d);
  draw fullcircle scaled .35d shifted (.725d,.4d);
endchar;

beginchar("v", d#, d#, 0);
  "v: Informator symbol ``without''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.8d);
  z2=(.1d,0);
  z3=(.9d,0);
  draw z1--z2--z3;
endchar;

beginchar("w", d#, d#, 0);
  "w: Informator symbol ``with''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,0);
  z2=(.9d,0);
  z3=(.9d,.8d);
  draw z1--z2--z3;
endchar;

beginchar("A", .9d#, d#, 0);
  "A: Informator symbol ``with attack''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.4d);
  z2=(.7d,.4d);

  draw z1--z2;
  draw quartercircle rotated 180 scaled .2d shifted (.7d,.5d);
  draw quartercircle rotated 90 scaled .2d shifted (.7d,.3d);
endchar;

beginchar("C", .6d#, d#, 0);
  "C: Informator symbol ``with initiative''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.3d,.7d);
  z2=(.3d,.1d);

  draw z1--z2;
  draw quartercircle rotated 270 scaled .2d shifted (.2d,.7d);
  draw quartercircle rotated 180 scaled .2d shifted (.4d,.7d);
endchar;

beginchar("D", d#, d#, 0);
  "D: Informator symbol ``zugzwang''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  draw fullcircle scaled .8d shifted (.5d,.4d);
  fill fullcircle scaled .15d shifted (.5d,.4d);
endchar;

beginchar("E", d#, d#, 0);
  "E: Informator symbol ``with the idea''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,0);
  z2=(.9d,0);
  z3=(.5d,.8d);

  draw z1--z2--z3--z1;
endchar;

beginchar("F", d#, d#, 0);
  "F: Informator symbol ``only move''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,0);
  z2=(.9d,0);
  z3=(.9d,.8d);
  z4=(.1d,.8d);

  draw z1--z2--z3--z4--z1;
endchar;

beginchar("G", d#, d#, 0);
  "G: Informator symbol ``diagonal''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.15d);
  z2=(.75d,.8d);
  z3=(.25d,0);
  z4=(.9d,.65d);
  z5=(.55d,.8d);
  z6=(.9d,.45d);
  z7=(.9d,.8d);

  draw z1--z2;
  draw z3--z4;
  draw z5--z7--z6;
endchar;

beginchar("H", d#, d#, 0);
  "H: Informator symbol ``file''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.2d,.5d);
  z2=(.8d,.5d);
  z3=(.2d,.3d);
  z4=(.8d,.3d);
  z5=(.3d,.6d);
  z6=(.1d,.4d);
  z7=(.3d,.2d);
  z8=(.7d,.6d);
  z9=(.9d,.4d);
  z10=(.7d,.2d);

  draw z1--z2;
  draw z3--z4;
  draw z5--z6--z7;
  draw z8--z9--z10;
endchar;

beginchar("I", d#, d#, 0);
  "I: Informator symbol ``centre''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Outer square
  z1=(.1d,0);
  z2=(.9d,0);
  z3=(.9d,.8d);
  z4=(.1d,.8d);
  % Cross
  z5=(.2d,.4d);
  z6=(.8d,.4d);
  z7=(.5d,.7d);
  z8=(.5d,.1d);

  draw z1--z2--z3--z4--z1;
  draw z5--z6;
  draw z7--z8;
endchar;

beginchar("J", d#, d#, 0);
  "J: Informator symbol ``weak point''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,0);
  z2=(.9d,0);
  z3=(.9d,.8d);
  z4=(.1d,.8d);

  draw z1--z3;
  draw z2--z4;
endchar;

beginchar("L", d#, d#, 0);
  "L: Informator symbol ``ending''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,0);
  z2=(.9d,0);
  z3=(.5d,0);
  z4=(.5d,.8d);

  draw z1--z2;
  draw z3--z4;
endchar;

beginchar("M", .8d#, d#, 0);
  "M: Informator symbol ``queen's side''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.4d,.7d);
  z2=(.1d,.4d);
  z3=(.4d,.1d);
  z4=(.6d,.7d);
  z5=(.3d,.4d);
  z6=(.6d,.1d);

  draw z1--z2--z3;
  draw z4--z5--z6;
endchar;

beginchar("O", .8d#, d#, 0);
  "O: Informator symbol ``king's side''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.4d,.7d);
  z2=(.7d,.4d);
  z3=(.4d,.1d);
  z4=(.2d,.7d);
  z5=(.5d,.4d);
  z6=(.2d,.1d);

  draw z1--z2--z3;
  draw z4--z5--z6;
endchar;

beginchar("P", .4d#, d#, 0);
  "P: Informator symbol ``etc''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.8d);
  z2=(.1d,0);
  z3=(.3d,.8d);
  z4=(.3d,0);

  draw z1--z2;
  draw z3--z4;
endchar;

beginchar("S", .8d#, d#, 0);
  "S: Informator symbol ``advantage in number of pawns''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.8d);
  z2=(.7d,.4d);
  z3=(.1d,0);

  draw z1--z2--z3;
endchar;

beginchar("T", d#, d#, 0);
  "T: Informator symbol ``time''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  % Cross
  z1=(.2d,.4d);
  z2=(.8d,.4d);
  z3=(.5d,.7d);
  z4=(.5d,.1d);

  draw z1--z2;
  draw z3--z4;
  draw fullcircle scaled .8d shifted (.5d,.4d);
endchar;

beginchar("U", d#, d#, 0);
  "U: Informator symbol ``greater board room''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  draw fullcircle scaled .8d shifted (.5d,.4d);
endchar;

beginchar("V", .8d#, d#, 0);
  "V: Informator symbol ``with counter-play''";

  pickup pencircle scaled thin;
  define_whole_pixels(d);

  z1=(.1d,.5d);
  z2=(.7d,.5d);
  z3=(.1d,.3d);
  z4=(.7d,.3d);

  draw z1--z2;
  draw z3--z4;
  draw quartercircle rotated 270 scaled .2d shifted (.1d,.6d);
  draw quartercircle scaled .2d shifted (.1d,.4d);
  draw quartercircle rotated 180 scaled .2d shifted (.7d,.4d);
  draw quartercircle rotated 90 scaled .2d shifted (.7d,.2d);
endchar;