From 8e98311e31de87f1f53f0f413708a30c331a5245 Mon Sep 17 00:00:00 2001
From: Peter Breitenlohner <peb@mppmu.mpg.de>
Date: Wed, 22 Oct 2014 13:01:50 +0000
Subject: Build lua52 as (possibly shared) Libtool library

git-svn-id: svn://tug.org/texlive/trunk@35423 c570f23f-e606-0410-a88d-b1316a301751
---
 Build/source/m4/ChangeLog           |  5 +++++
 Build/source/m4/kpse-dll-name.m4    | 34 ++++++++++++++++++++++++++++++++++
 Build/source/m4/kpse-lua52-flags.m4 |  6 +++---
 3 files changed, 42 insertions(+), 3 deletions(-)
 create mode 100644 Build/source/m4/kpse-dll-name.m4

(limited to 'Build/source/m4')

diff --git a/Build/source/m4/ChangeLog b/Build/source/m4/ChangeLog
index 9807a11635e..15d9eeada3b 100644
--- a/Build/source/m4/ChangeLog
+++ b/Build/source/m4/ChangeLog
@@ -1,3 +1,8 @@
+2014-10-22  Peter Breitenlohner  <peb@mppmu.mpg.de>
+
+	* kpse-lua52-flags.m4: Lua52 is now a Libtool library.
+	* kpse-dll-name.m4: New file to specify MinGW/Cygwin DLL names.
+
 2014-06-16  Peter Breitenlohner  <peb@mppmu.mpg.de>
 
 	* kpse-gmp-flags.m4, kpse-mpfr-flags.m4: New files.
diff --git a/Build/source/m4/kpse-dll-name.m4 b/Build/source/m4/kpse-dll-name.m4
new file mode 100644
index 00000000000..019cf0b1328
--- /dev/null
+++ b/Build/source/m4/kpse-dll-name.m4
@@ -0,0 +1,34 @@
+# Public macros for the TeX Live (TL) tree.
+# Copyright (C) 2014 Peter Breitenlohner <tex-live@tug.org>
+#
+# This file is free software; the copyright holders
+# give unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# KPSE_DLL_NAME([M32], [M64], [C32], [C64])
+# -----------------------------------------
+# Specify the DLL name for 32- and/or 64-bit MinGW and/or Cywin.
+AC_DEFUN([KPSE_DLL_NAME], [dnl
+AC_PROVIDE_IFELSE([LT_INIT], ,
+                  [m4_fatal([$0: requires libtool])])[]dnl
+AC_PROVIDE_IFELSE([LT_OUTPUT],
+                  [m4_fatal([$0: too late])])[]dnl
+AC_CHECK_SIZEOF([void *])
+AS_CASE([$host:$ac_cv_sizeof_void_p],
+        [*-*-mingw*:4], [kpse_dll_name=$1],
+        [*-*-mingw*:8], [kpse_dll_name=$2],
+        [*-*-cygwin:4], [kpse_dll_name=$3],
+        [*-*-cygwin:8], [kpse_dll_name=$4],
+        [kpse_dll_name=])
+_LT_CONFIG_SAVE_COMMANDS([## $0: Specify the DLL name
+if test "x$kpse_dll_name" != x; then
+  $SED '/^soname_spec=/a\
+## $0: Specify the DLL name\
+soname_spec='$kpse_dll_name'.dll\
+' "$ofile" >"$cfgfile"
+  mv "$cfgfile" "$ofile" ||
+    (rm -f "$ofile" && cp "$cfgfile" "$ofile" && rm -f "$cfgfile")
+  chmod +x "$ofile"
+fi], [kpse_dll_name='$kpse_dll_name'])
+]) # KPSE_DLL_NAME
+
diff --git a/Build/source/m4/kpse-lua52-flags.m4 b/Build/source/m4/kpse-lua52-flags.m4
index ff10b340253..20801945a0d 100644
--- a/Build/source/m4/kpse-lua52-flags.m4
+++ b/Build/source/m4/kpse-lua52-flags.m4
@@ -8,10 +8,10 @@
 # KPSE_LUA52_FLAGS
 # ----------------
 # Set the make variables LUA52_INCLUDES and LUA52_LIBS to the CPPFLAGS and
-# LIBS required for the `-llua52' library in libs/lua52/ of the TL tree.
+# LIBS required for the `-ltexlua52' library in libs/lua52/ of the TL tree.
 AC_DEFUN([KPSE_LUA52_FLAGS], [dnl
-_KPSE_LIB_FLAGS([lua52], [lua52], [tree],
-                [-IBLD/libs/lua52/include], [BLD/libs/lua52/liblua52.a], [],
+_KPSE_LIB_FLAGS([lua52], [texlua52], [tree],
+                [-IBLD/libs/lua52/include], [BLD/libs/lua52/libtexlua52.la], [],
                 [], [${top_builddir}/../../libs/lua52/include/lua.h])[]dnl
 ]) # KPSE_LUA52_FLAGS
 
-- 
cgit v1.2.3