summaryrefslogtreecommitdiff
path: root/Master/texmf-dist/fonts/source/jknappen/fc/italpqr.mf
diff options
context:
space:
mode:
Diffstat (limited to 'Master/texmf-dist/fonts/source/jknappen/fc/italpqr.mf')
-rw-r--r--Master/texmf-dist/fonts/source/jknappen/fc/italpqr.mf96
1 files changed, 96 insertions, 0 deletions
diff --git a/Master/texmf-dist/fonts/source/jknappen/fc/italpqr.mf b/Master/texmf-dist/fonts/source/jknappen/fc/italpqr.mf
new file mode 100644
index 00000000000..a2dc92c2671
--- /dev/null
+++ b/Master/texmf-dist/fonts/source/jknappen/fc/italpqr.mf
@@ -0,0 +1,96 @@
+% This is ITALPQR.MF
+% Version 1.1a
+% Date 13-MAR-1992
+%
+% (c) 1991, 1992 by J"org Knappen. See fc.rme for copying conditions
+% This file is part of the fc-package
+% See fc.rme for more information
+%
+% J"org Knappen
+% Institut f"ur Kernphysik
+% Postfach 39 80
+% D-W 6500 Mainz
+% knappen@vkpmzd.kph.uni-mainz.de
+
+% Contents:
+%
+% The following characters are generated without condition:
+%
+% p, q, r
+%
+% And the following on demand, i. e. if their code is known:
+%
+% hooktop_p
+%
+% Higher versions of this file might include more characters.
+
+cmchar "Italic letter p";
+beginchar("p",9u#,x_height#,desc_depth#);
+italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
+adjust_fit(0,0); pickup fine.nib;
+x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2); % opening hook
+pos4(hair,-180); pos5(vair,-90); pos6(curve,0); pos7(vair,90);
+x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
+bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
+filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
+ & pulled_arc.e(6,7) & super_arc.e(7,4); % bowl
+pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
+z2=z2'; x3=x2; bot y3=-d; filldraw stroke z2'e--z3e; % stem
+dish_serif(3,2',a,1/3,.75jut,b,1/3,jut); % serif
+math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
+ 2u#-.5stem#-desc_depth#*slant),ic#);
+numeric savedpoint; savedpoint=x7;
+picture savedpicture; savedpicture=currentpicture;
+penlabels(0,1,2,3,4,5,6,7); endchar;
+
+iff known hooktop_p:
+cmchar"Italic letter hooktop p"; % jk
+beginchar(hooktop_p,9u#,asc_height#,desc_depth#);
+italcorr asc_height#*slant-.7u#;
+adjust_fit(0,0);
+currentpicture:=savedpicture;
+pos0(stem,180); pos1(stem,180); pos2(vair,90);
+pos3(hair,0); pos4(flare,0);
+x0=x1=savedpoint; y1=.8h; y0=x_height;
+x2=.4[x1,x3]; top y2r=h+oo;
+rt x3r=hround(w-.7u); y4=.85h;
+filldraw z2r{left}...{down}z1r--z0r--z0l--z1l{up}...{right}z2l--cycle;
+bulb(2,3,4);
+penlabels(0,1,2,3,4); endchar;
+
+numeric savedpoint;
+savedpicture:=nullpicture;
+
+cmchar "Italic letter q";
+beginchar("q",8u#,x_height#,desc_depth#);
+italcorr x_height#*slant+.5stem#-u#;
+adjust_fit(0,0); pickup fine.nib;
+pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
+x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
+x4+.5stem=hround(w-1.5u+.5stem)+eps;
+top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
+filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
+ & pulled_arc.e(2,3) & super_arc.e(3,0); % bowl
+pickup tiny.nib; pos4(stem,0); pos5(stem,0);
+x4=x5; x6=x5r; top y6=h+oo; bot y4=-d;
+y5=ypart(((x4l,0)--(x4l,y6))intersectionpoint super_arc.r(0,1));
+filldraw z6{2(x5l-x6),y5-y6}...z5l---z4l--z4r--cycle; % stem
+dish_serif(4,5,a,1/3,jut,b,1/3,jut); % serif
+math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
+penlabels(0,1,2,3,4,5,6,7,8); endchar;
+
+cmchar "Italic letter r";
+beginchar("r",5.5u#+max(1.75u#,flare#),x_height#,0);
+italcorr x_height#*slant;
+adjust_fit(if monospace:.25u#,.5u# else: 0,0 fi); pickup fine.nib;
+x0=0; x2=x3; pos3(stem,0); lft x3l=hround(2.5u-.5stem); y3-.5stem=-oo;
+hook_in(0,1,2); % opening hook
+filldraw circ_stroke z3e--z2e; % left stem
+pos3'(hair,180); z3'=z3; pos4(vair,90); pos5(hair,0); pos6(flare,0);
+x4=w-.5u-max(1.75u,flare); rt x5r=hround(r-.5u); top y4r=h+oo;
+filldraw stroke z3'e{up}...z4e{right}; % link
+y6+.5flare=vround(bot y4l-.03x_height); bulb(4,5,6); % bulb
+math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-.5u#);
+penlabels(0,1,2,3,4,5,6); endchar;
+
+endinput;