% ----------------------------------------------------------------
% BibTeX bibliography style `rsc' for Dalton Trans., 
% Org. Biomol. Chem., Chem. Commun., Phys. Chem. Chem. Phys., etc.
% ----------------------------------------------------------------
%
% ----------------------------------------------------------------
% Maintained by Joseph A. Wright 
% E-mail: joseph.wright@morningstar2.co.uk
% Released under the GNU General Public License
% See http://www.gnu.org/licenses/gpl.txt
% ----------------------------------------------------------------

% ----------------------------------------------------------------
% History
% 2006-10-30    Improvements to patent number handling; automatic
%               digit grouping.  Patent assignee recognised from
%               organization field.  Added support for non-standard
%               types as in achemso.bst
% 2006-10-22    Added converters for edition numbers (to change
%               1 to 1st, 2 to 2nd, etc.) from custom-bib 
%               package.
% 2006-06-27    Substantial improvements to output consistency
%               with RSC style requirements.
%               Improved support for unpublished works, in press
%               and so on.
% ----------------------------------------------------------------
%   
% ----------------------------------------------------------------
% Usage notes:
% 1) Other than the 'article' reference type, the RSC publication
%    rules give only limited guidance.  I have therefore had to 
%    look at a number of real-world examples, and pick the useage
%    I am happiest with.  So of the layout is therefore more of
%    a personal preference than anything else.
% 2) Patents.  Patents can be saves as type 'patent' or 'other'
%    Fill in as for article, and the correct formatting will 
%    result (Authors, "Journal", Year).  Any other use of 'other'
%    will give the same result.  Patent numbers are automatically
%    digit-grouped if they are purely made up of digits.  Assignee
%    is given in the organization field.
% 3) Unpublished.  If a journal is given (for example, for 
%    submitted or in press articles), then this will be printed.
%    Use the 'note' field for the status of the references
%    (personal communication, in press, etc.)
% 4) In press articles with DOI.  If unpublished articles have
%    a DOI given, this will be given in the output, with 
%    the year added as well.  In this case, no 'note' is added
% 5) Miscellaneous (e.g. software). Use the 'howpublished' field
%    for organisation, address etc. 
% 6) The non-standard types remark, inpress and submitted are 
%    supported for compatibility with achemso.bst.  Note that they
%    are implemented to act in the same way as the rest of this 
%    style.
% ----------------------------------------------------------------

ENTRY
  { address
    author
    booktitle
    chapter
    doi
    edition
    editor
    howpublished
    institution
    journal
    key
    month
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
  }
  {}
  { label }

INTEGERS { output.state before.all mid.sentence after.sentence after.block after.item author.or.editor }

FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.sentence :=
  #3 'after.block :=
  #4 'after.item :=
}

FUNCTION {add.semicolon}
{ duplicate$
  #-1 #1 substring$ "}" =
      { #-2 #1024 substring$ ";} " * }
      { "; " * }
  if$
}

FUNCTION {add.comma}
{ duplicate$
  #-1 #1 substring$ "}" =
      { #-2 #1024 substring$ ";} " * }
      { ", " * }
  if$
}

STRINGS { s t }

FUNCTION {output.nonnull}
{ 's :=
  output.state mid.sentence =
    { ", " * write$ }
    { output.state after.block =
    { add.comma write$
      newline$
      "\newblock " write$
    }
    { output.state before.all =
        'write$
        { output.state after.item =
        { " " * write$ }
          { add.period$ " " * write$ }
        if$
        }
        if$
      }
    if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {output.bibitem}
{ newline$
  "\bibitem{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {fin.entry}
{ add.period$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { after.block 'output.state := }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
    'skip$
    { after.sentence 'output.state := }
      if$
    }
  if$
}

FUNCTION {new.item}
{ duplicate$ empty$
    { skip$ }
    { output.state mid.sentence =
        { after.item 'output.state := }
        { skip$ }
      if$
    }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {new.sentence.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.sentence
  if$
}

FUNCTION {new.item.checka}
{ empty$
    'skip$
    'new.item
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "\emph{" swap$ * "}" * }
  if$
}

FUNCTION {boldface}
{ duplicate$ empty$
    { pop$ "" }
    { "\textbf{" swap$ * "}" * }
  if$
}

FUNCTION {paren}
{ duplicate$ empty$
    { pop$ "" }
    { "(" swap$ * ")" * }
  if$
}

% Some functions taken from custombib.tex
FUNCTION {bbl.first}
{ "1st" }

FUNCTION {bbl.second}
{ "2nd" }

FUNCTION {bbl.third}
{ "3rd" }

FUNCTION {bbl.fourth}
{ "4th" }

FUNCTION {bbl.fifth}
{ "5th" }

FUNCTION {bbl.st}
{ "st" }

FUNCTION {bbl.nd}
{ "nd" }

FUNCTION {bbl.rd}
{ "rd" }

FUNCTION {bbl.th}
{ "th" }

FUNCTION {eng.ord}
{ duplicate$ "1" swap$ *
  #-2 #1 substring$ "1" =
     { bbl.th * }
     { duplicate$ #-1 #1 substring$
       duplicate$ "1" =
         { pop$ bbl.st * }
         { duplicate$ "2" =
             { pop$ bbl.nd * }
             { "3" =
                 { bbl.rd * }
                 { bbl.th * }
               if$
             }
           if$
          }
       if$
     }
   if$
}

FUNCTION {is.num}
{ chr.to.int$
  duplicate$ "0" chr.to.int$ < not
  swap$ "9" chr.to.int$ > not and
}

FUNCTION {extract.num}
{ duplicate$ 't :=
  "" 's :=
  { t empty$ not }
  { t #1 #1 substring$
    t #2 global.max$ substring$ 't :=
    duplicate$ is.num
      { s swap$ * 's := }
      { pop$ "" 't := }
    if$
  }
  while$
  s empty$
    'skip$
    { pop$ s }
  if$
}

FUNCTION {bibinfo.check}
{ swap$
  duplicate$ missing$
    {
      pop$ pop$
      ""
    }
    { duplicate$ empty$
        {
          swap$ pop$
        }
        { swap$
          pop$
        }
      if$
    }
  if$
}

FUNCTION {convert.edition}
{ extract.num "l" change.case$ 's :=
  s "first" = s "1" = or
    { bbl.first 't := }
    { s "second" = s "2" = or
        { bbl.second 't := }
        { s "third" = s "3" = or
            { bbl.third 't := }
            { s "fourth" = s "4" = or
                { bbl.fourth 't := }
                { s "fifth" = s "5" = or
                    { bbl.fifth 't := }
                    { s #1 #1 substring$ is.num
                        { s eng.ord 't := }
                        { edition 't := }
                      if$
                    }
                  if$
                }
              if$
            }
          if$
        }
      if$
    }
  if$
  t
}

INTEGERS { nameptr namesleft numnames }

FUNCTION {format.names}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr "{f.~}{vv~}{ll}{ jj}" format.name$ 't :=
      nameptr #1 >
    { namesleft #1 >
        { ", " * t * }
        { numnames #2 >
        { "" * }
        'skip$
            if$
          t "others" =
          { " \emph{et~al.}" * }
          { " and " * t * }
            if$
        }
      if$
      }
    't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { #1 'author.or.editor :=
      author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
    { "" }
    { #2 'author.or.editor :=
      editor num.names$ #1 >
      { "ed. " * }
      { "ed. " * }
      if$
      editor format.names
    }
  if$
}

INTEGERS { a b }

FUNCTION {mult}
{
 'a := 			    %% we store the first value
 'b :=			    %% we store the second value

 b #0 <			    %% We remember the sign of b, and
    {#-1 #0 b - 'b :=}	    %% then consider its absolute value.
    {#1}		    %%
 if$			    %%

 #0			    %% Put 0 on the stack.
 {b #0 >}		    %% While b is strictly positive,
 {			    %% we add a to the value on the stack
   a +			    %% and decrement b.
   b #1 - 'b :=		    %%
 }			    %%
 while$			    %%

 swap$ 	  		    %% Last, we take the opposite
   'skip$  		    %% if b was negative.
   {#0 swap$ -}		    %%
 if$			    %%
}

FUNCTION {chr.to.value.silent}	      %% The ASCII code of a character
{
  chr.to.int$ #48 -	      %% ASCII value of "0" -> 48
  duplicate$ duplicate$	      %%	        "1" -> 49
  #0 < swap$ #9 > or	      %%		   ...
  { pop$ pop$ "0" #0 }
  {}
  if$
}

FUNCTION {str.to.int.aux.silent}     %% The auxiliary function
{
  {duplicate$ empty$ not}     %% While the string is not empty
    {			      %% consider its first char
      swap$ #10 mult 'a :=    %% and ``add'' it at the end of
      duplicate$ #1 #1 substring$   %% the result.
      chr.to.value.silent a +
      swap$
      #2 global.max$ substring$
    }
  while$
  pop$
}

FUNCTION {str.to.int.silent}
{			      %% Handling negative values
  duplicate$ #1 #1 substring$ "-" =
    {#1 swap$ #2 global.max$ substring$}
    {#0 swap$}
  if$
			      %% Initialization, and then
  #0 swap$ str.to.int.aux.silent     %% call to the aux. funtion
  swap$
    {#0 swap$ -}	      %% And handle the sign.
    {}
  if$
}

% Two functions from Nicolas Markey

FUNCTION{is.a.digit}
{
  duplicate$ "" =
    {pop$ #0}
    {chr.to.int$ #48 - duplicate$
     #0 < swap$ #9 > or not}
  if$
}

FUNCTION{is.a.number}
{ 
  {duplicate$ #1 #1 substring$ is.a.digit }
    {#2 global.max$ substring$}
  while$
  "" =
}

FUNCTION {n.separate.multi}
{ 't :=
  ""
  #0 'numnames :=
  t text.length$ #4 > t is.a.number and % Test that t is both:  
    {                                   % 1) a number
      { t empty$ not }                  % 2) over four digits long
      { t #-1 #1 substring$ is.num
          { numnames #1 + 'numnames := }
          { #0 'numnames := }
        if$
        t #-1 #1 substring$ swap$ *
        t #-2 global.max$ substring$ 't :=
        numnames #4 =
          { duplicate$ #1 #1 substring$ swap$
            #2 global.max$ substring$
            "\," swap$ * *
            #1 'numnames :=
          }
          'skip$
        if$
      }
      while$
    } 
    { t swap$ * }
  if$
}

% Need a different format for books with editors
% than for editors in a collection

FUNCTION {format.editors.paren}
{ editor empty$
    { "" }
    { editor format.names
      #2 'author.or.editor :=
      editor num.names$ #1 >
      { * " (ed.)" }
      { * " (ed.)" }
      if$
    }
  if$
}

FUNCTION {format.title}
{ title empty$
    { "" }
    { title "t" change.case$ }
  if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
    { t #1 #2 substring$ "--" = not
        { "--" *
          t #2 global.max$ substring$ 't :=
        }
        {   { t #1 #1 substring$ "-" = }
        { "-" *
          t #2 global.max$ substring$ 't :=
        }
          while$
        }
      if$
    }
    { t #1 #1 substring$ *
      t #2 global.max$ substring$ 't :=
    }
      if$
    }
  while$
}

FUNCTION {format.date}
{ year empty$
    { "" }
    { year }
  if$
}

FUNCTION {format.bdate}
{ year empty$
    { "there's no year in " cite$ * warning$ }
    'year
  if$
}

FUNCTION {format.btitle}
{ title emphasize
}

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {space.connect}
{ " "
  swap$ * *
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}
{ volume empty$
    { "" }
    { "vol." volume tie.or.space.connect
      series empty$
    'skip$
    { " of " * series emphasize * }
      if$
      "volume and number" number either.or.check
    }
  if$
}

FUNCTION {format.number.series}
{ volume empty$
    { number empty$
    { series field.or.null }
    { output.state mid.sentence =
        { "no." }
        { "No." }
      if$
      number tie.or.space.connect
      series empty$
        { "there's a number but no series in " cite$ * warning$ }
        { " in " * series * }
      if$
    }
      if$
    }
    { "" }
  if$
}

FUNCTION {format.edition}
{ edition duplicate$ empty$ 'skip$
    {
      convert.edition
      output.state mid.sentence =
        { "l" }
        { "t" }
      if$ change.case$
      "edn." bibinfo.check
      " " * "edn." *
    }
  if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
    { #1 'multiresult := }
    { t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages multi.page.check
    { "pp." pages n.dashify tie.or.space.connect }
    { "p." pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.pages.nopp}
{ pages empty$
    { "" }
    { pages multi.page.check
    { pages n.dashify space.connect }
    { pages space.connect }
      if$
    }
  if$
}

FUNCTION {format.pages.patent}
{ pages empty$
    { "there is no patent number for " cite$ * warning$ }
    { pages multi.page.check
      { pages n.dashify }
      { pages n.separate.multi }
      if$
    }
  if$
}

FUNCTION {format.vol.num.pages}
{ volume boldface field.or.null
  number empty$
    'skip$
    { "(" number * ")" * *
      volume empty$
    { "there's a number but no volume in " cite$ * warning$ }
    'skip$
      if$
    }
  if$
  pages empty$
    'skip$
    { duplicate$ empty$
    { pop$ format.pages }
    { ", " * pages n.dashify * }
      if$
    }
  if$
}

FUNCTION {format.vol.pages}
{ volume boldface field.or.null
  pages empty$
    'skip$
    { duplicate$ empty$
    { pop$ format.pages }
    { ", " * pages n.dashify * }
      if$
    }
  if$
}

FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.pages
    { type empty$
    { "ch." }
    { type "l" change.case$ }
      if$
      chapter tie.or.space.connect
      pages empty$
    'skip$
    { ", " * format.pages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.booktitle}
{ booktitle empty$
    { "" }
    { editor empty$
    { "in " booktitle emphasize * }
    { "in " format.editors * ", " * booktitle emphasize * }
      if$
    }
  if$
}

FUNCTION {format.title.incoll}
{ title empty$
    { "" }
    { author empty$
        { title emphasize *}
        { ", " * title emphasize *}
      if$
    }        
  if$
}

FUNCTION {format.in.booktitle.ed}
{ booktitle empty$
    { "" }
    { editor empty$
        { " in " booktitle emphasize * }
        { " in " booktitle emphasize * ", " * format.editors * }
      if$
    }    
  if$
}

FUNCTION {format.pub.address}
{ publisher empty$
    { "" }
    { address empty$
        { publisher }
        { publisher ", " * address *}
      if$
    }    
  if$
}

FUNCTION {empty.misc.check}
{ author empty$ title empty$ howpublished empty$
  month empty$ year empty$ note empty$
  and and and and and
    { "all relevant fields are empty in " cite$ * warning$ }
    'skip$
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      type "t" change.case$
    }
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "Technical Report" }
    'type
  if$
  number empty$
    { "t" change.case$ }
    { number tie.or.space.connect }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
    { "need key or journal for " cite$ * " to crossref " * crossref *
      warning$
      ""
    }
    { "In \emph{" journal * "\/}" * }
      if$
    }
    { "In " key * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.crossref.editor}
{ editor #1 "{vv~}{ll}" format.name$
  editor num.names$ duplicate$
  #2 >
    { pop$ " \emph{et~al.}" * }
    { #2 <
    'skip$
    { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
        { " \emph{et~al.}" * }
        { " and " * editor #2 "{vv~}{ll}" format.name$ * }
      if$
    }
      if$
    }
  if$
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "In "
    }
    { "Volume" volume tie.or.space.connect
      " of " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { series empty$
        { "need editor, key, or series for " cite$ * " to crossref " *
          crossref * warning$
          "" *
        }
        { "\emph{" * series * "\/}" * }
      if$
    }
    { key * }
      if$
    }
    { format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { booktitle empty$
        { "need editor, key, or booktitle for " cite$ * " to crossref " *
          crossref * warning$
          ""
        }
        { "In \emph{" booktitle * "\/}" * }
      if$
    }
    { "In " key * }
      if$
    }
    { "In " format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  crossref missing$
    { journal emphasize "journal" output.check
      format.date "year" output.check
      volume empty$
      { ""
        format.pages.nopp output
      }
      { format.vol.pages output }
      if$
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  fin.entry
}

FUNCTION {patent}
{ output.bibitem
  organization empty$
    { format.authors "author" output.check }
    { format.authors
      " (" organization ")" * * * 
      "author" output.check 
    }
    if$
  journal emphasize "journal" output.check
  format.pages.patent "pages" output.check
  format.date "year" output.check
  fin.entry
}

FUNCTION { other } { patent }

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors.paren "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
    { "author and editor" editor either.or.check }
    'skip$
      if$
    }
  if$
  format.btitle "title" output.check
  crossref missing$
    { % Suspect these are not needed 
      % But hold on to just in case!
      % format.bvolume output 
      % format.number.series output
      format.pub.address "publisher" output.check
    }
    { format.book.crossref output.nonnull }
  if$
  format.edition output
  format.bdate "year" output.check
  new.block
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  format.authors output new.item
  format.title "title" output.check
  howpublished address new.block.checkb
  howpublished output
  address output
  format.date output
  new.block
  fin.entry
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull }
  if$
  format.in.booktitle.ed "title" output.check
  crossref missing$
    { format.pub.address "publisher" output.check
      format.bdate "year" output.check
      new.block
      format.bvolume output
      format.chapter.pages "chapter and pages" output.check
    new.block
      format.number.series output
    }
    { format.chapter.pages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  new.block
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "" output
  format.title.incoll output
  crossref missing$
    { format.in.booktitle.ed "booktitle" output.check
            format.number.series output
      new.block
      format.pub.address "publisher" output.check
      format.edition output
      format.bdate "year" output.check
    new.block
      format.bvolume output
      format.chapter.pages output
    }
    { format.incoll.inproc.crossref output.nonnull
      format.chapter.pages output
    }
  if$
  new.block
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check new.item
  crossref missing$
    { format.btitle "title" output.check
      format.number.series output
      format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.pages output
      address empty$
    { organization publisher new.sentence.checkb
      organization output
      publisher output
      format.bdate "year" output.check
    }
    { address output.nonnull
      format.bdate "year" output.check
      new.sentence
      organization output
      publisher output
    }
      if$
    }
    { format.incoll.inproc.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
    'skip$
    { organization output.nonnull
      address output
    }
      if$
    }
    {format.authors output.nonnull}
  if$
  format.btitle "title" output.check
  author empty$
    { organization empty$
    { address output
    }
    'skip$
      if$
    }
    { organization output
      address output
    }
  if$
  format.edition output
  format.date output
  new.block
  fin.entry
}


FUNCTION {mastersthesis}
{ output.bibitem
  format.authors "author" output.check
  "M.Sc.~thesis" emphasize format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  format.authors output
  format.title emphasize output
  howpublished output
  format.bdate output
  new.block
  fin.entry
  empty.misc.check
}

FUNCTION {phdthesis}
{ output.bibitem
  format.authors "author" output.check
  "Ph.D.~thesis" emphasize format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  editor empty$
    { organization output }
    { format.editors output.nonnull new.item }
  if$
  new.block
  format.btitle "title" output.check
  format.bvolume output
  format.number.series output
  address empty$
    { editor empty$
    { publisher new.sentence.checka }
    { organization publisher new.sentence.checkb
      organization output
    }
      if$
      publisher output
      format.date "year" output.check
    }
    { address output.nonnull
      format.date "year" output.check
      new.sentence
      editor empty$
    'skip$
    { organization output }
      if$
      publisher output
    }
  if$
  new.block
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  format.authors "author" output.check new.item
  format.title "title" output.check new.item
  format.tr.number output.nonnull
  institution "institution" output.check
  address output
  format.date "year" output.check
  new.block
  fin.entry
}

FUNCTION {unpublished}
{ output.bibitem
  format.authors "author" output.check
  journal empty$
    {}
    { journal emphasize "journal" output.check }
  if$
  doi empty$
    {  note output }
    {  format.date "year" output.check
       "DOI:" doi tie.or.space.connect output }
  if$
  fin.entry
}

% The next three dunctions are taken from
% achemso to provide compatiblity.  They have
% been modified to conform to the approach taken by
% the rest of this style.

FUNCTION { submitted }
{ output.bibitem
  format.authors "author" output.check
  "submitted for publication in" 
  journal emphasize space.connect "journal" output.check 
  fin.entry
}

FUNCTION { inpress }
{ output.bibitem
  format.authors "author" output.check
  journal emphasize "journal" output.check
  "in press" output
  fin.entry
}

FUNCTION { remark }
{ output.bibitem
  note "note" output.check
  fin.entry
}

FUNCTION {default.type} { misc }

MACRO {jan} {"January"}
MACRO {feb} {"February"}
MACRO {mar} {"March"}
MACRO {apr} {"April"}
MACRO {may} {"May"}
MACRO {jun} {"June"}
MACRO {jul} {"July"}
MACRO {aug} {"August"}
MACRO {sep} {"September"}
MACRO {oct} {"October"}
MACRO {nov} {"November"}
MACRO {dec} {"December"}

READ

STRINGS { longest.label }

INTEGERS { number.label longest.label.width }

FUNCTION {initialize.longest.label}
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
    { label 'longest.label :=
      label width$ 'longest.label.width :=
    }
    'skip$
  if$
}

EXECUTE {initialize.longest.label}

ITERATE {longest.label.pass}

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}
