summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/jknappen/fc/lowera.mf
diff options
context:
space:
mode:
Diffstat (limited to 'Master/texmf-dist/fonts/source/jknappen/fc/lowera.mf')
-rw-r--r--Master/texmf-dist/fonts/source/jknappen/fc/lowera.mf222
1 files changed, 222 insertions, 0 deletions
diff --git a/Master/texmf-dist/fonts/source/jknappen/fc/lowera.mf b/Master/texmf-dist/fonts/source/jknappen/fc/lowera.mf
new file mode 100644
index 00000000000..4e722b72f5a
--- /dev/null
+++ b/Master/texmf-dist/fonts/source/jknappen/fc/lowera.mf
@@ -0,0 +1,222 @@
+% This is LOWERA.MF
+% Version 1.0a
+% Date 8-SEP-1991
+%
+% (c) 1991 by J"org Knappen. See fc.rme for copying conditions
+% This file is part of the fc-package
+% See fc.rme for more information
+%
+% J"org Knappen
+% Institut f"ur Kernphysik
+% Postfach 39 80
+% D-W 6500 Mainz
+% knappen@vkpmzd.kph.uni-mainz.de
+
+% Contents:
+%
+% The following characters are generated without condition:
+%
+% a
+%
+% And the following on demand, i. e. if their code is known:
+%
+% a_tilde, a_acute, a_grave, a_umlaut, a_hat, ae_lig
+%
+% Higher versions of this file might include more characters.
+
+cmchar "The letter a";
+beginchar("a",9u#,x_height#,0);
+bh#:=min(bar_height#,1.14x_height#-bar_height#); define_pixels(bh);
+italcorr 1/3[bh#,x_height#]*slant+.5stem#-serif_fit#-2u#;
+adjust_fit(0,serif_fit# if serifs: if hair#+.5stem#>1.5u#:-.25u# fi\\fi);
+pickup fine.nib; top y3r=h+vround 1.5oo;
+if serifs: pos1(flare,180); pos2(hair,180);
+ pos3(vair,90); lft x1r=hround max(u,2.1u-.5flare); x3=.5w-.5u;
+ y1=min(bh+.5flare+2vair+2,.9[bh,h]-.5flare);
+ bulb(3,2,1); % bulb
+else: pos1(5/7[vair,flare],95); x1l=good.x 1.5u; x1r:=good.x x1r;
+ pos3(1/8[vair,thin_join],90);
+ x3=.5w-.2u; top y1r=vround .82[bh,top y3r];
+ filldraw stroke term.e(3,1,left,.9,4); fi % terminal
+pos4(stem,0); rt x4r=hround(w-2.5u+.5stem); y4=1/3[bh,h];
+pos5(stem,0); x5=x4; y5=max(.55bh,2vair);
+filldraw stroke super_arc.e(3,4)&z4e..z5e; % arc and stem
+pos6(.3[thin_join,vair],90); x6=x4; bot y6=bh;
+pos7(hround(curve-2stem_corr),180);
+lft x7r=hround max(.5u,1.5u-.5curve); y7=1/3[top y8l,top y6r];
+pos8(vair,270); x8l=.5w-.75u; bot y8r=-oo;
+pos9(thin_join,360); z9l=z5l;
+(x,y8r)=whatever[z8l,z9l]; x8r:=max(x,x8-u);
+{{interim superness:=more_super;
+ filldraw stroke z9e{down}...z8e{left}...{up}z7e&super_arc.e(7,6)}}; % bowl
+if serifs: numeric shaved_stem; shaved_stem=hround(stem-3stem_corr);
+ if hair#+.5stem#>1.5u#: pickup tiny.nib;
+ pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
+ pos10(shaved_stem,0); x10=x5'; y10=.2[.5tiny,bh];
+ pos11(shaved_stem,0); rt x11r=hround(w-.25u); bot y11=0;
+ pos12(shaved_stem,0); x11=x12; top y12=slab+eps;
+ filldraw z5'l---z10l...z11l{right}--z11r
+ --z12r{left}...z10r+.75(z12-z11)---z5'r--cycle; % foot
+ else: pickup crisp.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
+ pos10(shaved_stem,0); x10=x5'; y10=1/3bh;
+ pos11(.2[vair,stem],90); x11r=.5[x10r,x12r]; bot y11l=-vround .5oo;
+ pos12(hair,180); rt x12l=hround(w-.1u); y12=max(y10,y11+vair);
+ pos13(hair,180); x13=x12; top y13=max(vround .6bh,top y12);
+ (x',y11l)=whatever[z11r,z12r]; x11l:=max(x',x10);
+ filldraw stroke z5'e---z10e...z11e{right}...z12e---z13e; fi % hook
+else: numeric shaved_stem; shaved_stem=hround(stem-stem_corr);
+ pickup tiny.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
+ pos10(shaved_stem,0); x10=x5'; bot y10=0;
+ filldraw stroke z5'e--z10e; fi % base of stem
+picture savedpicture;
+savedpicture:=currentpicture;
+penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
+
+iff known a_umlaut:
+cmchar "The letter a with trema";
+numeric dot_diam#,dot_diam;
+dot_diam#=max(dot_size#,cap_curve#);
+beginchar(a_umlaut,9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
+dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
+currentpicture:=savedpicture;
+pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
+x1=x2=good.x(.5w-1.75u); top y2r=h+1;
+if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
+y1=.5[y2l,y2r]; dot(1,2); % left dot
+pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=good.x(.5w+1.75u);
+dot(3,4); % right dot
+penlabels(1,2,3,4); endchar;
+
+iff known a_tilde:
+cmchar "The letter a with tilde";
+beginchar(a_tilde,9u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+currentpicture:=savedpicture;
+if serifs: numeric theta; theta=angle(1/6(6u-vair),1/4(h-x_height));
+ pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
+ pos1(vair,theta+90); pos2(vair,theta+90);
+ pos3(vair,theta+90); pos4(vair,theta+90);
+ z2-z1=z4-z3=(mid_width-crisp)*dir theta;
+ lft x1r=hround(1/6w);rt x4l=hround(5/6w); top y4r=h;
+ bot y1l=vround(bot y1l+min(2/3[x_height,h],y3l-.25vair)-top y1r);
+ pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
+ filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
+ --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
+else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
+ pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
+ lft x1r=hround(1/6w);rt x5l=hround(5/6w); x2-x1=x3-x2=x4-x3=x5-x4;
+ bot y1=bot y4l=vround(.75[x_height,h]-vair);
+ top y2r=top y5=h; y3=.5[y2,y4];
+ filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
+penlabels(1,2,3,4,5); endchar;
+
+iff known a_grave:
+cmchar "The letter a with gravis";
+beginchar(a_grave,9u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+currentpicture:=savedpicture;
+if serifs: pickup crisp.nib; x1=hround(.5w-2.5u+.5stem);
+ x2=hround(.5w+5/6u);
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ lft x1l=hround(.5w-3u); rt x2r=hround(.5w+.25u+.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+iff known a_acute:
+cmchar "The letter a with acute";
+beginchar(a_acute,9u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+currentpicture:=savedpicture;
+if serifs: pickup crisp.nib; x1=hround(.5w+2.5u-.5stem);
+ x2=hround(.5w-5/6u);
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ rt x1r=hround(.5w+3u); lft x2l=hround(.5w-.25u-.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+iff known a_hat:
+cmchar "The letter a with circumflex";
+beginchar(a_hat,9u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+currentpicture:=savedpicture;
+if serifs:
+ pickup crisp.nib; pos2(.5[vair,curve],90); top y2r=h; x2=.5w;
+ x1=good.x(.5w-2.25u); x3=good.x(.5w+2.25u); y1=y3=.5[x_height,y2];
+ pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
+ filldraw stroke z1e--z2e--z3e; % diagonals
+else:
+ pickup fine.nib; pos1(vair,0); pos3(vair,0);
+ pos2(stem,0); top y2=h; x2=.5w; bot y1=bot y3=vround 2/3[h,x_height]-eps;
+ rt x3r=hround(lft x2l+3.25u+.5vair);
+ lft x1l=hround(rt x2r-3.25u-.5vair); % same slope as in the acute accent
+ z0=whatever[z1r,z2r]=whatever[z2l,z3l];
+ y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=good.x(.2[x2r,x2]);
+ filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
+penlabels(0,1,2,3,4); endchar;
+
+savedpicture:=nullpicture;
+
+iff known ae_lig:
+cmchar "The ligature ae";
+beginchar(ae_lig,13u#,x_height#,0);
+italcorr .5[bar_height#,x_height#]*slant+.5min(curve#-1.5u#,0);
+adjust_fit(0,0);
+numeric left_curve,right_curve;
+if monospace: right_curve=left_curve=fudged.stem;
+else: left_curve=max(tiny.breadth,hround(curve-2stem_corr));
+ right_curve=max(tiny.breadth,hround(curve-if serifs:6 else:8 fi\\stem_corr));fi
+pickup tiny.nib; pos11(right_curve,0);
+pos12(vair,90); pos13(mfudged.stem,180);
+y11=good.y bar_height; top y12r=h+vround 1.5oo; y10l=bot y11;
+rt x11r=hround min(w-.5u,w-u+.5right_curve);
+lft x13r=hround (.5w-.5mfudged.stem); x12=.55[x13,x11];
+{{interim superness:=more_super;
+ filldraw stroke super_arc.e(11,12)}}; % right bowl of e
+y13=.5[y12,y14]; bot y14r=-oo; x14=x12+.25u;
+if serifs: pos14(vair',270); pos15(mfudged.hair,360);
+ y15=max(good.y(.5bar_height-.9),y14l+vair); x15r=x11r;
+ (x,y14l)=whatever[z14r,z15]; x14l:=min(x,x14l+.5u);
+ filldraw stroke pulled_arc.e(12,13)
+ & pulled_super_arc.e(13,14)(.8superpull)
+ ...{x15-x14,5(y15-y14)}z15e; % left bowl, arc, and terminal of e
+else: pos14(vair,270);
+ filldraw stroke super_arc.e(12,13)
+ & super_arc.e(13,14); % left bowl and arc of e
+ pickup fine.nib; pos14'(vair,270); z14=z14';
+ pos15(.5[vair,flare],275); rt x15r=hround(w-.6u);
+ y15r=good.y(y15r+1/3bar_height-y15); y15l:=good.y y15l; x15l:=good.x x15l;
+ filldraw stroke term.e(14',15,right,1,4); fi % right terminal
+y11'r=y10r=y10l+.6[thin_join,vair]; y11'l=y10l; x11'l=x11'r=x11; x10l=x10r=x13;
+fill stroke z10e--z11'e; % crossbar
+pickup fine.nib; top y3r=h+vround 1.5oo;
+if serifs: pos1(flare,180); pos2(mfudged.hair,180);
+ pos3(vair,90); lft x1r=hround max(u,2.1u-.5flare); x3=4u;
+ y1=min(bar_height+.5flare+2vair+2,.9[bar_height,h]-.5flare);
+ bulb(3,2,1); % bulb
+else: pos1(5/7[vair,flare],95); x1l=good.x 1.5u; x1r:=good.x x1r;
+ pos3(1/8[vair,thin_join],90);
+ x3=4.3u; top y1r=vround .82[bar_height,top y3r];
+ filldraw stroke term.e(3,1,left,.9,4); fi % left terminal
+pos4(mfudged.stem,0); x4=x13; y4=1/3[bar_height,h];
+pos5(mfudged.stem,0); x5=x4; y5=min(y4,y13);
+filldraw stroke super_arc.e(3,4)&z4e--z5e; % arc and stem
+pos6(.6[thin_join,vair],90); x6=x4; bot y6=y10l;
+pos7(left_curve,180);
+lft x7r=hround max(.5u,1.5u-.5left_curve); y7=1/3[top y8l,top y6r];
+pos8(vair,270); x8l=3.75u; bot y8r=-oo;
+pos9(.5[vair,fudged.stem],360); x9=x5; y9=.55bar_height;
+(x',y8r)=whatever[z8l,z9l]; x8r:=max(x',x8-u);
+{{interim superness:=more_super;
+ filldraw stroke z9e{down}...z8e{left}...{up}z7e&super_arc.e(7,6)}}; % bowl
+if y9<y5: filldraw stroke z5e{down}..{down}z9e; fi % link (usually hidden)
+penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15); endchar;
+
+
+
+endinput;