1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% mfdigits.mf - a set of digits for the MFLOGO font
%
% This file is designed to be |input| by `mflogo.mf'.
%
% Damian Cugley <pdc@oxford.prg> Fri 15 Dec 1989
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginlogodigit("0");
x.O1=x.O3=.5w; top y.O1=h+o; bot y.O3=-o; % points at top and bottom
x.O4=w-x.O2=good.x(1.5u+s); y.O2=y.O4=barheight; % points in middle
super_points(O);
draw super_arc(O)(1,1',2,2',3,3',4,4',1) & cycle;
penlabels(O1,O1',O2,O2',O3,O3',O4,O4');
endchar;
beginlogodigit("1");
% Note that I am including serifs in this character...
if 1/2w <> good.x 1/2w: change_width; fi % Assure symmetry
x1 = x2 = 1/2w; top y1 = h + o; bot y2 = 0; % Points at ends of vertical
x3 = x4 = w - x5 = leftstemloc; % points at ends of serifs
y4 = y5 = y2; y3 = 2/3[barheight,h];
draw z3{right} .. z1{up} & z1 -- z2;
draw z4 -- z5;
penlabels(1,2,3,4,5);
endchar;
beginlogodigit("2");
% Define points on top part of curve:
x.T1 = x.T3 = 1/2w; top y.T1 = h+o; bot y.T3 = 0.8barheight;
x.T4 = w - x.T2 = good.x(1.5u + s); y.T2=y.T4=0.45[barheight,h];
super_points(T);
% define points on bottom part (B) and stroke(S):
z.B1 = z.T3;
x.B4 = w - x.B2 = x.T4; bot y.B4 = 0 = bot y.B2; super_points(B);
draw super_arc(T)(4,4',1,1',2,2',3) &
(reverse (super_arc(B)(4,4',1))) -- z.B2;
;
penlabels(T1,T1',T2,T2',T3,T4',T4,B4',B4,B2);
endchar;
beginlogodigit("3");
% Define points on top part of curve:
x.T1 = x.T3 = 1/2w; top y.T1 = h+o; bot y.T3 = barheight;
x.T4 = w - x.T2 = good.x(1.5u + s); y.T2=y.T4=0.45[y.T3,y.T1];
super_points(T);
% define points on bottom part (B) and stroke(S):
z.B1 = z.T3; x.B3 = x.B1; bot y.B3 = 0;
x.B4 = w - x.B2 = x.T4; y.B4 = y.B2 = 0.45[y.B3,y.B1];
super_points(B);
draw super_arc(T)(4,4',1,1',2,2',3) &
super_arc(B)(1,1',2,2',3,3',4);
penlabels(T1,T1',T2,T2',T3,T4',T4,B1,B1',B2,B2',B3,B3',B4)
endchar;
|