1 files changed, 67 insertions, 0 deletions
diff --git a/Master/texmf-dist/fonts/source/lh/base/lgcspl.mf b/Master/texmf-dist/fonts/source/lh/base/lgcspl.mf
new file mode 100644
index 00000000000..10d16248635
--- /dev/null
+++ b/Master/texmf-dist/fonts/source/lh/base/lgcspl.mf
@@ -0,0 +1,67 @@
+%
+% lgcspl.mf
+%
+%% Cyrillic font container with T2 encoding beta-support
+%
+% This file is future part of lxfonts package
+% Version 3.4 // Patchlevel=1
+% (c) O.Lapko
+%
+% This package belongs to the public domain under conditions similar to
+% those of D. E. Knuth specified for the Computer Modern family of fonts.
+% In particular, only the authors are entitled to modify this file
+% and to save it under the same name.
+%
+% Content:
+%
+%   Metafont program for the characters in positions of ligatures
+%   for the "caps and small caps" fonts
+%
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+%   I,J
+%   if roman_ec: FI,FL,FFI,FFL fi -- for T2* stuff only (lgcsplff.mf)
+%
+
+LHver_check(3,4); % like |version_check| in ec
+
+if roman_ec:
+
+input lgcsplff.mf
+
+fi % roman_ec
+
+lhchar "Small Caps letter I";
+cyrchar(i_dotl,max(6u#,4u#+cap_stem#),cap_height#,0);
+italcorr cap_height#*slant-.25u#;
+adjust_fit(cap_serif_fit#,cap_serif_fit#);
+pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
+lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
+filldraw stroke z1e--z2e; % stem
+if serifs or slitex or monospace:
+ dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut);  % upper serif
+ dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut);  fi % lower serif
+math_fit(0,.5ic#); penlabels(1,2); endchar;
+
+lhchar "Small Caps letter J";
+cyrchar(j_dotl,9u#,cap_height#,0);
+italcorr cap_height#*slant-cap_serif_fit#
+ +.75cap_jut#-2.5u#+min(.5cap_stem#,u#);
+adjust_fit(0,cap_serif_fit#);
+pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
+top y1=h; rt x1r=hround(w-2u); x2=x1; y2=.21h;
+if serifs: pos3(vair,-90); pos4(cap_hair,-180);
+ pos5(flare+(cap_stem-stem),-180);
+ bot y3r=-o; x3=.5[x4,x2]; y5=1/6h; rt x5l=hround 2.75u; z5r=z4r;
+ filldraw stroke z1e--z2e&super_arc.e(2,3);  % stem and arc
+ dish_serif(1,2,a,1/3,1.3cap_jut,b,1/3,.75cap_jut);  % serif
+ pickup tiny.nib; bulb(3,4,5);  % bulb
+else: filldraw stroke z1e--z2e;  % stem
+ pickup fine.nib; pos3(cap_stem',0); z3=z2;
+ pos4(flare,angle(6.5u,-h)); pos5(1.1flare,-100);
+ bot y4r=-o; x4r=.5[x5r,x3r]; lft x5r=hround.75u; bot y5r=vround.06h-o;
+ filldraw stroke z3e{down}....term.e(4,5,left,1,4); fi % arc and terminal
+math_fit(0,.5ic#-.5u#); penlabels(1,2,3,4,5); endchar;
+
+endinput;
+%end of file