summaryrefslogtreecommitdiff
path: root/fonts/schulschriften/source/weva
diff options
context:
space:
mode:
Diffstat (limited to 'fonts/schulschriften/source/weva')
-rw-r--r--fonts/schulschriften/source/weva/weva14.mf69
-rw-r--r--fonts/schulschriften/source/weva/weva14_def.mf409
-rw-r--r--fonts/schulschriften/source/weva/weva14_gr.mf260
-rw-r--r--fonts/schulschriften/source/weva/weva14_kl.mf314
-rw-r--r--fonts/schulschriften/source/weva/weva14_lig.mf246
-rw-r--r--fonts/schulschriften/source/weva/weva14_sz.mf405
-rw-r--r--fonts/schulschriften/source/weva/wevabx14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevabxsl14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevaeb14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevaebsl14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevasb14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevasbsl14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevasl14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevaub14.mf3
-rw-r--r--fonts/schulschriften/source/weva/wevaubsl14.mf3
15 files changed, 1730 insertions, 0 deletions
diff --git a/fonts/schulschriften/source/weva/weva14.mf b/fonts/schulschriften/source/weva/weva14.mf
new file mode 100644
index 0000000000..045b5430ad
--- /dev/null
+++ b/fonts/schulschriften/source/weva/weva14.mf
@@ -0,0 +1,69 @@
+% Vereinfachte Ausgangsschrift weva
+% Driver-File
+% Walter Entenmann
+% 05.09.2011
+% 13.09.2012
+%
+font_identifier "WEVA";
+font_size 14pt#;
+font_coding_scheme:="WEVA text";
+
+mode_setup;
+
+% Vereinbarungen:
+path p, q;
+
+%
+% sharp Variables:
+% unit_width
+ut#:=0.233pt#;
+% Linienabstand, 1:1:1
+ht# := 20ut#;
+dt# := ht#;
+Ht# := ht#+dt#;
+
+% Umrechnung von sharp Variablen in Pixelgroessen:
+define_pixels(ut,ht,Ht,dt);
+
+if unknown fetter: fetter:=0; fi
+fetter:=sqrt(2)**fetter;
+% Federn:
+ pickup pencircle scaled (fetter*1.25*ut);
+weva_pen := savepen;
+% fuer i-Punkte etc.
+if fetter>3: pickup pencircle scaled 7ut;
+ elseif fetter>2.5: pickup pencircle scaled 5ut;
+ else:
+ pickup pencircle scaled 3.5ut;
+ fi
+weva_pen_thick := savepen;
+%
+
+% Current Transformation, slanted
+if unknown slant: slant:=0; else: currenttransform:=identity slanted slant; fi
+
+
+% Fontbeswchreibungen der einzelnen Zeichen:
+% Parameter- und Makrodefinitionen
+input weva14_def;
+% Grossbuchstaben
+input weva14_gr;
+% Kleinbuchstaben
+ input weva14_kl;
+% Sonderzeichen
+input weva14_sz;
+
+% Abstandsmasse:
+font_quad 14pt#;% 1em
+font_x_height := 4.667pt#; % 1ex
+font_normal_space 5pt#; % Wortzwischenraum
+font_normal_stretch 2pt#;
+font_normal_shrink 1pt#;
+
+boundarychar:=oct"040"; % space
+
+% Ligaturtabellen
+input weva14_lig;
+
+end
+%%%%%%%% Ende weva14 Metafont-Hauptfile (Driver-File) %%%%%%%
diff --git a/fonts/schulschriften/source/weva/weva14_def.mf b/fonts/schulschriften/source/weva/weva14_def.mf
new file mode 100644
index 0000000000..516d9182e0
--- /dev/null
+++ b/fonts/schulschriften/source/weva/weva14_def.mf
@@ -0,0 +1,409 @@
+% Definitionen fuer weva Vereinfchte Ausgangsschrift (VA)
+% Walter Entenmann
+% 06.09.2011
+% 13.09.2012
+%
+% Parameter und Makros
+% Math. Sonderzeichen
+hmath:=ht/2;
+hdash:=ht/2;
+
+% Steigung des Verbindungsstrichs
+m:=4/3;
+
+% Superellipse (klein)
+b:=ht/2;
+a:=7ut;
+k:=b/a;
+sigma:=0.73345;
+% Superellipse (gross)
+ B:=Ht/2;
+ A:=13.75ut;
+ K:=B/A;
+ Sigma:=sigma;
+% Rundungsradius bei Stock, etc.
+r:=3.5ut;
+fr:=1;
+% "b"
+db:=2.5ut;
+mb:=2.5;
+% Oberschleife, Unterschleife; Breite, Faktor
+sb:=9ut;
+fs:=0.4;
+% Fahnenbreiten
+fahnekurz:=12ut; % fuer r,x
+fahnemittel:=13ut; % fuer o,v,w
+fahnelang:=15ut; % fuer b
+% Ansatz beim scharfen s, etc.
+nase:=1.5ut;
+% Ansatz beim q
+qnase:=1.5ut;
+% Fundamentale Breiten
+ H_breit:=22.5ut;
+ N_breit:=25ut;C:=N_breit/2;
+ O_breit:=2*A;
+ V_breit:=30ut;
+
+% Anlauf bei A, M etc
+xauf=8.5ut; mxauf:=6ut;
+yauf=3.5ut;
+
+% Spornbreite, horiz.Teile bei B, D, etc.
+ sporn:=6ut;
+ flach:=sporn; % fuer B
+ Flach:=10ut; % fuer B
+
+% Steigung bei 8
+ macht:=1/3;
+
+%
+% Delta, delta
+x1:=whatever;y1:=whatever;
+ x2:=whatever;y2:=whatever;
+ x5:=whatever;y5:=whatever;
+ z1=(0,b); z2=(-a,0);
+ z5=(-sigma*a,sigma*b);
+ p := z1{left}..z5{z2-z1}..{down}z2;
+ x0:=whatever;y0:=whatever;
+ z0=(directionpoint(1,m) of (reverse (subpath (0,2) of p)));
+ delta:=a+x0;Delta:=b-y0;
+
+%
+ def oval (expr sx) =
+ x1:=whatever;y1:=whatever;
+ x2:=whatever;y2:=whatever;
+ x3:=whatever;y3:=whatever;
+ x4:=whatever;y4:=whatever;
+ x5:=whatever;y5:=whatever;
+ x6:=whatever;y6:=whatever;
+ x7:=whatever;y7:=whatever;
+ x8:=whatever;y8:=whatever;
+ z1=(0,b); z2=(-a,0); z3=(0,-b); z4=(a,0);
+ z5=(-sigma*a,sigma*b);
+ z6=(-sigma*a,-sigma*b);
+ z7=(sigma*a,-sigma*b);
+ z8=(sigma*a,sigma*b);
+ draw (z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..z3{right}..z7{z4-z3}..z4{up}..z8{z1-z4}..cycle)
+ shifted (sx+a-delta,b);
+ xpos:=sx+2*a-delta;
+ enddef;
+
+ def Oval (expr sx) =
+ x1:=whatever;y1:=whatever;
+ x2:=whatever;y2:=whatever;
+ x3:=whatever;y3:=whatever;
+ x4:=whatever;y4:=whatever;
+ x5:=whatever;y5:=whatever;
+ x6:=whatever;y6:=whatever;
+ x7:=whatever;y7:=whatever;
+ x8:=whatever;y8:=whatever;
+ z1=(0,B); z2=(-A,0); z3=(0,-B); z4=(A,0);
+ z5=(-Sigma*A,Sigma*B);
+ z6=(-Sigma*A,-Sigma*B);
+ z7=(Sigma*A,-Sigma*B);
+ z8=(Sigma*A,Sigma*B);
+ draw (z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..z3{right}..z7{z4-z3}..z4{up}..z8{z1-z4}..cycle)
+ shifted (sx+A,B);
+ xpos:=sx+2*A;
+ enddef;
+
+
+ def stamm (expr ha, hb, sx)=
+ draw ((0,ha)--(0,hb)) shifted (sx,0);
+ xpos:=sx;
+ enddef;
+
+ def strich(expr sx) =
+ draw ((0,0)--((ht-Delta)/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+(ht-Delta)/m;
+ enddef;
+
+ % Ansatz beim q
+ def qansatz (expr sx)=
+ draw ((0,-5ut){up}..{1,m}(qnase,0)) shifted (sx,0);
+ xpos:=sx+qnase;
+ enddef;
+
+ % Ansatz beim scharfen s
+ def ansatz (expr sx)=
+ draw ((0,ht)..{down}(nase,ht-5ut)) shifted (sx,0);
+ xpos:=sx+nase;
+ enddef;
+
+def stock(expr sx) =
+ draw ((0,r){down}..(r*fr,0){right}..tension2 and 4.5..{1,m}(ht-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+ht-Delta/m;
+enddef;
+
+ def gerade (expr hl, hr, abstand, sx)=
+ draw ((0,hl)--(abstand,hr)) shifted (sx,0);
+ xpos:=sx+abstand;
+ enddef;
+
+def ipunkt(expr sx) =
+ pickup weva_pen_thick;
+ drawdot (0,0) shifted (sx,ht+7.5ut);
+ pickup weva_pen;
+ xpos:=sx;
+enddef;
+
+def umlaut (expr dx,sx) =
+ pickup weva_pen_thick;
+drawdot (0,0) shifted (sx+dx,ht+7.5ut);
+drawdot (0,0) shifted (sx+dx+10ut,ht+7.5ut);
+pickup weva_pen;
+ xpos:=sx;
+ enddef;
+
+def Umlaut (expr dx,sx) =
+ pickup weva_pen_thick;
+drawdot (0,0) shifted (sx+dx,Ht+5ut);
+drawdot (0,0) shifted (sx+dx+6.5ut,Ht+5ut);
+pickup weva_pen;
+ xpos:=sx;
+ enddef;
+
+ def c_form (expr sx) =
+ x1:=whatever;y1:=whatever;
+ x2:=whatever;y2:=whatever;
+ x3:=whatever;y3:=whatever;
+ x4:=whatever;y4:=whatever;
+ x5:=whatever;y5:=whatever;
+ x6:=whatever;y6:=whatever;
+ x7:=whatever;y7:=whatever;
+ x8:=whatever;y8:=whatever;
+ z1=(0,b); z2=(-a,0); z3=(0,-b); z4=(a,0);
+ z5=(-sigma*a,sigma*b);
+ z6=(-sigma*a,-sigma*b);
+ z7=(sigma*a,-sigma*b);
+ z8=(sigma*a,sigma*b);
+ draw (z8{z1-z4}..z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..{right}z3)
+ shifted (sx+a-delta,b);
+ xpos:=sx+a-delta;
+ enddef;
+
+ def schweif (expr hl, hr, bt, phil, phir, tens, sx) =
+ p := (0,hl){dir phil}..tension tens..{dir phir}(bt,hr);
+ draw p shifted (sx,0);
+ xpos:=sx+bt;
+% if wmax<xpos: wmax:=xpos; fi
+enddef;
+
+def halbellipse(expr sx) =
+ x1:=whatever;y1:=whatever;
+ x2:=whatever;y2:=whatever;
+ x3:=whatever;y3:=whatever;
+ x5:=whatever;y5:=whatever;
+ x6:=whatever;y6:=whatever;
+ z1=(0,b); z2=(-a,0); z3=(0,-b);
+ z5=(-sigma*a,sigma*b);
+ z6=(-sigma*a,-sigma*b);
+ draw (z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..{right}z3)
+ shifted (sx+a-delta,b);
+ xpos:=sx+a-delta;
+ enddef;
+
+ def ekopf(expr sx) =
+ draw ((0,ht){right}..(3.5ut,ht-6ut){down}..(-1.5ut,ht-12ut){left}..{1,m}(-a+delta,ht-Delta)) shifted (sx,0);
+ xpos:=sx;
+ enddef;
+
+ def oschl(expr sx) =
+ draw ((0,ht){1,m}..(sb,Ht-fs*sb){up}..(sb*(1-fs),Ht){left}..tension1.5..{down}(0,ht)) shifted (sx,0);
+ xpos:=sx;
+ enddef;
+
+ def uschl (expr sx) =
+ draw ((0,0){down}..tension1.5..(-(1-fs)*sb,-dt){left}..(-sb,-dt+fs*sb){up}..{1,m}(0,0)) shifted (sx,0);
+ xpos:=sx;
+ enddef;
+
+ def bbauch (expr sx) =
+ draw ((0,ht){down}..(a,0){right}..(2*a,ht/2){up}..{-1,mb}(2*a-db,ht)) shifted (sx,0);
+ xpos:=sx+2*a-db;
+ enddef;
+
+% Hermite-Interpolation, 2 Intervalle
+% Scheitelpunkt bei (fx*b,hm)
+def bogen (expr hl, hm, hr, b, fx, phil, phir, tensl, tensr, sx) =
+ p := (0,hl){dir phil}..tension tensl..(fx*b,hm){b/abs(b),0}..tension tensr..{dir phir}(b,hr);
+ draw p shifted (sx,0);
+ xpos:=sx+b;
+% if wmax<xpos: wmax:=xpos; fi
+enddef;
+
+def nbogen=
+bogen(ht/4,ht,3*ht/4,2*a,0.75,90,-90,1.2,1,xpos);
+enddef;
+
+def ubogen=
+bogen(ht/3,0,3*ht/4,2*a,0.375,-90,90,1,1,xpos);
+ enddef;
+
+def k_form (expr sx) =
+ draw ((0,ht/4){up}..(10ut,ht){right}..(15ut,15ut){down}..{left}(5ut,ht/2)--(15ut-r/sqrt2,(1-1/sqrt2)*r)..{right}(15ut,0)) shifted (sx,0);
+ xpos:=sx+15ut;
+enddef;
+
+def s_form (expr sx) =
+ draw ((0,ht){1,-m}..(7.5ut,7.5ut){down}..(0,0){left}..(-5ut,2.5ut)) shifted (sx,0);
+ xpos:=sx+7.5ut;
+enddef;
+
+def s_char (expr sx) =
+ draw ((0,ht){1,-m}..(7.5ut,5ut){down}..(3.75ut,0){left}..(0,5ut){up}..
+ tension1.5..{1,m}(ht-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+ht-Delta/m;
+enddef;
+
+def st_char (expr sx) =
+ draw ((0,ht){1,-m}..(7.5ut,5ut){down}..(3.75ut,0){left}..(0,5ut){up}..
+ tension1..{1,m}(10ut,ht)..(20ut,Ht){up}) shifted (sx,0);
+ draw ((20ut,Ht)--(20ut,0)) shifted (sx,0);
+ draw ((12.5ut,6ut)..(20ut,3.5ut){right}..tension1.2..{1,m}(40ut-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+20ut+20ut-Delta/m;
+enddef;
+
+def t_char (expr sx) =
+ draw ((0,ht){1,m}..{up}(10ut,Ht)) shifted (sx,0);
+ draw ((10ut,Ht)--(10ut,0)) shifted (sx,0);
+draw ((0,7.5ut)..(10ut,3.5ut){right}..tension1.2..{1,m}(30ut-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+30ut-Delta/m;
+enddef;
+
+def x_form (expr sx)=
+ draw ((2*a-15ut,0)--(2*a,ht)) shifted (sx,0);
+ draw ((0,ht)--(2*a,0)) shifted (sx,0);
+ xpos:=sx+2*a;
+enddef;
+
+def z_char (expr sx)=
+ draw ((0,ht-Delta){1,m}..(5ut,ht){right}..(10ut,ht-5ut){down}..{-1,-0.75}(0,3ut)) shifted (sx,0);
+ draw ((0,3ut){1,0.75}..(10ut,-5ut){down}..tension1.5..(3ut,-dt){left}..(0,-15ut){up}..tension1.5..{1,m}(9ut,0)--(24ut-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+24ut-Delta/m;
+ enddef;
+
+ def tz_char (expr sx)=
+ draw ((0,ht){1,m}..{up}(10ut,Ht)) shifted (sx,0);
+ draw ((10ut,Ht)--(10ut,0)) shifted (sx,0);
+ draw ((5ut,ht-7.5ut){1,0.7}..(25ut,ht){right}..(30ut,ht-5ut){down}..{-1,-0.75}(20ut,3ut)) shifted (sx,0);
+ draw ((20ut,3ut){1,0.75}..(30ut,-5ut){down}..tension1.5..(23ut,-dt){left}..(20ut,-15ut){up}..tension1.5..{1,m}(29ut,0)--(44ut-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+44ut-Delta/m;
+ enddef;
+
+% scharfes s am Wortende
+ def ss_form(expr sx)=
+ draw ((0,-dt)--(0,ht){up}..tension1.5..(8ut,Ht){right}..(14ut,Ht-6ut){down}..(5ut,ht){-1,-1}) shifted (sx,0);
+ draw ((5ut,ht){1,-0.7}..(17.5ut,7.5ut){down}..(10ut,0){left}..(5ut,2.5ut)) shifted (sx,0);
+ xpos:=sx+17.5ut;
+ enddef;
+
+% scharfes s im Wort
+ def ss_char (expr sx)=
+ draw ((0,-dt)--(0,ht){up}..tension1.5..(8ut,Ht){right}..(14ut,Ht-6ut){down}..(5ut,ht){-1,-1}) shifted (sx,0);
+ draw ((5ut,ht){1,-0.7}..(17.5ut,5ut){down}..(14ut,0){left}..(10ut,5ut){up}..tension2.5..{1,m}(27.5ut-Delta/m,ht-Delta)) shifted (sx,0);
+ xpos:=sx+27.5ut-Delta/m;
+ enddef;
+
+ def sst_char (expr sx)=
+ draw ((0,-dt)--(0,ht){up}..tension1.5..(8ut,Ht){right}..(14ut,Ht-6ut){down}..(5ut,ht){-1,-1}) shifted (sx,0);
+ draw ((5ut,ht){1,-0.7}..(17.5ut,5ut){down}..(14ut,0){left}..(10ut,5ut){up}..tension1..{1,m}(20ut,ht)) shifted (sx,0);
+ draw ((0,ht){1,m}..(10ut,Ht){up}) shifted (sx+20ut,0);
+ draw ((0,Ht)--(0,0)) shifted (sx+30ut,0);
+ draw ((-7.5ut,5ut)..(0,3ut){right}..tension1.5..{1,m}(20ut-Delta/m,ht-Delta)) shifted (sx+30ut,0);
+ xpos:=sx+50ut-Delta/m;
+ enddef;
+
+ def a_char=
+oval(xpos);
+stamm(ht,r,xpos);
+stock(xpos);
+enddef;
+
+def o_char=
+oval(xpos);
+stamm(ht,ht/2,xpos);
+schweif(ht,ht-Delta,fahnemittel-Delta/m,-90,angle(1,m),1.2,xpos);
+enddef;
+
+def u_char=
+ stamm(ht,ht/3,xpos);
+ ubogen;
+ stamm(ht,r,xpos);
+ stock(xpos);
+enddef;
+
+% Grossbuchstaben:
+ def C_form(expr sx)=
+ x1:=whatever;y1:=whatever;
+ x2:=whatever;y2:=whatever;
+ x3:=whatever;y3:=whatever;
+ x4:=whatever;y4:=whatever;
+ x5:=whatever;y5:=whatever;
+ x6:=whatever;y6:=whatever;
+ x7:=whatever;y7:=whatever;
+ x8:=whatever;y8:=whatever;
+ z1=(0,Ht/2); z2=(-C,0); z3=(0,-Ht/2); z4=(C,0);
+ z5=(-Sigma*C,Sigma*Ht/2);
+ z6=(-Sigma*C,-Sigma*Ht/2);
+ z7=(Sigma*C,-Sigma*Ht/2);
+ z8=(Sigma*C,Sigma*Ht/2);
+ draw (z8{z1-z4}..z1{left}..z5{z2-z1}..z2{down}..z6{z3-z2}..{right}z3)
+ shifted (sx+C,Ht/2);
+ xpos:=sx+C;
+ enddef;
+
+ def Bauch (expr ha, hb, br, sx)=
+ draw ((0,ha){right}..(br,(ha+hb)/2){down}..{left}(0,hb)) shifted (sx,0);
+ xpos:=sx;
+ enddef;
+
+ def welle(expr breit, sx)=
+ draw ((0,0){H_breit,Ht})..(5ut,2.5ut){right}..{right}(breit,0) shifted (sx,0);
+ xpos:=sx+breit;
+ enddef;
+
+ def E_form(expr sx)=
+ draw ((18.5ut,Ht-2ut)..(C,Ht){left}..(2.5ut,30ut){down}..{right}(C,ht+1ut)) shifted (sx,0);
+ draw ((C,ht+1ut){left}..(0,11ut){down}..{right}(C,0)) shifted (sx,0);
+ xpos:=sx+C;
+ enddef;
+
+ def G_form(expr sx)=
+ draw ((2*C,Ht-2.5ut)..(2*C-8ut,Ht){left}..(0,ht){down}..(2*C-12ut,0){right}..{up}(2*C,ht)) shifted (sx,0);
+ xpos:=sx+2*C;
+ enddef;
+
+ def S_char(expr sx)=
+ draw ((21ut,Ht-2.5ut)..(12ut,Ht){left}..(3ut,Ht-10ut){down}..(12ut,ht)..(21ut,10ut){down}..(12ut,0){left}..(0,3ut)) shifted (sx,0);
+ xpos:=sx+21ut;
+ enddef;
+
+ def A_char=
+ xpos:=0;
+ schweif(0,yauf,xauf,0,angle(H_breit,Ht),1,xpos);
+ gerade(yauf,Ht,H_breit-yauf*H_breit/Ht,xpos);
+ stamm(Ht,0,xpos);
+ bogen(ht-6ut,10.5ut,ht-Delta,35ut,0.35,-35,angle(1,m),1,1.2,xpos-20ut);
+enddef;
+
+
+def U_char=
+ xpos:=0;
+ stamm(Ht,ht/2,xpos);
+ bogen(ht/2,0,1.5*ht,2*C,0.375,-90,90,1,1.2,xpos);
+ stamm(Ht,r,xpos);
+ stock(xpos);
+ enddef;
+
+ % Nur fuer Testzwecke zur Bestimmung der Breite der Lettern
+ def zeigen=
+% weite:=20*xpos/ht;
+% showvariable weite;
+ enddef;
+
+% Fuer Sonderzeichen
+def komma(expr deltax, deltay) =
+ draw ((0,0){down}..(-2.5ut,-10ut)) shifted (deltax,deltay);
+ enddef;
+%%%%%%%%%%%%%%%%%%%%%%%%%%%% Ende des Files wesut14_def.mf %%%%%%%%%%%
diff --git a/fonts/schulschriften/source/weva/weva14_gr.mf b/fonts/schulschriften/source/weva/weva14_gr.mf
new file mode 100644
index 0000000000..8f5a3c9085
--- /dev/null
+++ b/fonts/schulschriften/source/weva/weva14_gr.mf
@@ -0,0 +1,260 @@
+% Vereinfachte Ausgangsschrift weva
+% Walter Entenmann
+% 11.09.2011
+% 13.09.2012
+% Grossbuchstaben
+%
+
+beginchar("A",44.031ut#,Ht#,0);
+ pickup weva_pen;
+ A_char;
+zeigen; endchar;
+
+beginchar("B",25ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,sporn,xpos);
+ gerade(0,0,sporn,xpos-sporn);
+ stamm(Ht,0,xpos);
+ gerade(Ht,Ht,flach,xpos);
+ Bauch(Ht,ht,16ut-flach,xpos);
+ gerade(ht,ht,Flach,xpos-flach);
+ Bauch(ht,0,19ut-Flach,xpos);
+ gerade(0,0,Flach,xpos-Flach);
+ xpos:=sporn+19ut;
+zeigen; endchar;
+
+beginchar("C",30.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ C_form(xpos);
+ schweif(0,ht-Delta,20ut-Delta/m,0,angle(1,m),1.5,xpos);
+zeigen; endchar;
+
+beginchar("D",31ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,sporn,xpos);
+ stamm(Ht,0,xpos);
+ gerade(0,0,sporn,xpos-sporn);
+ gerade(Ht,Ht,flach,xpos);
+ Bauch(Ht,0,25ut-flach,xpos);
+ gerade(0,0,flach,xpos-flach);
+ xpos:=sporn+25ut;
+zeigen; endchar;
+
+beginchar("E",30.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ E_form(xpos);
+schweif(0,ht-Delta,20ut-Delta/m,0,angle(1,m),1.2,xpos);
+zeigen; endchar;
+
+beginchar("F",27.5ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,2*A,xpos);
+ stamm(Ht,0,xpos-2*A+7.5ut);
+ schweif(ht-2ut,ht-Delta,25ut-Delta/m,-20,angle(1,m),2,xpos-5ut);
+ xpos:=2*A;
+zeigen; endchar;
+
+beginchar("G",38.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ G_form(xpos);
+ stamm(ht,0,xpos);
+ uschl(xpos);
+ strich(xpos);
+zeigen; endchar;
+
+beginchar("H",42.5ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(Ht,0,xpos+5ut);
+ stamm(Ht,0,xpos+H_breit);
+ schweif(ht-5ut,ht-Delta,H_breit+5ut+15ut,-45,angle(1,m),2,xpos-H_breit-5ut);
+zeigen; endchar;
+
+beginchar("I",17.5ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,15ut,xpos+2.5ut);
+ stamm(Ht,10ut,xpos);
+ bogen(10ut,0,3ut,-17.5ut,0.57,-90,140,1,1,xpos);
+ xpos:=17.5ut;
+zeigen; endchar;
+
+beginchar("J",28.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,15ut,xpos);
+ stamm(Ht,0,xpos);
+ uschl(xpos);
+ strich(xpos);
+zeigen; endchar;
+
+beginchar("K",34.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(Ht,0,xpos);
+ gerade(ht,Ht,ht,xpos);
+bogen(ht,0,ht-Delta,35ut-Delta/m,0.57,-45,angle(1,m),3,3,xpos-ht+1ut);
+zeigen; endchar;
+
+beginchar("L",34.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(Ht-10ut,10ut,xpos+2.5ut);
+ schweif(Ht-10ut,Ht,flach,90,angle(1,0.4),1,xpos);
+ schweif(0,10ut,2.5ut,angle(H_breit,Ht),90,1,xpos-flach-2.5ut);
+ welle(ht,xpos-2.5ut);
+ schweif(0,ht-Delta,16ut-Delta/m,0,angle(1,m),2.5,xpos);
+zeigen; endchar;
+
+beginchar("M",62.375ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ schweif(0,yauf,mxauf,0,angle(Ht/2,Ht),1,xpos);
+ gerade(yauf,Ht,Ht/2-yauf/2,xpos);
+ stamm(Ht,0,xpos);
+ gerade(0,Ht,Ht/2,xpos);
+ stamm(Ht,r,xpos);
+ stock(xpos);
+zeigen; endchar;
+
+beginchar("N",30ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ schweif(0,5ut,2.5ut,45,90,1,xpos);
+ stamm(Ht,5ut,xpos);
+ gerade(Ht,0,2*C,xpos);
+ stamm(Ht-5ut,0,xpos);
+ schweif(Ht-5ut,Ht,2.5ut,90,45,1,xpos);
+zeigen; endchar;
+
+beginchar("O",27.5ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ Oval(xpos);
+zeigen; endchar;
+
+beginchar("P",25ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,sporn,xpos);
+ stamm(Ht,0,xpos);
+ gerade(Ht,Ht,Flach,xpos);
+ Bauch(Ht,ht,19ut-Flach,xpos);
+ gerade(ht,ht,Flach,xpos-Flach);
+ xpos:=sporn+19ut;
+zeigen; endchar;
+
+beginchar("Q",41.875ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ Oval(xpos);
+ bogen(12.5ut,0,ht-Delta,30ut-Delta/m,0.42,-45,angle(1,m),1.5,2.5,xpos-A);
+zeigen; endchar;
+
+beginchar("R",42.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,sporn,xpos);
+ stamm(Ht,0,xpos);
+ gerade(Ht,Ht,flach,xpos);
+ Bauch(Ht,ht,16ut-flach,xpos);
+ gerade(ht,ht,flach,xpos-flach);
+ bogen(ht,0,ht-Delta,37.5ut-Delta/m,0.57,-45,angle(1,m),3,3,xpos-flach+1ut);
+zeigen; endchar;
+
+beginchar("S",21ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ S_char(xpos);
+zeigen; endchar;
+
+beginchar("T",27.5ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(Ht,Ht,2*A,xpos);
+ stamm(Ht,0,xpos-A);
+ xpos:=2*A;
+zeigen; endchar;
+
+beginchar("U",43.125ut#,Ht#,0);
+ pickup weva_pen;
+ U_char;
+zeigen; endchar;
+
+beginchar("V",32.25ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(Ht,0,xpos);
+ gerade(0,Ht-5ut,V_breit-5ut/m,xpos);
+ schweif(Ht-5ut,Ht,flach,angle(1,m),15,1,xpos);
+zeigen; endchar;
+
+beginchar("W",48.2ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(Ht,0,xpos);
+ gerade(0,Ht,H_breit,xpos);
+ stamm(Ht,0,xpos);
+ gerade(0,Ht-5ut,19.7ut,xpos);
+ schweif(Ht-5ut,Ht,flach,angle(H_breit,Ht),angle(1,0.5),1,xpos);
+zeigen; endchar;
+
+beginchar("X",42.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(0,Ht,2*A,xpos);
+ gerade(Ht,ht,11.25ut,xpos-2*A+2.5ut);
+ bogen(ht,0,ht-Delta,30.25ut-Delta/m,0.465,angle(11.25ut,-ht),angle(1,m),3.5,3,xpos);
+zeigen; endchar;
+
+beginchar("Y",38.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(Ht,ht/2,xpos);
+ bogen(ht/2,0,1.5*ht,2*C,0.375,-90,90,1,1.2,xpos);
+ stamm(Ht,0,xpos);
+ uschl(xpos);
+ strich(xpos);
+zeigen; endchar;
+
+beginchar("Z",36.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ gerade(0,Ht,H_breit,xpos);
+ gerade(Ht,Ht,-H_breit,xpos);
+ welle(H_breit,xpos);
+ schweif(0,ht-Delta,16ut-Delta/m,0,angle(1,m),2.5,xpos);
+
+zeigen; endchar;
+
+% Umlaute
+%\"A
+beginchar(oct"304",44.031ut#,45ut#,0);
+ pickup weva_pen;
+ xpos:=0;
+ Umlaut(25ut,xpos);
+A_char;
+zeigen; endchar;
+
+%\"O
+beginchar(oct"326",27.5ut#,45ut#,0);
+ pickup weva_pen;
+xpos:=0;
+Umlaut(10ut,xpos);
+Oval(xpos);
+zeigen; endchar;
+
+%\"U
+beginchar(oct"334",43.125ut#,45ut#,0);
+ pickup weva_pen;
+ xpos:=0;
+Umlaut(10ut,xpos);
+U_char;
+zeigen; endchar;
+%%%%%%%%%%%%%%%%%% End of File %%%%%%%%%%%%%%%%%%
diff --git a/fonts/schulschriften/source/weva/weva14_kl.mf b/fonts/schulschriften/source/weva/weva14_kl.mf
new file mode 100644
index 0000000000..e5da3ae402
--- /dev/null
+++ b/fonts/schulschriften/source/weva/weva14_kl.mf
@@ -0,0 +1,314 @@
+% Vereinfachte Ausgangsschrift weva
+% Walter Entenmann
+% 05.09.2011
+% 13.09.2012
+% Kleinbuchstaben
+%
+beginchar("a",30.139ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ a_char;
+zeigen; endchar;
+
+beginchar("b",24.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+oschl(xpos);
+bbauch(xpos);
+schweif(ht,ht-Delta,fahnelang-Delta/m,angle(1,-mb),angle(1,m),1,xpos);
+zeigen; endchar;
+
+beginchar("c",21.639ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+c_form(xpos);
+schweif(0,ht-Delta,r+(ht-Delta)/m,0,angle(1,m),2.5,xpos);
+zeigen; endchar;
+
+beginchar("d",30.139ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+oval(xpos);
+stamm(Ht,r,xpos);
+stock(xpos);
+zeigen; endchar;
+
+beginchar("e",21.639ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+halbellipse(xpos);
+ekopf(xpos);
+schweif(0,ht-Delta,r+(ht-Delta)/m,0,angle(1,m),1.5,xpos);
+zeigen; endchar;
+
+
+beginchar("f",18.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+oschl(xpos);
+stamm(ht,-dt,xpos);
+bogen(6ut,3ut,ht-Delta,5ut+ht-Delta/m,0.3,-45,angle(1,m),1,1.3,xpos-5ut);
+zeigen; endchar;
+
+beginchar("g",25.139ut#,ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+oval(xpos);
+stamm(ht,0,xpos);
+uschl(xpos);
+strich(xpos);
+zeigen; endchar;
+
+beginchar("h",32.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+oschl(xpos);
+stamm(ht,0,xpos);
+nbogen;
+stamm(3*ht/4,r,xpos);
+stock(xpos);
+zeigen; endchar;
+
+
+beginchar("i",18.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(ht,r,xpos);
+ ipunkt(xpos);
+ stock(xpos);
+zeigen; endchar;
+
+
+beginchar("j",13.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(ht,0,xpos);
+ ipunkt(xpos);
+ uschl(xpos);
+ strich(xpos);
+zeigen; endchar;
+
+
+beginchar("k",31.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+oschl(xpos);
+stamm(ht,0,xpos);
+k_form(xpos);
+schweif(0,ht-Delta,r+(ht-Delta)/m,0,angle(1,m),3.5,xpos);
+zeigen; endchar;
+
+beginchar("l",21.625ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+oschl(xpos);
+stamm(ht,ht/2,xpos);
+schweif(ht/2,0,5ut,-90,0,1,xpos);
+schweif(0,ht-Delta,r+(ht-Delta)/m,0,angle(1,m),3.5,xpos);
+zeigen; endchar;
+
+beginchar("m",46.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+stamm(ht,0,xpos);
+nbogen;
+stamm(3*ht/4,0,xpos);
+nbogen;
+stamm(3*ht/4,r,xpos);
+stock(xpos);
+zeigen; endchar;
+
+beginchar("n",32.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+stamm(ht,0,xpos);
+nbogen;
+stamm(3*ht/4,r,xpos);
+stock(xpos);
+zeigen; endchar;
+
+
+beginchar("o",23.139ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ o_char;
+zeigen; endchar;
+
+beginchar("p",32.125ut#,ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+stamm(ht,-dt,xpos);
+nbogen;
+stamm(3*ht/4,r,xpos);
+stock(xpos);
+zeigen; endchar;
+
+beginchar("q",26.639ut#,ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+oval(xpos);
+stamm(ht,-dt,xpos);
+qansatz(xpos);
+strich(xpos);
+zeigen; endchar;
+
+beginchar("r",18.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+stamm(ht,0,xpos);
+schweif(ht/4,ht,8ut,90,angle(1,0.5),1,xpos);
+schweif(ht,ht-Delta,fahnekurz-Delta/m,-90,angle(1,m),1.2,xpos);
+zeigen; endchar;
+
+beginchar("s",18.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+s_char(xpos);
+zeigen; endchar;
+
+beginchar("t",28.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ t_char(xpos);
+zeigen; endchar;
+
+beginchar("u",32.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ u_char;
+zeigen; endchar;
+
+beginchar("v",25.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(ht,ht/2,xpos);
+ bogen(ht/2,0,ht/2,2*a,0.5,-90,90,1,1,xpos);
+ stamm(ht,ht/2,xpos);
+ schweif(ht,ht-Delta,fahnemittel-Delta/m,-90,angle(1,m),1.2,xpos);
+zeigen; endchar;
+
+
+beginchar("w",39.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(ht,ht/2,xpos);
+ bogen(ht/2,0,ht/2,2*a,0.5,-90,90,1,1,xpos);
+ stamm(ht,ht/2,xpos);
+ bogen(ht/2,0,ht/2,2*a,0.5,-90,90,1,1,xpos);
+ stamm(ht,ht/2,xpos);
+ schweif(ht,ht-Delta,fahnemittel-Delta/m,-90,angle(1,m),1.2,xpos);
+zeigen; endchar;
+
+beginchar("x",24.125ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ x_form(xpos);
+ schweif(ht,ht-Delta,fahnekurz-Delta/m,-90,angle(1,m),1.2,xpos);
+zeigen; endchar;
+
+beginchar("y",27.125ut#,ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ stamm(ht,ht/3,xpos);
+ ubogen;
+ stamm(ht,0,xpos);
+ uschl(xpos);
+ strich(xpos);
+zeigen; endchar;
+
+beginchar("z",22.125ut#,ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ z_char(xpos);
+zeigen; endchar;
+
+% scharfes s
+% am Wortende
+beginchar(oct"035",19ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ ansatz(xpos);
+ ss_form(xpos);
+zeigen; endchar;
+
+% \scharfes s im Inneren eines Wortes (\ss):
+beginchar(oct"377",27.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ ansatz(xpos);
+ ss_char(xpos);
+zeigen; endchar;
+
+% \ss t scharfes s mit t
+beginchar(oct"036",49.6252ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ ansatz(xpos);
+ sst_char(xpos);
+zeigen; endchar;
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Umlaute
+% \"a
+beginchar(oct"344",30.1392ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ umlaut(2ut,xpos);
+a_char;
+zeigen; endchar;
+
+
+% \"o
+beginchar(oct"366",23.1392ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ umlaut(2ut,xpos);
+o_char;
+zeigen; endchar;
+
+% \"u
+beginchar(oct"374",32.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ umlaut(2ut,xpos);
+u_char;
+zeigen; endchar;
+
+% tz
+beginchar(oct"037",42.125ut#,Ht#,dt#);
+ pickup weva_pen;
+ xpos:=0;
+ tz_char(xpos);
+zeigen; endchar;
+
+% Verbindungsstueck zu den spitzen Kleinbuchstaben im Wortinneren
+beginchar(oct"200",1.875ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ draw ((0,ht-Delta)--(Delta/m,ht));
+ xpos:=Delta/m;
+zeigen; endchar;
+
+% Aufstrich bei s und st am Wortanfang
+beginchar(oct"030",7.5ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ draw ((0,ht/2)--(ht/(2*m),ht));
+ xpos:=ht/(2*m);
+zeigen; endchar;
+
+% Schluss s
+beginchar(oct"031",7.5ut#,ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ s_form(xpos);
+zeigen; endchar;
+
+% st im Innern eines Wortes
+beginchar(oct"034",38.125ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=0;
+ st_char(xpos);
+zeigen; endchar;
+
+%%%%%%%%%%%%%% File-Ende %%%%%%%%%%%%%%%%
diff --git a/fonts/schulschriften/source/weva/weva14_lig.mf b/fonts/schulschriften/source/weva/weva14_lig.mf
new file mode 100644
index 0000000000..3906d1b57e
--- /dev/null
+++ b/fonts/schulschriften/source/weva/weva14_lig.mf
@@ -0,0 +1,246 @@
+% Ligaturtabelle fuer weva14
+% Vereinfachte Ausgangsschrift (VA)
+% Walter Entenmann
+% 07.11.2011
+%
+
+ligtable "-":
+"-" =: oct"025", % --, Gedankenstrich
+"s" |=:| oct"030"; % s am Wortanfang (teil)
+
+ligtable oct"025":
+"-" =: oct"026"; % ---, langer Gedankenstrich
+
+ligtable "s": "t" =: oct"034", % st
+oct"040" =:| oct"031", % Wortende erkennen
+"!" =:| oct"031",
+oct"020" =:| oct"031",
+oct"042" =:| oct"031",
+"]" =:| oct"031",
+"'" =:| oct"031",
+")" =:| oct"031",
+"*" =:| oct"031",
+"+" =:| oct"031",
+"-" =:| oct"031",
+oct"177" =:| oct"031",
+"," =:| oct"031",
+"." =:| oct"031",
+"/" =:| oct"031",
+":" =:| oct"031",
+";" =:| oct"031",
+">" =:| oct"031",
+"<" =:| oct"031",
+"=" =:| oct"031",
+"?" =:| oct"031",
+"@" =:| oct"031",
+"b" |=:| oct"200", % Verbindungsstueck einfuegen
+"f" |=:| oct"200",
+"h" |=:| oct"200",
+"i" |=:| oct"200",
+"j" |=:| oct"200",
+"k" |=:| oct"200",
+"l" |=:| oct"200",
+"m" |=:| oct"200",
+"n" |=:| oct"200",
+"p" |=:| oct"200",
+"r" |=:| oct"200",
+"s" |=:| oct"200",
+"t" |=:| oct"200",
+"u" |=:| oct"200",
+"v" |=:| oct"200",
+"w" |=:| oct"200",
+"x" |=:| oct"200",
+"y" |=:| oct"200",
+oct"377" |=:| oct"200",
+oct"374" |=:| oct"200"
+;
+
+ligtable "t": "z" =: oct"037", % tz
+"b" |=:| oct"200", % Verbindungsstueck einfuegen
+"f" |=:| oct"200",
+"h" |=:| oct"200",
+"i" |=:| oct"200",
+"j" |=:| oct"200",
+"k" |=:| oct"200",
+"l" |=:| oct"200",
+"m" |=:| oct"200",
+"n" |=:| oct"200",
+"p" |=:| oct"200",
+"r" |=:| oct"200",
+"s" |=:| oct"200",
+"t" |=:| oct"200",
+"u" |=:| oct"200",
+"v" |=:| oct"200",
+"w" |=:| oct"200",
+"x" |=:| oct"200",
+"y" |=:| oct"200",
+oct"377" |=:| oct"200",
+oct"374" |=:| oct"200"
+;
+
+ligtable oct"377": "t" =: oct"036", % sst
+oct"040" =:| oct"035", % Wortende erkennen
+"!" =:| oct"035",
+oct"020" =:| oct"035",
+oct"042" =:| oct"035",
+"]" =:| oct"035",
+"'" =:| oct"035",
+")" =:| oct"035",
+"*" =:| oct"035",
+"+" =:| oct"035",
+"-" =:| oct"035",
+oct"177" =:| oct"035",
+"," =:| oct"035",
+"." =:| oct"035",
+"/" =:| oct"035",
+":" =:| oct"035",
+";" =:| oct"035",
+">" =:| oct"035",
+"<" =:| oct"035",
+"=" =:| oct"035",
+"?" =:| oct"035",
+"@" =:| oct"035",
+"b" |=:| oct"200", % Verbindungsstueck einfuegen:
+"f" |=:| oct"200",
+"h" |=:| oct"200",
+"i" |=:| oct"200",
+"j" |=:| oct"200",
+"k" |=:| oct"200",
+"l" |=:| oct"200",
+"m" |=:| oct"200",
+"n" |=:| oct"200",
+"p" |=:| oct"200",
+"r" |=:| oct"200",
+"s" |=:| oct"200",
+"t" |=:| oct"200",
+"u" |=:| oct"200",
+"v" |=:| oct"200",
+"w" |=:| oct"200",
+"x" |=:| oct"200",
+"y" |=:| oct"200",
+oct"377" |=:| oct"200",
+oct"374" |=:| oct"200"
+;
+
+
+ligtable ||: % Wortanfang erkennen
+"0": "1": "2": "3": "4": "5": "6": "7": "8": "9":
+oct"040": "[": "'": "(": "*": "+":
+ "/": ">": "<": "=": "@":
+ oct"022": oct"026": oct"023": oct"024": oct"016": oct"017":
+"s" |=:| oct"030"
+;
+
+ligtable "B": "D": "I": "N": "O": "P": "S": oct"326":
+1:: oct"030" kern 5ut#,
+"a" kern 7.5ut#,
+"b" kern 7.5ut#,
+"c" kern 7.5ut#,
+"d" kern 7.5ut#,
+"e" kern 7.5ut#,
+"f" kern 7.5ut#,
+"g" kern 7.5ut#,
+"h" kern 7.5ut#,
+"i" kern 7.5ut#,
+"j" kern 7.5ut#,
+"k" kern 7.5ut#,
+"l" kern 7.5ut#,
+"m" kern 7.5ut#,
+"n" kern 7.5ut#,
+"o" kern 7.5ut#,
+"p" kern 7.5ut#,
+"q" kern 7.5ut#,
+"r" kern 7.5ut#,
+"s" |=:| oct"030",
+"t" kern 7.5ut#,
+"u" kern 7.5ut#,
+"v" kern 7.5ut#,
+"w" kern 7.5ut#,
+"x" kern 7.5ut#,
+"y" kern 7.5ut#,
+"z" kern 7.5ut#,
+oct"377" kern 7.5ut#,
+oct"034" |=:| oct"030",
+oct"036" kern 7.5ut#,
+oct"037" kern 7.5ut#,
+oct"344" kern 7.5ut#,
+oct"366" kern 7.5ut#,
+oct"374" kern 7.5ut#,
+skipto 1
+;
+
+ligtable "T": "V": "W":
+2:: oct"030" kern -2.5ut#,
+"a" kern 2.5ut#,
+"b" kern 5ut#,
+"c" kern 2.5ut#,
+"d" kern 2.5ut#,
+"e" kern 2.5ut#,
+"f" kern 5ut#,
+"g" kern 2.5ut#,
+"h" kern 5ut#,
+"i" kern 5ut#,
+"j" kern 5ut#,
+"k" kern 5ut#,
+"l" kern 5ut#,
+"m" kern 5ut#,
+"n" kern 5ut#,
+"o" kern 2.5ut#,
+"p" kern 5ut#,
+"q" kern 2.5ut#,
+"r" kern 5ut#,
+"s" |=:| oct"030",
+"t" kern 2.5ut#,
+"u" kern 5ut#,
+"v" kern 5ut#,
+"w" kern 5ut#,
+"x" kern 5ut#,
+"y" kern 5ut#,
+"z" kern -2.5ut#,
+oct"377" kern 5ut#,
+oct"034" |=:| oct"030",
+oct"036" kern 5ut#,
+oct"037" kern 2.5ut#,
+oct"344" kern 2.5ut#,
+oct"366" kern 2.5ut#,
+oct"374" kern 5ut#,
+skipto 2
+;
+
+% alle verbundenen Buchst. vor spitzverb. Buchst,
+ % Verbindungsstueck einfuegen:
+ligtable "A": "C": "E": "F": "G": "H": "J": "K": "L":
+ "M": "Q": "R": "U": "X": "Y": "Z":
+ "a": "b": "c": "d": "e": "f": "g": "h": "i": "j": "k": "l":
+ "m": "n": "o": "p": "q": "r":
+ "u": "v": "w": "x": "y": "z":
+ oct"037": oct"034": oct"036":
+ oct"304": oct"334":
+ oct"344": oct"366": oct"374":
+ "b" |=:| oct"200",
+ "f" |=:| oct"200",
+ "h" |=:| oct"200",
+ "i" |=:| oct"200",
+ "j" |=:| oct"200",
+ "k" |=:| oct"200",
+ "l" |=:| oct"200",
+ "m" |=:| oct"200",
+ "n" |=:| oct"200",
+ "p" |=:| oct"200",
+ "r" |=:| oct"200",
+ "s" |=:| oct"200",
+ "t" |=:| oct"200",
+ "u" |=:| oct"200",
+ "v" |=:| oct"200",
+ "w" |=:| oct"200",
+ "x" |=:| oct"200",
+ "y" |=:| oct"200",
+ oct"377" |=:| oct"200",
+ oct"034" |=:| oct"200",
+ oct"036" |=:| oct"200",
+ oct"037" |=:| oct"200",
+ oct"344" |=:| oct"200",
+ oct"366" |=:| oct"200",
+ oct"374" |=:| oct"200"
+ ;
+%%%%%%%%%%%%%%%%%%% File-Ende %%%%%%%%%%%%%%%%%%%%%%%%%%%%
diff --git a/fonts/schulschriften/source/weva/weva14_sz.mf b/fonts/schulschriften/source/weva/weva14_sz.mf
new file mode 100644
index 0000000000..f02d49ce6b
--- /dev/null
+++ b/fonts/schulschriften/source/weva/weva14_sz.mf
@@ -0,0 +1,405 @@
+% Vereinfachte Ausgangsschrift weva
+% Ziffern, Satzzeichen, Sonderzeichen
+% Walter Entenmann
+% 11.09.2011
+% 13.09.2012
+% 14.11.2014: einheitliche Sonderzeichen
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% #
+beginchar("#",35ut#,Ht#,0);
+ pickup weva_pen;
+ p:=(0,0)--(0,Ht);
+ draw p slanted 0.176 shifted (10ut,0);
+ draw p slanted 0.176 shifted (20ut,0);
+ q:=((0,0)--(26ut,0)) shifted (2ut,0);
+ draw q shifted(0,Ht/3) slanted 0.176;
+ draw q shifted(0,2Ht/3) slanted 0.176;
+endchar;
+
+% ยง
+ beginchar(oct"237",43.333ut#,Ht#,dt#);
+ pickup weva_pen;
+sep:=10ut; breit:=20ut;
+p := ((8ut,20ut){curl 10}..(0ut,30ut){left}..(-breit/2,22ut){down}..
+ (breit/2,-2.5ut){down}..{-1,2/3}(2ut,-11ut)) scaled ((Ht+dt)/60ut);
+ draw p shifted (sep+breit*0.583,ht/2);
+ draw p rotated 180 shifted (sep+breit*0.583,ht/2);
+ endchar;
+
+% *
+beginchar("*",30ut#,Ht#,0);
+ pickup weva_pen;
+ p:= (-ht/2,0)--(ht/2,0);
+ draw p rotated 90 shifted (15ut,1.5ht);
+ draw p rotated 30 shifted (15ut,1.5ht);
+ draw p rotated -30 shifted (15ut,1.5ht);
+endchar;
+
+% Prozentzeichen (%)
+beginchar("%",40ut#,Ht#,0);
+ pickup weva_pen;
+ q := (-23.6ut,0)--(23.6ut,0);
+ breit:=12.5ut;hoch:=17.5ut;
+ p := (breit/2,0){up}..(0,hoch/2){left}..(-breit/2,0){down}..(0,-hoch/2){right}..{up}(breit/2,0);
+ x0:=whatever;y0:=whatever;
+ z0=(directionpoint (-1,2) of (subpath (0,1) of p)) shifted (7.5ut+breit/2,Ht-hoch/2);
+ draw p shifted (7.5ut+breit/2,Ht-hoch/2);
+ draw p shifted (7.5ut+25ut-breit/2,hoch/2);
+ draw q rotated 58 shifted (w/2,h/2);
+ draw z0{1,-2}..{dir 58}(7.5ut+25ut,Ht);
+endchar;
+
+% &
+ beginchar("&",40ut#,Ht#,0);
+ pickup weva_pen;
+ p := (22.5ut,12.5ut)..tension 1.2..(7.5ut,0){left}..(0,8ut){up}..
+ %(8.167ut,21ut){3,2}..
+ tension 1.2..(17ut,34.5ut){up}..(11.5ut,Ht){left}..(4ut,30ut){down}..{2,-3}(8.167ut,21ut)--(22.5ut,0);
+ draw p shifted (10ut,0);
+ endchar;
+
+% $
+beginchar("$",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw halfcircle xscaled 20ut yscaled 20ut shifted (15ut,30ut);
+ draw (halfcircle rotated 180 xscaled 20ut yscaled 20ut) shifted (15ut,10ut);
+ draw ((-10ut,10ut){down}..{down}(10ut,-10ut)) shifted (15ut,ht);
+ draw ((0,ht+2.5ut)--(0,-ht-2.5ut)) shifted (15ut,ht);
+endchar;
+
+% "+"
+beginchar("+",30ut#,22.5ut#,0);
+ path p;
+ pickup weva_pen;
+ z0=(15ut,hmath);
+ z1=(0ut,10ut);
+ z2=(0ut,-10ut);
+ p := z1--z2;
+ draw p shifted z0 ;
+ draw p rotated 90 shifted z0 ;
+ labels(range 0 thru 2);
+endchar;
+
+% ASCII Bindestrich oct"055" (OT1: auch Trennstrich)
+beginchar("-",27.5ut#,ht#,0);
+ pickup weva_pen;
+ draw ((0,0)--(12.5ut,0)) shifted (7.5ut,hdash);
+endchar;
+
+% T1: Trennstrich
+beginchar(oct"177",27.5ut#,ht#,0);
+ pickup weva_pen;
+ draw ((0,0)--(12.5ut,0)) shifted (7.5ut,hdash);
+endchar;
+
+% "/"
+beginchar("/",25ut#,Ht#,0);
+ pickup weva_pen;
+draw ((5ut,0)--(20ut,Ht));
+endchar;
+
+% ">"
+beginchar(">",30ut#,Ht#,0);
+ path p;
+ pickup weva_pen;
+p:=(0,0)--(20ut,0);
+draw p rotated 30 shifted (6.33ut,hmath);
+ draw p rotated -30 shifted (6.33ut,hmath);
+endchar;
+
+% "="
+beginchar("=",30ut#,ht#,0);
+ pickup weva_pen;
+ draw((0,0)--(20ut,0)) shifted (5ut,hmath-2.5ut);
+ draw((0,0)--(20ut,0)) shifted (5ut,hmath+2.5ut);
+endchar;
+
+% "<"
+beginchar("<",30ut#,Ht#,0);
+ path p;
+ pickup weva_pen;
+p:=(0,0)--(-20ut,0);
+draw p rotated 30 shifted (23.66ut,hmath);
+ draw p rotated -30 shifted (23.66ut,hmath);
+endchar;
+
+% oct"025" Bis-Strich --, Gedankenstrich
+beginchar(oct"025",30ut#,ht#,0);
+ pickup weva_pen;
+draw ((0,0)--(20ut,0)) shifted (5ut,hdash);
+endchar;
+
+% engl. Gedankenstrich ---
+beginchar(oct"026",45ut#,ht#,0);
+ pickup weva_pen;
+draw ((0,0)--(30ut,0)) shifted (7.5ut,hdash);
+endchar;
+
+% oct"023" franz. Anfz. <<
+beginchar(oct"023",32.5ut#,ht#,0);
+ path p, q;
+ pickup weva_pen;
+ z1=(0ut,0ut);
+ z2=(1.1*ht/2,0);
+ z3=(6,-1);
+ z4=(6,1);
+ z5=(7.5ut,ht/2);
+z6=(15ut,ht/2);
+ p := (z1{z3}..z2) rotated 45;
+ q := (z1{z4}..z2) rotated -45;
+ draw p shifted z5 ;
+ draw p shifted z6 ;
+ draw q shifted z5 ;
+ draw q shifted z6 ;
+ labels(range 1 thru 6);
+endchar;
+
+% oct"024" franz. Anfz. >>
+beginchar(oct"024",32.5ut#,ht#,0);
+ path p, q;
+ pickup weva_pen;
+ z1=(0ut,0ut);
+ z2=(1.1*ht/2,0);
+ z3=(6,-1);
+ z4=(6,1);
+ z5=(17.5ut,ht/2);
+ z6=(25ut,ht/2);
+
+ p := (z1{z4}..z2) rotated 135;
+ q := (z1{z3}..z2) rotated -135;
+ draw p shifted z5 ;
+ draw p shifted z6 ;
+ draw q shifted z5 ;
+ draw q shifted z6 ;
+ labels(range 1 thru 6);
+endchar;
+
+% oct"016" franz. Anfz. <
+beginchar(oct"016",25ut#,ht#,0);
+ path p, q;
+ pickup weva_pen;
+ z1=(0ut,0ut);
+ z2=(1.1*ht/2,0);
+ z3=(6,-1);
+ z4=(6,1);
+ z5=(7.5ut,ht/2);
+ p := (z1{z3}..z2) rotated 45;
+ q := (z1{z4}..z2) rotated -45;
+ draw p shifted z5 ;
+ draw q shifted z5 ;
+ labels(range 1 thru 5);
+endchar;
+
+% oct"017" franz. Anfz. >
+beginchar(oct"017",25ut#,ht#,0);
+ path p, q;
+ pickup weva_pen;
+ z1=(0ut,0ut);
+ z2=(1.1*ht/2,0);
+ z3=(6,-1);
+ z4=(6,1);
+ z5=(17.5ut,ht/2);
+ p := (z1{z4}..z2) rotated 135;
+ q := (z1{z3}..z2) rotated -135;
+ draw p shifted z5 ;
+ draw q shifted z5 ;
+ labels(range 1 thru 5);
+endchar;
+
+% "@":
+beginchar("@",50ut#,Ht#,0);
+ pickup weva_pen;
+sep:=10ut;gap:=8ut;
+draw (superellipse((a,0),(0,b),(-a,0),(0,-b),sigma)) shifted (gap+a+sep,ht);
+draw ((0,ht)--(0,5ut){down}..(2ut,0){right}..tension 1.5..(gap,ht/2){up}..
+ (-a,3ht/2){left}..(-2*a-gap,ht/2){down}..
+ (-a,-ht/2){right}..(7.5ut,-5ut)) shifted (2*a+gap+sep,ht/2);
+endchar;
+
+% Euro (\symbol{160})
+beginchar(oct"240",47.5ut#,Ht#,0);
+ pickup weva_pen;
+ sep:=7.5ut; gap:=7.5ut;
+ draw (halfcircle rotated 90) xscaled 30ut yscaled Ht shifted (15ut+gap+sep,Ht/2);
+ draw ((0,0){right}..(7.5ut,-3ut)) shifted (15ut+gap+sep,Ht);
+ draw ((0,0){right}..(7.5ut,3ut)) shifted (15ut+gap+sep,0);
+ draw (((-25ut,2.5ut)--(0,2.5ut)) shifted (15ut+gap+sep,ht)) slanted 0.25;
+ draw (((-25ut,-2.5ut)--(0,-2.5ut)) shifted (15ut+gap+sep,ht)) slanted 0.25;
+endchar;
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+
+% Ziffern
+beginchar("0",30ut#,Ht#,0);
+ pickup weva_pen;
+draw fullcircle xscaled 20ut yscaled Ht shifted (15ut,ht);
+endchar;
+
+beginchar("1",30ut#,Ht#,0);
+ pickup weva_pen;
+ xpos:=7.5ut;
+ gerade(ht,Ht,10ut,xpos);
+ stamm(Ht,0,xpos);
+endchar;
+
+beginchar("2",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw halfcircle xscaled 17.5ut yscaled ht shifted (13.75ut,1.5*ht);
+ draw ((22.5ut,1.5*ht){down}..tension2and 5..{-17.5ut,-27.5ut}(5ut,0));
+ gerade(0,0,20ut,5ut);
+endchar;
+
+beginchar("3",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw ((-8.5ut,Ht-5ut)..(0,Ht){right}..(8.5ut,30ut){down}..(-1.5ut,ht+1ut){left}) shifted (15ut,0);
+ draw ((-1.5ut,ht+1ut){right}..(10ut,ht/2){down}..(0,0){left}..(-10ut,5ut)) shifted (15ut,0);
+endchar;
+
+beginchar("4",30ut#,Ht#,0);
+ pickup weva_pen;
+draw ((10ut,h)--(0,h/4)--(20ut,h/4)) shifted (5ut,0);
+draw ((15ut,25ut)--(15ut,0)) shifted (5ut,0);
+endchar;
+
+beginchar("5",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw ((20ut,Ht)--(0,Ht)--(0,25ut)) shifted (5ut,0);
+ draw (halfcircle rotated -90 xscaled 25ut yscaled 27.5ut) shifted (12.5ut,13.75ut);
+ draw ((7.5ut,27.5ut){left}..(0,25ut)) shifted (5ut,0);
+ draw ((7.5ut,0){left}..(0,5ut)) shifted (5ut,0);
+endchar;
+
+
+beginchar("6",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw fullcircle xscaled 20ut yscaled 27.5ut shifted (15ut,13.75ut);
+ draw ((0,13.75ut){up}..(10ut,Ht){right}..(16ut,Ht-2.5ut)) shifted (5ut,0);
+endchar;
+
+beginchar("7",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw ((0,Ht)--(20ut,Ht)--(10ut,0)) shifted (5ut,0);
+ draw ((0,ht)--(10ut,ht)) shifted (15ut,0);
+endchar;
+
+beginchar("8",30ut#,Ht#,0);
+ pickup weva_pen;
+ p:=(0,0){-1,-macht}..(-10ut,-10ut){down}..(0,-ht){right}..(10ut,-10ut){up}..{-1,macht}(0,0);
+ draw p shifted (15ut,ht);
+ draw p rotated 180 shifted (15ut,ht);
+endchar;
+
+
+beginchar("9",30ut#,Ht#,0);
+ pickup weva_pen;
+ draw fullcircle xscaled 20ut yscaled 25ut shifted (15ut,27.5ut);
+ draw ((20ut,Ht)--(20ut,27.5ut){down}..(10ut,0){left}..(0,5ut)) shifted (5ut,0);
+endchar;
+
+% ASCII-Zeichen
+beginchar("!",20ut#,Ht#,0);
+ pickup weva_pen;
+ z1=(10ut,40ut);
+ z2=(10ut,10ut);
+ z3=(10ut,0);
+ p := z1--z2;
+ draw p;
+ pickup weva_pen_thick;
+ drawdot z3;
+ labels(range 1 thru 3);
+endchar;
+
+% ", Doppelapostroph, hier identisch mit oct"020", dt. Anfz. o.
+beginchar(oct"042",25ut#,Ht#,0);
+ pickup weva_pen;
+ komma(12.5ut,Ht);
+ komma(17.5ut,Ht);
+endchar;
+
+% [
+beginchar("[",25ut#,Ht#,ht#);
+ pickup weva_pen;
+draw ((10ut,Ht)--(5ut,Ht)--(5ut,-ht)--(10ut,-ht)) shifted (5ut,0);
+ endchar;
+
+% ]
+beginchar("]",25ut#,Ht#,ht#);
+ pickup weva_pen;
+draw ((0,Ht)--(5ut,Ht)--(5ut,-ht)--(0,-ht)) shifted (5ut,0);
+ endchar;
+
+beginchar("'",20ut#,Ht#,0);
+ pickup weva_pen;
+komma(12.5ut,Ht);
+endchar;
+
+beginchar("(",20ut#,60ut#,ht#);
+ pickup weva_pen;
+draw ((10ut,Ht)..(2.5,ht/2){down}..(10ut,-ht)) shifted (5ut,0);
+endchar;
+
+beginchar(")",20ut#,60ut#,ht#);
+ pickup weva_pen;
+draw ((0,Ht)..(7.5ut,ht/2){down}..(0,-ht)) shifted(5ut,0);
+endchar;
+
+beginchar(",",15ut#,ht#,dt#);
+ pickup weva_pen;
+komma(7.5ut,3.5ut);
+endchar;
+
+beginchar(".",15ut#,ht#,0);
+ pickup weva_pen_thick;
+ z1=(7.5ut,0ut);
+ drawdot z1 ;
+ labels(1);
+endchar;
+
+beginchar(":",20ut#,ht#,0);
+ pickup weva_pen_thick;
+ drawdot (0,0) shifted (10ut,0);
+ drawdot (0,0) shifted (10ut,17.5ut);
+endchar;
+
+beginchar(";",20ut#,ht#,-dt#);
+ pickup weva_pen;
+komma(10ut,3.5ut);
+ pickup weva_pen_thick;
+ drawdot (0,0) shifted (10ut,17.5ut);
+endchar;
+
+beginchar("?",35ut#,Ht#,0);
+ pickup weva_pen;
+ z1=(-7.5ut,10ut);
+ z2=(0,15ut);
+ z3=(7.5ut,7.5ut);
+ z4=(0,0);
+ z5=(-7.5ut,-7.5ut);
+ z6=(0,-15ut);
+ z7=(7.5ut,-10ut);
+ p := z1..z2{right}..z3{down}..z4..{down}z5..z6{right}..z7;
+ draw p shifted (w/2,h/2+5ut) ;
+ pickup weva_pen_thick;
+ drawdot (0,0) shifted (w/2,0);
+ labels(range 1 thru 7);
+endchar;
+
+%
+% spezielle Sonderzeichen (T1-Kodierung)
+% dt. Anfuehrungszeichen oben (\grqq), wie oct"042"
+beginchar(oct"020",25ut#,Ht#,0);
+ pickup weva_pen;
+ komma(12.5ut,Ht);
+ komma(17.5ut,Ht);
+endchar;
+
+% dt. Anfuehrungszeichen unten (\glqq)
+beginchar(oct"022",25ut#,ht#,dt#);
+ pickup weva_pen;
+ komma(7.5ut,3.5ut);
+ komma(12.5ut,3.5ut);
+endchar;
+
+
+
+%%%%%%%%%%%%%%%% File-Ende %%%%%%%%%%%%%%%%%
diff --git a/fonts/schulschriften/source/weva/wevabx14.mf b/fonts/schulschriften/source/weva/wevabx14.mf
new file mode 100644
index 0000000000..fa0caea063
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevabx14.mf
@@ -0,0 +1,3 @@
+% weva bold
+fetter:=2;
+input weva14;
diff --git a/fonts/schulschriften/source/weva/wevabxsl14.mf b/fonts/schulschriften/source/weva/wevabxsl14.mf
new file mode 100644
index 0000000000..d1c7fe0ec0
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevabxsl14.mf
@@ -0,0 +1,3 @@
+% weva bold, slanted
+fetter:=2;
+input wevasl14;
diff --git a/fonts/schulschriften/source/weva/wevaeb14.mf b/fonts/schulschriften/source/weva/wevaeb14.mf
new file mode 100644
index 0000000000..4a0b26b6bd
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevaeb14.mf
@@ -0,0 +1,3 @@
+% weva extra bold
+fetter:=3;
+input weva14;
diff --git a/fonts/schulschriften/source/weva/wevaebsl14.mf b/fonts/schulschriften/source/weva/wevaebsl14.mf
new file mode 100644
index 0000000000..5c99ac6212
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevaebsl14.mf
@@ -0,0 +1,3 @@
+% weva extra bold, slanted
+fetter:=3;
+input wevasl14;
diff --git a/fonts/schulschriften/source/weva/wevasb14.mf b/fonts/schulschriften/source/weva/wevasb14.mf
new file mode 100644
index 0000000000..8eb12bded7
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevasb14.mf
@@ -0,0 +1,3 @@
+% weva semi bold
+fetter:=1;
+input weva14;
diff --git a/fonts/schulschriften/source/weva/wevasbsl14.mf b/fonts/schulschriften/source/weva/wevasbsl14.mf
new file mode 100644
index 0000000000..0dea57946a
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevasbsl14.mf
@@ -0,0 +1,3 @@
+% weva semi bold, slanted
+fetter:=1;
+input wevasl14;
diff --git a/fonts/schulschriften/source/weva/wevasl14.mf b/fonts/schulschriften/source/weva/wevasl14.mf
new file mode 100644
index 0000000000..2f31a4aa37
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevasl14.mf
@@ -0,0 +1,3 @@
+% weva slanted
+slant:=0.19;
+input weva14;
diff --git a/fonts/schulschriften/source/weva/wevaub14.mf b/fonts/schulschriften/source/weva/wevaub14.mf
new file mode 100644
index 0000000000..92bfd8cd2e
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevaub14.mf
@@ -0,0 +1,3 @@
+% weva ultra bold
+fetter:=4;
+input weva14;
diff --git a/fonts/schulschriften/source/weva/wevaubsl14.mf b/fonts/schulschriften/source/weva/wevaubsl14.mf
new file mode 100644
index 0000000000..c4ae992c35
--- /dev/null
+++ b/fonts/schulschriften/source/weva/wevaubsl14.mf
@@ -0,0 +1,3 @@
+% weva ultra bold, slanted
+fetter:=4;
+input wevasl14;