prepare for new build system

git-svn-id: svn://tug.org/texlive/trunk@12429 c570f23f-e606-0410-a88d-b1316a301751

1 files changed, 34 insertions, 0 deletions

diff --git a/Build/source/texk/dvipdfm/m4/maw-time.m4 b/Build/source/texk/dvipdfm/m4/maw-time.m4
new file mode 100644
index 00000000000..91a6c005ddd
--- /dev/null
+++ b/Build/source/texk/dvipdfm/m4/maw-time.m4
@@ -0,0 +1,34 @@
+# maw-time.m4 - timezone tests
+# Copyright (C) 1998 - 2009 Mark A. Wicks <mwicks@kettering.edu>
+# Kettering University
+#
+# This file is free software; the copyright holder
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# serial 2
+
+# MAW_EXT_TIMEZONE
+# ----------------
+AC_DEFUN([MAW_EXT_TIMEZONE],
+[AC_MSG_CHECKING([whether time.h defines timezone as an external variable])
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]],
+                                 [[-timezone;]])],
+                [AC_MSG_RESULT([yes])
+                 AC_DEFINE([HAVE_TIMEZONE], 1,
+                           [Define if <time.h> has timezone as an external variable.])],
+                [AC_MSG_RESULT([no])])
+])# MAW_EXT_TIMEZONE
+
+# MAW_TM_HAS_TM_GMTOFF
+# --------------------
+AC_DEFUN([MAW_TM_HAS_TM_GMTOFF],
+[AC_MSG_CHECKING([whether struct tm has tm_gmtoff as a member])
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]],
+                                 [[struct tm *tp; tp->tm_gmtoff;]])],
+                [AC_MSG_RESULT([yes])
+                 AC_DEFINE([HAVE_TM_GMTOFF], 1,
+                           [Define if struct tm has tm_gmtoff as a member.])],
+                [AC_MSG_RESULT([no])])
+])# MAW_TM_HAS_TM_GMTOFF
+