summaryrefslogtreecommitdiff
path: root/Build/source/libs/harfbuzz/configure.ac
diff options
context:
space:
mode:
authorPeter Breitenlohner <peb@mppmu.mpg.de>2012-11-30 10:42:45 +0000
committerPeter Breitenlohner <peb@mppmu.mpg.de>2012-11-30 10:42:45 +0000
commitcdae43322cc315a65b9bee9f62b2e28934fefa6a (patch)
tree18a8ae660cb1dc7d1136962b4e8dcbccad5b873d /Build/source/libs/harfbuzz/configure.ac
parent156b1ea47fd003feee19afbb34c0e85e596b54dc (diff)
libs/harfbuzz: Added for future XeTeX
git-svn-id: svn://tug.org/texlive/trunk@28390 c570f23f-e606-0410-a88d-b1316a301751
Diffstat (limited to 'Build/source/libs/harfbuzz/configure.ac')
-rw-r--r--Build/source/libs/harfbuzz/configure.ac89
1 files changed, 89 insertions, 0 deletions
diff --git a/Build/source/libs/harfbuzz/configure.ac b/Build/source/libs/harfbuzz/configure.ac
new file mode 100644
index 00000000000..62509da69ed
--- /dev/null
+++ b/Build/source/libs/harfbuzz/configure.ac
@@ -0,0 +1,89 @@
+dnl Process this file with autoconf to produce a configure script.
+dnl
+dnl Copyright (C) 2012 Peter Breitenlohner <tex-live@tug.org>
+dnl
+dnl This file is free software; the copyright holder
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+dnl
+m4_include([version.ac])[] dnl define harfbuzz_version
+AC_INIT([harfbuzz for TeX Live], harfbuzz_version, [tex-k@tug.org])
+AC_PREREQ([2.65])
+AC_CONFIG_SRCDIR([harfbuzz-]harfbuzz_version[/harfbuzz.pc.in])
+AC_CONFIG_AUX_DIR([../../build-aux])
+AC_CONFIG_MACRO_DIR([../../m4])
+
+AM_INIT_AUTOMAKE([foreign])
+AM_MAINTAINER_MODE
+
+KPSE_LIB_VERSION([harfbuzz])[]dnl
+AC_SUBST([HB_VERSION_MAJOR], [harfbuzz_major])[]dnl
+AC_SUBST([HB_VERSION_MINOR], [harfbuzz_minor])[]dnl
+AC_SUBST([HB_VERSION_MICRO], [harfbuzz_micro])[]dnl
+AC_SUBST([HB_VERSION], [harfbuzz_version])[]dnl
+
+AC_PROG_CC
+AC_PROG_CXX
+AC_PROG_RANLIB
+AC_PROG_LN_S
+
+KPSE_COMPILER_WARNINGS
+
+LT_INIT
+
+KPSE_FREETYPE2_FLAGS
+dnl not yet KPSE_GRAPHITE2_FLAGS
+KPSE_ICU_FLAGS
+
+# Functions and headers
+AC_CHECK_FUNCS([atexit mprotect sysconf getpagesize sched_yield mmap _setmode isatty])
+AC_CHECK_HEADERS([unistd.h sys/mman.h sched.h io.h])
+
+AC_CONFIG_HEADERS([config.h])
+
+AM_CONDITIONAL([build], [test "x$enable_build" != xno])
+
+if test "x$enable_build" != xno || test -f config.force; then
+
+KPSE_ADD_FLAGS([freetype2])
+AC_CHECK_FUNC([FT_Face_GetCharVariantIndex], , [AC_ERROR([FT_Face_GetCharVariantIndex() not found])])
+KPSE_RESTORE_FLAGS
+
+echo timestamp >config.force
+fi
+
+if :; then
+ AC_DEFINE([HAVE_OT], 1, [Use native OpenType Layout backend])
+ AC_DEFINE([HAVE_ICU], 1, [Use ICU library])
+dnl not yet AC_DEFINE([HAVE_GRAPHITE2], 1, [Use Graphite library])
+ AC_DEFINE([HAVE_FREETYPE], 1, [Use FreeType 2 library])
+ AC_DEFINE([HAVE_FT_FACE_GETCHARVARIANTINDEX], 1,
+ [Define to 1 if you have the `FT_Face_GetCharVariantIndex' function.])
+else
+dnl add all these to config.h.in but do not define them in config.h
+ AC_DEFINE([HAVE_PTHREAD], 1, [Use POSIX threads])
+ AC_DEFINE([HAVE_HB_OLD], 1, [Use Old HarfBuzz backend])
+ AC_DEFINE([HAVE_UCDN], 1, [Use UCDN Unicode functions])
+ AC_DEFINE([HAVE_GLIB], 1, [Use glib2 library])
+ AC_DEFINE([HAVE_GTHREAD], 1, [Use gthread2 library])
+ AC_DEFINE([HAVE_GOBJECT], 1, [Use gobject2 library])
+ AC_DEFINE([HAVE_CAIRO], 1, [Use cairo graphics library])
+ AC_DEFINE([HAVE_CAIRO_FT], 1, [Use cairo-ft support in cairo graphics library])
+ AC_DEFINE([HAVE_ICU_LE], 1, [Use ICU Layout Engine library])
+ AC_DEFINE([HAVE_GRAPHITE2], 1, [Use Graphite library])
+ AC_DEFINE([HAVE_UNISCRIBE], 1, [Use Uniscribe backend])
+ AC_DEFINE([HAVE_CORETEXT], 1, [Use Core Text backend])
+ AC_DEFINE([HAVE_INTEL_ATOMIC_PRIMITIVES], 1, [Use Intel __sync_* atomic primitives])
+fi
+
+AC_SUBST([HARFBUZZ_TREE], [harfbuzz-]harfbuzz_version)
+
+if test -f $srcdir/$HARFBUZZ_TREE/src/hb-version.h; then
+ AC_MSG_ERROR([Sorry, you must remove the file $HARFBUZZ_TREE/src/hb-version.h])
+fi
+
+AC_CONFIG_FILES([Makefile
+ include/Makefile
+ hb-version.h:harfbuzz-]harfbuzz_version[/src/hb-version.h.in])
+
+AC_OUTPUT