summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/jknappen/fc/italuvw.mf
diff options
context:
space:
mode:
Diffstat (limited to 'Master/texmf-dist/fonts/source/jknappen/fc/italuvw.mf')
-rw-r--r--Master/texmf-dist/fonts/source/jknappen/fc/italuvw.mf253
1 files changed, 253 insertions, 0 deletions
diff --git a/Master/texmf-dist/fonts/source/jknappen/fc/italuvw.mf b/Master/texmf-dist/fonts/source/jknappen/fc/italuvw.mf
new file mode 100644
index 00000000000..dfcaf0c48cd
--- /dev/null
+++ b/Master/texmf-dist/fonts/source/jknappen/fc/italuvw.mf
@@ -0,0 +1,253 @@
+% This is ITALUVW.MF
+% Version 1.0a
+% Date 8-SEP-1991
+%
+% (c) 1991 by J"org Knappen. See fc.rme for copying conditions
+% This file is part of the fc-package
+% See fc.rme for more information
+%
+% J"org Knappen
+% Institut f"ur Kernphysik
+% Postfach 39 80
+% D-W 6500 Mainz
+% knappen@vkpmzd.kph.uni-mainz.de
+
+% Contents:
+%
+% The following characters are generated without condition:
+%
+% u, v, w (v and w have sharp shapes -- in contrast to the round ones of cmti)
+%
+% And the following on demand, i. e. if their code is known:
+%
+% u_grave, u_acute, u_hat, u_tilde, u_dotu, var_u (round v), w_breve
+%
+% Higher versions of this file might include more characters.
+
+cmchar "Italic letter u";
+beginchar("u",9.5u#,x_height#,0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed); % opening hook
+pos2'(stem,-180); z2'=z2;
+pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
+pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
+x5=x6=x7; x9=w; hook_out(7,8,9); % closing hook
+y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
+filldraw stroke z2'e{-u,-x_height}
+ ...super_arc.e(3,4)...{up}z5e; % left stem and arc
+filldraw circ_stroke z6e--z7e; % right stem
+picture savedpicture;
+savedpicture:=currentpicture;
+savedpoint:=x4;
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
+penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
+
+iff known u_tilde:
+cmchar "The letter u with tilde";
+beginchar(u_tilde,9.5u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
+currentpicture:=savedpicture;
+if serifs: numeric theta; theta=angle(1/6(6u-vair),1/4(h-x_height));
+ pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
+ pos1(vair,theta+90); pos2(vair,theta+90);
+ pos3(vair,theta+90); pos4(vair,theta+90);
+ z2-z1=z4-z3=(mid_width-crisp)*dir theta;
+ lft x1r=hround(1/6w);rt x4l=hround(5/6w); top y4r=h;
+ bot y1l=vround(bot y1l+min(2/3[x_height,h],y3l-.25vair)-top y1r);
+ pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
+ filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
+ --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
+else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
+ pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
+ lft x1r=hround(1/6w);rt x5l=hround(5/6w); x2-x1=x3-x2=x4-x3=x5-x4;
+ bot y1=bot y4l=vround(.75[x_height,h]-vair);
+ top y2r=top y5=h; y3=.5[y2,y4];
+ filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
+penlabels(1,2,3,4,5); endchar;
+
+iff known u_acute:
+cmchar "The letter u with acute";
+beginchar(u_acute,9.5u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
+currentpicture:=savedpicture;
+if serifs: pickup crisp.nib; x1=hround(.5w+2.5u-.5stem);
+ x2=hround(.5w-5/6u);
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ rt x1r=hround(.5w+3u); lft x2l=hround(.5w-.25u-.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+iff known u_grave:
+cmchar "The letter u with gravis";
+beginchar(u_grave,9.5u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
+currentpicture:=savedpicture;
+if serifs: pickup crisp.nib; x1=hround(.5w-2.5u+.5stem);
+ x2=hround(.5w+5/6u);
+ y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
+ numeric theta; theta=angle(z2-z1)+90;
+ pos1(stem,theta); pos2(hair,theta);
+ filldraw circ_stroke z1e--z2e; % diagonal
+else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
+ lft x1l=hround(.5w-3u); rt x2r=hround(.5w+.25u+.5vair);
+ top y1=h; bot y2=vround 2/3[h,x_height];
+ filldraw stroke z1e--z2e; fi % diagonal
+penlabels(1,2); endchar;
+
+iff known u_hat:
+cmchar "The letter u with circumflex";
+beginchar(u_hat,9.5u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
+currentpicture:=savedpicture;
+if serifs:
+ pickup crisp.nib; pos2(.5[vair,curve],90); top y2r=h; x2=.5w;
+ x1=good.x(.5w-2.25u); x3=good.x(.5w+2.25u); y1=y3=.5[x_height,y2];
+ pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
+ filldraw stroke z1e--z2e--z3e; % diagonals
+else:
+ pickup fine.nib; pos1(vair,0); pos3(vair,0);
+ pos2(stem,0); top y2=h; x2=.5w; bot y1=bot y3=vround 2/3[h,x_height]-eps;
+ rt x3r=hround(lft x2l+3.25u+.5vair);
+ lft x1l=hround(rt x2r-3.25u-.5vair); % same slope as in the acute accent
+ z0=whatever[z1r,z2r]=whatever[z2l,z3l];
+ y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=good.x(.2[x2r,x2]);
+ filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
+penlabels(0,1,2,3,4); endchar;
+
+iff known u_dotu:
+cmchar "The letter u with dot below";
+beginchar(u_dotu,9.5u#,x_height#,0.875desc_depth#);
+italcorr 1/3x_height#*slant+.5hair#+.5u#;
+adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
+currentpicture:=savedpicture;
+pickup tiny.nib;
+pos88(flare,0); pos99(flare,90);
+x88=x99=good.x(savedpoint); bot y99l=-d-1;
+if top y99r+oo>-slab: y99r:=max(y99l+eps,-oo-tiny-slab); fi
+y88=.5[y99r,y99l];
+dot(88,99);
+penlabels(88,99); endchar;
+
+savedpicture:=nullpicture;
+numeric savedpoint;
+
+
+iff known var_u:
+cmchar "Italic letter round v"; % from cm (v)
+beginchar(var_u,8u#,x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
+x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
+hook_in(0,1,2)(skewed); % opening hook
+pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
+x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
+filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
+ ..tension atleast 1.05..{up}z5e; % left stem and arc
+v_bulb(5,6); % closing bulb
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+cmchar "Italic letter v";
+beginchar("v",8u#,x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(0,0);
+numeric left_stem,right_stem,alpha;
+left_stem=fudged.stem-stem_corr;
+right_stem=min(fudged.hair,left_stem);
+pickup tiny.nib;
+x1l=.5w-u; x4r=w-.5u; y1=y4=.57h;
+x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_oo;
+alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
+penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
+penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
+z23=whatever[z1r,z2r]=whatever[z3l,z4l];
+x[-2]=hround(.5hair)-.5hair; z0=whatever[z1,z2]; pos0(alpha*left_stem,0);
+v_hook_in([-2],[-1],0); % opening hook
+if y23>notch_cut: y23:=notch_cut;
+ fill z23+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
+ --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
+ ...{down}z23+.5left--cycle; % left and right diagonal parts
+else: fill z23--diag_end(23,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
+ --diag_end(2l,1l,1,1,1r,23)--cycle; fi % left and right diagonal parts
+pickup tiny.nib;
+z1'=z1; pos1'(alpha*left_stem,0);
+filldraw stroke z0e--z1'e;
+z4'=z4; pos4'(alpha*right_stem,0);
+v_bulb(4',5);
+penlabels([-2],[-1],0,1,2,3,4,5,23); endchar;
+
+cmchar "Italic letter w";
+beginchar("w",12u#,x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(0,0);
+numeric stem[],upper_notch,alpha,mid_corr;
+stem1=fudged.stem-stem_corr;
+stem4=min(fudged.hair,stem1);
+stem2=stem4;
+stem3=max(stem2,stem1-3stem_corr);
+pickup tiny.nib;
+x1l=1/3w-u; x8r=w-.5u;
+x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
+y1=y8=.57h; y2=y3=y6=y7=-apex_oo;
+y4=y5=if monospace: vround .6 fi\\ h; upper_notch=y4-notch_cut;
+mid_corr=if monospace:-.3apex_corr else: .5jut fi;
+alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
+penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
+penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
+penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
+penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
+x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r| $\approx$ |x4r+mid_corr|
+z23=whatever[z1r,z2r]=whatever[z3l,z4l];
+z45=whatever[z3r,z4r]=whatever[z5l,z6l];
+z67=whatever[z5r,z6r]=whatever[z7l,z8l];
+fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
+ ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
+ --(x45,upper_notch)+.5right{down} else: z45&z45 fi
+ ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
+ ...if y67>notch_cut:(x67,notch_cut)+.5right{down}
+ --(x67,notch_cut)+.5left{up} else: z67&z67 fi
+ ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
+ ...if y23>notch_cut:(x23,notch_cut)+.5right{down}
+ --(x23,notch_cut)+.5left{up} else: z23&z23 fi
+ ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle; % diagonals
+pickup tiny.nib;
+z8'=z8; pos8'(alpha*stem4,0);
+v_bulb(8',9); % closing bulb
+x[-2]=hround(.5hair)-.5hair;
+z99=whatever[z1,z2]; % z0 is hidden in special_diag_end
+pos99(alpha*stem1,0);
+v_hook_in ([-2],[-1],99); % opening hook
+z1'=z1; pos1'(alpha*stem1,0);
+filldraw stroke z99e--z1'e; % join
+picture savedpicture;
+savedpicture:=currentpicture;
+penlabels([-2],[-1],0,1,2,3,4,5,6,7,8,9,23,45,67,99); endchar;
+
+iff known w_breve:
+cmchar "The letter w with breve";
+beginchar(w_breve,13u#,.75[x_height#,min(asc_height#,2x_height#)],0);
+italcorr x_height#*slant+.25u#;
+adjust_fit(serif_fit#,serif_fit#);
+currentpicture:=savedpicture;
+pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
+top y1=top y3=h; lft x1r=hround(.5w-2.5u-.5vair);x3r=hround(.5w+2.5u+.5vair);
+numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
+pos2(mid_thickness,-90); x2=.5w;
+bot y2r=vround max(x_height+o+tiny,1/3[x_height,h]+o-.5mid_thickness);
+filldraw stroke z1e{down}...z2e{right}...{up}z3e; % stroke
+penlabels(1,2,3); endchar;
+
+savedpicture:=nullpicture;
+
+endinput;